Home My Page Projects Code Snippets Project Openings diderot
Summary Activity Tracker Tasks SCM

SCM Repository

[diderot] View of /benchmarks/programs/mandelbrot/bmark-diderot.diderot
ViewVC logotype

View of /benchmarks/programs/mandelbrot/bmark-diderot.diderot

Parent Directory Parent Directory | Revision Log Revision Log


Revision 3349 - (download) (annotate)
Tue Oct 27 15:16:36 2015 UTC (3 years, 7 months ago) by jhr
File size: 1215 byte(s)
making copyrights consistent for all code in the repository
// bmark-diderot.diderot
//
// This code is part of the Diderot Project (http://diderot-language.cs.uchicago.edu)
//
// COPYRIGHT (c) 2015 The University of Chicago
// All rights reserved.
//
// compute Mandelbrot set image
//

// unu quantize -b 8 -i rgb.nrrd -o mandel.png 

// Global definitions
int reso = 2000;
int maxiter = 2000;
vec2 center = [-1.2, -0.3]; // [0.0,0.0] for whole thing
real fov = 0.15; // 2.0 for whole thing

// Strand definition
strand mandel (vec2 c) {
   vec2 z = [0.0, 0.0];
   int iter = 0;
   output vec3 rgb = [0.0, 0.0, 0.0];
   update  {
      z = [z[0]^2 - z[1]^2, 2.0*z[0]*z[1]] + c; // z = z^2 + c
      iter += 1;
      if (z•z > 4.0) {
         // point has escaped; set color based on iteration
         real t = 11.0*real(iter)^0.2;
         rgb = [sin(t), sin(t + 2.0*π/3.0), sin(t - 2.0*π/3.0)];
         rgb = ([1.7, 1.7, 1.7] + rgb)/2.7;
         stabilize;
      }
      else if (iter > maxiter)
         stabilize;
   }
}

// Strand initialization
initially [ mandel([lerp(center[0]-fov, center[0]+fov, 1.0, real(crIdx), real(reso)),
                    lerp(center[1]-fov, center[1]+fov, 1.0, real(ciIdx), real(reso))])
	  | ciIdx in 1..reso, crIdx in 1..reso ];

root@smlnj-gforge.cs.uchicago.edu
ViewVC Help
Powered by ViewVC 1.0.0