Home My Page Projects Code Snippets Project Openings SML/NJ
Summary Activity Forums Tracker Lists Tasks Docs Surveys News SCM Files

SCM Repository

[smlnj] Annotation of /MLRISC/releases/release-110.84/library/probability.sml
ViewVC logotype

Annotation of /MLRISC/releases/release-110.84/library/probability.sml

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1136 - (view) (download)
Original Path: sml/trunk/src/MLRISC/library/probability.sml

1 : jhr 1109 (* probability.sml
2 : monnier 411 *
3 : jhr 1109 * COPYRIGHT (c) 2002 Bell Labs, Lucent Technologies.
4 :     *
5 :     * A representation of probabilities for branch prediction.
6 : monnier 411 *)
7 :    
8 : monnier 245 signature PROBABILITY =
9 : jhr 1109 sig
10 : monnier 245
11 : jhr 1109 type prob
12 : monnier 245
13 : jhr 1109 exception BadProb
14 :    
15 :     val never : prob (* 0% probability *)
16 : george 1136 val unlikely : prob (* very close to 0% *)
17 :     val likely : prob (* very close to 100% *)
18 : jhr 1109 val always : prob (* 100% probability *)
19 :    
20 : jhr 1110 val prob : (int * int) -> prob
21 : jhr 1109 val fromFreq : int list -> prob list
22 :    
23 :     val + : (prob * prob) -> prob
24 :     val - : (prob * prob) -> prob
25 :     val * : (prob * prob) -> prob
26 :     val / : (prob * int) -> prob
27 :    
28 :     val percent : int -> prob
29 :    
30 :     val toReal : prob -> real
31 :     val toString : prob -> string
32 :    
33 :     end
34 :    
35 : monnier 245 structure Probability :> PROBABILITY =
36 : jhr 1109 struct
37 : monnier 245
38 : jhr 1109 (* Probabilities are represented as positive rationals. Zero is
39 :     * represented as PROB(0w0, 0w0) and one is represented as
40 :     * PROB(0w1, 0w1). There are several invariants about PROB(n, d):
41 :     * 1) n <= d
42 :     * 2) if n = 0w0, then d = 0w0 (uniqueness of zero)
43 :     * 3) if d = 0w1, then n = 0w1 (uniqueness of one)
44 :     *)
45 :     datatype prob = PROB of (word * word)
46 : monnier 245
47 : jhr 1109 exception BadProb
48 : monnier 245
49 : jhr 1109 val never = PROB(0w0, 0w0)
50 : george 1136 val unlikely = PROB(0w1, 0w1000)
51 :     val likely = PROB(0w999, 0w1000)
52 : jhr 1109 val always = PROB(0w1, 0w1)
53 : monnier 245
54 : jhr 1109 (* Fast GCD on words. This algorithm is based on the following
55 :     * observations:
56 :     * - If u and v are both even, then gcd(u, v) = 2*gcd(u/2, v/2)
57 :     * - If u is even and v is odd, then gcd(u, v) = gcd(u/2, v)
58 :     * - If both are odd, then gcd(u, v) = gcd(abs(u-v), v)
59 :     *)
60 :     fun gcd (u : word, v : word) = let
61 :     fun isEven x = (Word.andb(x, 0w1) = 0w0)
62 :     fun divBy2 x = Word.>>(x, 0w1)
63 :     fun lp1 (g, u, v) =
64 :     if isEven(Word.orb(u, v))
65 :     then lp1 (Word.<<(g, 0w1), divBy2 u, divBy2 v)
66 :     else lp2 (g, u, v)
67 :     and lp2 (g, 0w0, v) = g*v
68 :     | lp2 (g, u, v) =
69 :     if (isEven u) then lp2 (g, divBy2 u, v)
70 :     else if (isEven v) then lp2 (g, u, divBy2 v)
71 :     else if (u < v) then lp2 (g, u, divBy2(v-u))
72 :     else lp2 (g, divBy2(u-v), v)
73 :     in
74 :     lp1 (0w1, u, v)
75 :     end
76 : monnier 245
77 : jhr 1109 fun normalize (0w0, _) = never
78 :     | normalize (n, d) = (case Word.compare(n, d)
79 :     of LESS => (case gcd(n, d)
80 :     of 0w1 => PROB(n, d)
81 : george 1136 | g => PROB(Word.div(n, g), Word.div(d, g))
82 : jhr 1109 (* end case *))
83 :     | EQUAL => always
84 :     | GREATER => raise BadProb
85 :     (* end case *))
86 :    
87 :     fun prob (n, d) =
88 : jhr 1110 if (n > d) orelse (n < 0) orelse (d <= 0)
89 : jhr 1109 then raise Domain
90 : jhr 1110 else normalize(Word.fromInt n, Word.fromInt d)
91 : monnier 245
92 : jhr 1109 fun add (PROB(n1, d1), PROB(n2, d2)) = normalize(d2*n1 + d1*n2, d1*d2)
93 : monnier 245
94 : jhr 1109 fun sub (PROB(n1, d1), PROB(n2, d2)) = let
95 :     val n1' = d2*n1
96 :     val n2' = d1*n2
97 :     in
98 :     if (n1' < n2') then raise BadProb else normalize(n1'-n2', d1*d2)
99 :     end
100 : monnier 245
101 : jhr 1109 fun mul (PROB(n1, d1), PROB(n2, d2)) = normalize (n1*n2, d1*d2)
102 : monnier 245
103 : jhr 1109 fun divide (PROB(n, d), m) = if (m <= 0)
104 :     then raise BadProb
105 :     else if (n = 0w0) then never
106 : george 1136 else normalize(n, d * Word.fromInt m)
107 : monnier 245
108 : jhr 1109 fun percent n =
109 :     if (n < 0) then raise BadProb
110 :     else normalize(Word.fromInt n, 0w100)
111 : monnier 245
112 : jhr 1109 fun fromFreq l = let
113 :     fun sum ([], tot) = tot
114 :     | sum (w::r, tot) = if (w < 0)
115 :     then raise BadProb
116 :     else sum(r, Word.fromInt w + tot)
117 :     val tot = sum (l, 0w0)
118 :     in
119 :     List.map (fn w => normalize(Word.fromInt w, tot)) l
120 :     end
121 : monnier 245
122 : jhr 1109 fun toReal (PROB(0w0, _)) = 0.0
123 :     | toReal (PROB(_, 0w1)) = 1.0
124 :     | toReal (PROB(n, d)) = let
125 :     fun toReal n = Real.fromLargeInt(Word.toLargeIntX n)
126 :     in
127 :     toReal n / toReal d
128 :     end
129 :    
130 :     fun toString (PROB(0w0, _)) = "0"
131 :     | toString (PROB(_, 0w1)) = "1"
132 :     | toString (PROB(n, d)) = let
133 :     val toStr = Word.fmt StringCvt.DEC
134 :     in
135 :     concat [toStr n, "/", toStr d]
136 :     end
137 :    
138 :     val op + = add
139 :     val op - = sub
140 :     val op * = mul
141 :     val op / = divide
142 :    
143 :     end
144 :    

root@smlnj-gforge.cs.uchicago.edu
ViewVC Help
Powered by ViewVC 1.0.0