Home My Page Projects Code Snippets Project Openings diderot
Summary Activity Tracker Tasks SCM

SCM Repository

[diderot] Annotation of /benchmarks/programs/illust-vr/bmark-diderot.diderot
ViewVC logotype

Annotation of /benchmarks/programs/illust-vr/bmark-diderot.diderot

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1581 - (view) (download)

1 : jhr 1581 // illust-vr
2 :     //
3 :     // Demonstration of "illustrative volume rendering"
4 :     //
5 :     // process output with:
6 :     // unu reshape -i illust-vr.txt -s 4 640 480 | overrgb -i - -b 0.1 0.15 0.2 -g 1.2 -o - | unu quantize -b 8 -min 0 -max 255 -o illust-vr.png
7 :    
8 :     //field#2(3)[] F = bspln3 ⊛ load("../data/vfrhand-nohip.nhdr");
9 :     field#2(3)[] F = bspln3 ⊛ load("../data/vfrhand-nohip-smooth.nrrd");
10 :    
11 :     field#0(1)[] silho = tent ⊛ load("../data/txf/silho.nrrd");
12 :     field#0(1)[] shade = tent ⊛ load("../data/txf/shade.nrrd");
13 :     field#0(2)[] rival = tent ⊛ load("../data/txf/ridgvall.nrrd");
14 :     field#0(2)[] alpha = tent ⊛ load("../data/txf/alpha-bone.nrrd"); // load("../data/txf/alpha-skin.nrrd");
15 :     field#0(1)[3] depth = tent ⊛ load("../data/txf/depth.nrrd");
16 :    
17 :     bool useShade = true; // simple shading
18 :     bool useDepth = true; // depth-cue with warm-to-cool colormap
19 :     bool useSilho = true; // curvature-based silhouettes
20 :     bool useRival = true; // curvature-based ridge & valley emphasis
21 :    
22 :     // set camera, image, and rendering parameters
23 :     vec3 camEye = [127.331, -1322.05, 272.53];
24 :     vec3 camAt = [63.0, 82.6536, 98.0];
25 :     vec3 camUp = [0.9987, 0.0459166, -0.0221267];
26 :     real camNear = -78.0;
27 :     real camFar = 78.0;
28 :     real camFOV = 5.0;
29 :     int imgResU = 640;
30 :     int imgResV = 480;
31 :     real rayStep = 0.15;
32 :    
33 :     vec3 lightVspDir = [-2.0, -3.0, -2.0];
34 :     real sthick = 0.4;
35 :     real refStep = 1.5;
36 :    
37 :     // (boilerplate) computation of camera and light info
38 :     real camDist = |camAt - camEye|;
39 :     real camVspNear = camNear + camDist;
40 :     real camVspFar = camFar + camDist;
41 :     vec3 camN = normalize(camAt - camEye);
42 :     vec3 camU = normalize(camN × camUp);
43 :     vec3 camV = camN × camU;
44 :     real camVmax = tan(camFOV*π/360.0)*camDist;
45 :     real camUmax = camVmax*real(imgResU)/real(imgResV);
46 :     vec3 lightDir = normalize(lightVspDir[0]*camU +
47 :     lightVspDir[1]*camV +
48 :     lightVspDir[2]*camN);
49 :    
50 :    
51 :     strand RayCast (int ui, int vi) {
52 :     real rayU = lerp(-camUmax, camUmax, -0.5, real(ui), real(imgResU)-0.5);
53 :     real rayV = lerp(-camVmax, camVmax, -0.5, real(vi), real(imgResV)-0.5);
54 :     vec3 rayVec = (camDist*camN + rayU*camU + rayV*camV)/camDist;
55 :     vec3 vv = -normalize(rayVec);
56 :    
57 :     real rayN = camVspNear;
58 :     real rayTransp = 1.0;
59 :     vec3 rayRGB = [0.0, 0.0, 0.0];
60 :     output vec4 outRGBA = [0.0, 0.0, 0.0, 0.0];
61 :    
62 :     update {
63 :     vec3 pos = camEye + rayN*rayVec;
64 :     if (inside (pos,F)) {
65 :     real val = F(pos);
66 :     vec3 grad = -∇F(pos);
67 :     real gmag = |grad|;
68 :     real aa = alpha([max(0.0, min(2000.0, val)), max(0.0, min(900.0, gmag))]);
69 :     if (aa > 0.0) { // we have some opacity
70 :     vec3 norm = grad/gmag;
71 :     aa = 1.0 - pow(1.0-aa, rayStep/refStep);
72 :     real gray = 1.0;
73 :     if (useShade) {
74 :     gray = gray * shade(norm • lightDir);
75 :     }
76 :     tensor[3,3] Proj = identity[3];
77 :     tensor[3,3] Gten = identity[3];
78 :     if (useSilho || useRival) {
79 :     tensor[3,3] Hess = ∇⊗∇F(pos);
80 :     Proj = identity[3] - norm⊗norm;
81 :     Gten = -(Proj•Hess•Proj)/gmag;
82 :     }
83 :     if (useSilho) {
84 :     real kv = max(0.0, min(1.0/sthick, (vv•Gten•vv)/(vv•Proj•vv)));
85 :     real vdn = vv•norm;
86 :     vdn = vdn*(1.0 + 2.0*vdn*vdn); // limit silhouette on front-facing surfaces
87 :     gray = gray*silho(max(0.0, min(2.0,
88 :     vdn^2 + (sthick*(kv - 1.0/sthick))^2 )));
89 :     }
90 :     if (useRival) {
91 :     real disc = max(0.0, sqrt(2.0*|Gten|^2 - trace(Gten)^2));
92 :     real k1 = (trace(Gten) + disc)/2.0;
93 :     real k2 = (trace(Gten) - disc)/2.0;
94 :     gray = gray*rival([min(0.55, |Gten|)/0.55, atan2(k2,k1)]);
95 :     }
96 :     vec3 matRGB = depth(lerp(0.0, 1.0, camVspNear, rayN, camVspFar))
97 :     if useDepth else [1.0,1.0,1.0];
98 :     rayRGB = rayRGB + rayTransp*aa*gray*matRGB;
99 :     rayTransp = rayTransp*(1.0 - aa);
100 :     }
101 :     }
102 :     if (rayTransp < 0.01) { // early ray termination
103 :     rayTransp = 0.0;
104 :     rayRGB = 0.9*rayRGB;
105 :     outRGBA = [rayRGB[0], rayRGB[1], rayRGB[2], 1.0-rayTransp]; /* FIXME */
106 :     stabilize;
107 :     }
108 :     if (rayN > camVspFar) {
109 :     rayRGB = 0.9*rayRGB;
110 :     outRGBA = [rayRGB[0], rayRGB[1], rayRGB[2], 1.0-rayTransp]; /* FIXME */
111 :     stabilize;
112 :     }
113 :     rayN = rayN + rayStep;
114 :     }
115 :     }
116 :    
117 :     initially [ RayCast(ui, vi) | vi in 0..(imgResV-1), ui in 0..(imgResU-1) ];

root@smlnj-gforge.cs.uchicago.edu
ViewVC Help
Powered by ViewVC 1.0.0