structure NormalizeEin = struct

    local

    structure E = Ein
    structure P=Printer
    structure F=Filter
    structure G=EpsHelpers

    in

    fun err str=raise Fail (String.concat["Ill-formed EIN Operator",str])
    val testing=0
    fun flatProd e =F.rewriteProd e
    fun mkProd e= F.mkProd e
    fun filterSca e=F.filterSca e
    fun filterField e=F.filterField e
    fun mkAdd e=F.mkAdd e
    fun filterGreek e=F.filterGreek e
    fun testp n=(case testing
        of 0=> 1
        | _ =>(print(String.concat n);1)
        (*end case*))

    (*prodAppPartia:ein_exp list * mu list ->ein_exp
    * chain rule 
    *)
    fun prodAppPartial(es,p1)=(case es
        of []      => err "Empty App Partial"
        | [e1]     => E.Apply(E.Partial p1,e1)
        | (e1::e2) => let
            val l= prodAppPartial(e2,p1)
            val (_,e2')= mkProd[e1,l]
            val (_,e1')=mkProd(e2@ [E.Apply(E.Partial p1, e1)])
            in
                E.Add[e1',e2']
            end
        (* end case *))
                    
    (*mkSum:sum_indexid list * ein_exp->int *ein_exp
    *distribute summation expression 
    *)
    fun mkSum(c1,e1)=(case e1
        of E.Conv _   => (0,E.Sum(c1,e1))
        | E.Field _   => (0,E.Sum(c1,e1))
        | E.Probe _   => (0,E.Sum(c1,e1))
        | E.Apply _   => (0,E.Sum(c1,e1))
        | E.Delta _   => (0,E.Sum(c1,e1))
        | E.Epsilon _ => (0,E.Sum(c1,e1))
        | E.Eps2 _    => (0,E.Sum(c1,e1))
        | E.Tensor(_,[]) => (1,e1)
        | E.Tensor _  => (0,E.Sum(c1,e1))
        | E.Neg e2    => (1,E.Neg(E.Sum(c1,e2)))
        | E.Sub (a,b) => (1,E.Sub(E.Sum(c1,a),E.Sum(c1,b)))
        | E.Add e     => (1,E.Add (List.map (fn(a)=>E.Sum(c1,a)) e))
        | E.Div (a,b) => (1,E.Div(E.Sum(c1,a),E.Sum(c1,b)))
        | E.Lift e    => (1,E.Lift(E.Sum(c1,e)))
        | E.Sum(c2,e2)=> (1,E.Sum(c1@c2,e2))
        | E.Prod p    => filterSca(c1,p)
        | E.Const _   => err("Sum of Const")
        | E.Partial _ => err("Sum of Partial")
        | E.Krn _     => err("Krn used before expand")
        | E.Value _   => err("Value used before expand")
        | E.Img _     => err("Probe used before expand")
        (*end case*))
                    
    (* mkapply:mu list*ein_exp->int*ein_exp
    * rewrite Apply
    *)
    fun mkapply(d1,e1)=(case e1
        of E.Lift e   => (1,E.Const 0)
        | E.Prod []   => err("Apply of empty product")
        | E.Add []    => err("Apply of empty Addition")
        | E.Conv(v, alpha, h, d2)    =>let
            val E.Partial d3=d1
            in
                (1,E.Conv(v,alpha,h,d2@d3))
            end
        | E.Field _   => (0,E.Apply(d1,e1))
        | E.Probe _   => (0,E.Apply(d1,e1))
        | E.Apply(E.Partial d2,e2)  => let
            val E.Partial d3=d1
            in
                (1,E.Apply(E.Partial(d3@d2),e2))
            end
        | E.Apply _   => err" Apply of non-Partial expression"
        | E.Sum(c2,e2)=> (1,E.Sum(c2,E.Apply(d1,e2)))
        | E.Neg e2    => (1,E.Neg(E.Apply(d1,e2)))
        | E.Add e     => (1,E.Add (List.map (fn(a)=>E.Apply(d1,a)) e))
        | E.Sub (a,b) => (1,E.Sub(E.Apply(d1,a),E.Apply(d1,b)))
        | E.Div (g,b) => (case filterField[b]
            of (_,[]) => (1,E.Div(E.Apply(d1,g),b)) (*Division by a real*)
            | (pre,h) => let
                (*quotient rule*)
                val g'=E.Apply(d1,g)
                val h'=E.Apply(d1,flatProd(h))
                val num=E.Sub(E.Prod([g']@h),E.Prod[g,h'])
                val denom=E.Prod(pre@h@h)
                in (1,E.Div(num,denom))
                end
            (*end case*))
        | E.Prod p =>let
            val (pre, post)= filterField p
            val E.Partial d3=d1
            in mkProd(pre@[prodAppPartial(post,d3)])
            end
        | E.Const _   => err("Const without Lift")
        | E.Tensor _  => err("Tensor without Lift")
        | E.Delta _   => err("Apply of Delta")
        | E.Epsilon _ => err("Apply of Eps")
        | E.Eps2 _ => err("Apply of Eps")
        | E.Partial _ => err("Apply of Partial")
        | E.Krn _     => err("Krn used before expand")
        | E.Value _   => err("Value used before expand")
        | E.Img _     => err("Probe used before expand")
        (*end case*))
                    
    (*mkprobe:ein_exp* ein_exp-> int ein_exp
    *rewritten probe
    *)
    fun mkprobe(e1,x)=(case e1
        of E.Lift e   => (1,e)
        | E.Prod []   => err("Probe of empty product")
        | E.Prod p    => (1,E.Prod (List.map (fn(a)=>E.Probe(a,x)) p))
        | E.Apply _   => (0,E.Probe(e1,x))
        | E.Conv _    => (0,E.Probe(e1,x))
        | E.Field _   => (0,E.Probe(e1,x))
        | E.Sum(c,e') => (1,E.Sum(c,E.Probe(e',x)))
        | E.Add e     => (1,E.Add (List.map (fn(a)=>E.Probe(a,x)) e))
        | E.Sub (a,b) => (1,E.Sub(E.Probe(a,x),E.Probe(b,x)))
        | E.Neg e'    => (1,E.Neg(E.Probe(e',x)))
        | E.Div (a,b) => (1,E.Div(E.Probe(a,x),E.Probe(b,x)))
        | E.Const _   => err("Const without Lift")
        | E.Tensor _  => err("Tensor without Lift")
        | E.Delta _   => (0,e1)
        | E.Epsilon _ => (0,e1)
        | E.Eps2 _    => (0,e1)
        | E.Partial _ => err("Probe Partial")
        | E.Probe _   => err("Probe of a Probe")
        | E.Krn _     => err("Krn used before expand")
        | E.Value _   => err("Value used before expand")
        | E.Img _     => err("Probe used before expand")
    (*end case*))

    (* normalize: EIN->EIN
    * rewrite body of EIN
    * note "c" keeps track if ein_exp is changed 
    *)
    fun normalize (ee as Ein.EIN{params, index, body}) = let
      val changed = ref false
      fun rewriteBody body =(case body
        of E.Const _    => body
        | E.Tensor _    => body
        | E.Field _     => body
        | E.Delta _     => body
        | E.Epsilon _   => body
        | E.Eps2 _      => body
        | E.Conv _      => body
        | E.Partial _   => body
        | E.Krn _       => raise Fail"Krn before Expand"
        | E.Img _       => raise Fail"Img before Expand"
        | E.Value _     => raise Fail"Value before Expand"
            (*************Algebraic Rewrites **************)
        | E.Neg(E.Neg e)    => rewriteBody e
        | E.Neg e           => E.Neg(rewriteBody e)
        | E.Lift e          => E.Lift(rewriteBody e)
        | E.Add es          => let
            val (change,body')= mkAdd(List.map rewriteBody es)
            in if (change=1) then ( changed:=true;body') else body' end
        | E.Sub(a, E.Field f)=> (changed:=true;E.Add[a, E.Neg(E.Field(f))])
        | E.Sub(E.Sub(a,b),E.Sub(c,d))  => rewriteBody(E.Sub(E.Add[a,d],E.Add[b,c]))
        | E.Sub(E.Sub(a,b),e2)          => rewriteBody (E.Sub(a,E.Add[b,e2]))
        | E.Sub(e1,E.Sub(c,d))          => rewriteBody(E.Add([E.Sub(e1,c),d]))
        | E.Sub (a,b)                   => E.Sub(rewriteBody a, rewriteBody b)
        | E.Div(e1 as E.Tensor(_,[_]),e2 as E.Tensor(_,[]))=>
                rewriteBody (E.Prod[E.Div(E.Const 1, e2),e1])

        | E.Div(E.Div(a,b),E.Div(c,d))  => rewriteBody(E.Div(E.Prod[a,d],E.Prod[b,c]))
        | E.Div(E.Div(a,b),c)           => rewriteBody (E.Div(a, E.Prod[b,c]))
        | E.Div(a,E.Div(b,c))           => rewriteBody (E.Div(E.Prod[a,c],b))
        | E.Div (a, b)                  => (E.Div(rewriteBody a, rewriteBody b))
            (**************Apply, Sum, Probe**************)
        | E.Apply(E.Partial [],e)   => e
        | E.Apply(E.Partial d1, e1) =>
            let
            val e2 = rewriteBody e1
            val (c,e3)=mkapply(E.Partial d1,e2)
            in
                (case c of 1=>(changed:=true;e3)| _ =>e3 (*end case*))
            end
        | E.Apply _                 => raise Fail" Not well-formed Apply expression"
        | E.Sum([],e)               => (changed:=true;rewriteBody e)
        | E.Sum(c,e)                => let
            val (c,e')=mkSum(c,rewriteBody e)
            in
                (case c of 0 => e'|_ => (changed:=true;e'))
            end
        | E.Probe(u,v)              =>
            let
            val (c',b')=mkprobe(rewriteBody u,rewriteBody v)
            in (case c'
                of 1=> (changed:=true;b')
                |_=> b'
                (*end case*))
            end
        (*************Product**************)
        | E.Prod [] => raise Fail"missing elements in product"
        | E.Prod [e1] => rewriteBody e1
        | E.Prod((E.Add(e2))::e3)=>
           (changed := true; E.Add(List.map (fn e=> E.Prod([e]@e3)) e2))
        | E.Prod((E.Sub(e2,e3))::e4)=>
            (changed :=true; E.Sub(E.Prod([e2]@e4), E.Prod([e3]@e4 )))
        | E.Prod((E.Div(e2,e3))::e4)=> (changed :=true; E.Div(E.Prod([e2]@e4), e3 ))
        | E.Prod(e1::E.Add(e2)::e3)=>
            (changed := true; E.Add(List.map (fn e=> E.Prod([e1,e]@e3)) e2))
        | E.Prod(e1::E.Sub(e2,e3)::e4)=>
            (changed :=true; E.Sub(E.Prod([e1,e2]@e4), E.Prod([e1,e3]@e4 )))
        (*************Product EPS **************)

        | E.Prod(E.Epsilon(i,j,k)::E.Apply(E.Partial d,e)::es)=>let
            val change= G.matchEps(0,d,[],[i,j,k])
            in case (change,es)
                of (1,_) =>(changed:=true; E.Const 0)
                | (_,[]) =>E.Prod[E.Epsilon(i,j,k),rewriteBody (E.Apply(E.Partial d,e))]
                |(_,_)=> let
                    val a=rewriteBody(E.Prod([E.Apply(E.Partial d,e)]@ es))
                    val (_,b)=mkProd [E.Epsilon(i,j,k),a]
                    in b end
            end
        | E.Prod(E.Epsilon(i,j,k)::E.Conv(V,alpha, h, d)::es)=>let
            val change= G.matchEps(0,d,[],[i,j,k])
            in case (change,es)
                of (1,_) =>(changed:=true; E.Const 0)
                | (_,[]) =>E.Prod[E.Epsilon(i,j,k),E.Conv(V,alpha, h, d)]
                | (_,_) =>let
                    val a=rewriteBody(E.Prod([E.Conv(V,alpha, h, d)]@ es))
                    val (_,b) = mkProd [E.Epsilon(i,j,k),a]
                    in b end
            end
        | E.Prod[(E.Epsilon(e1,e2,e3)), E.Tensor(_,[E.V i1,E.V i2])]=>
            if(e2=i1 andalso e3=i2)
            then (changed :=true;E.Const(0))
            else body

        | E.Prod(E.Epsilon eps1::ps)=> (case (G.epsToDels(E.Epsilon eps1::ps))
            of (1,e,[],_,_)      =>(changed:=true;e)(* Changed to Deltas *)
            | (1,e,sx,_,_)      =>(changed:=true;E.Sum(sx,e))
                    (* Changed to Deltas *)
            | (_,_,_,_,[])   =>  body
            | (_,_,_,epsAll,rest) => let
                val p'=rewriteBody(E.Prod rest)
                val(_,b)= mkProd(epsAll@[p'])
                in b end
            (*end case*))
        | E.Prod(E.Sum(c1,E.Prod(E.Epsilon e1::es1))::E.Sum(c2,E.Prod(E.Epsilon e2::es2))::es) =>
            (case G.epsToDels([E.Epsilon e1, E.Epsilon e2]@es1@es2@es)
                of (1,e,sx,_,_)=> (changed:=true; E.Sum(c1@c2@sx,e))
                | (_,_,_,_,_)=>let
                    val eA=rewriteBody(E.Sum(c1,E.Prod(E.Epsilon e1::es1)))
                val eB=rewriteBody(E.Prod(E.Sum(c2,E.Prod(E.Epsilon e2::es2))::es))
                val (_,e)=mkProd([eA,eB])
                in
                    e
                end
            (*end case*))
        | E.Prod[E.Delta d, E.Neg e]=> (changed:=true;E.Neg(E.Prod[E.Delta d, e]))
        | E.Prod(E.Delta d::es)=>let
            val (pre',eps, dels,post)= filterGreek(E.Delta d::es)
            val (change,a)=G.reduceDelta(eps, dels, post)
            in (case (change,a)
                of (0, _)=> E.Prod [E.Delta d,rewriteBody(E.Prod es)]
                | (_, E.Prod p)=>let
                    val (_, p') = mkProd p
                    in (changed:=true;p') end
                | _ => (changed:=true;a )
                (*end case*))
            end
      | E.Prod[e1,e2]=> let
            val (_,b)=mkProd[rewriteBody e1, rewriteBody e2]
            in b end
      | E.Prod(e::es)=>let
            val e'=rewriteBody e
            val e2=rewriteBody(E.Prod es)
            val(_,b)=(case e2
                of E.Prod p'=> mkProd([e']@p')
                |_=>mkProd [e',e2])
            in
                    b
           end                

    (*end case*))

    fun loop(body ,count) = let
        val _= testp["\n\n N =>",Int.toString(count),"--",P.printbody(body)]
        val body' = rewriteBody body

        in
            if !changed
            then  (changed := false ;loop(body',count+1))
            else (body',count)
        end
    val _ =testp["\n ******************* \n Start Normalize \n\n "]
    val (b,count) = loop(body,0)
    val _ =testp["\n Out of normalize \n",P.printbody(b),
        "\n    Final CounterXX:",Int.toString(count),"\n\n"]
    in
        (Ein.EIN{params=params, index=index, body=b},count)
    end
end
                

end (* local *)

<script type="text/javascript">//<![CDATA[
		function toggle_ffErrors() {
			var errorsblock = document.getElementById("ffErrorsBlock");
			var errorsgroup = document.getElementById("ffErrors");
			if (errorsblock.style.display == "none") {
				errorsblock.style.display = "block";
				errorsgroup.style.right = "10px";
			} else {
				errorsblock.style.display = "none";
				errorsgroup.style.right = "300px";
			}
		}
//]]></script>
<div id="ffErrors">
<a href="javascript:toggle_ffErrors();">Click to toggle</a>
<div id="ffErrorsBlock">
	<div class="error">does not end with &lt;/html&gt; tag</div>
	<div class="error">does not end with &lt;/body&gt; tag</div>
	<div class="info">The output has ended thus:    (Ein.EIN{params=params, index=index, body=b},count)
    end
end
                

end (* local *)</div>
</div></div>
</body></html>