Home My Page Projects Code Snippets Project Openings diderot
Summary Activity Tracker Tasks SCM

SCM Repository

[diderot] Annotation of /branches/charisee/src/compiler/c-util/tree-to-c-fn.sml
ViewVC logotype

Annotation of /branches/charisee/src/compiler/c-util/tree-to-c-fn.sml

Parent Directory Parent Directory | Revision Log Revision Log


Revision 2356 - (view) (download)
Original Path: trunk/src/compiler/c-util/tree-to-c-fn.sml

1 : jhr 1640 (* tree-to-c.sml
2 :     *
3 :     * COPYRIGHT (c) 2011 The Diderot Project (http://diderot-language.cs.uchicago.edu)
4 :     * All rights reserved.
5 :     *
6 :     * Translate TreeIL to the C version of CLang.
7 :     *)
8 :    
9 :     signature TREE_VAR_TO_C =
10 :     sig
11 :     type env = CLang.typed_var TreeIL.Var.Map.map
12 :     (* translate a variable that occurs in an l-value context (i.e., as the target of an assignment) *)
13 :     val lvalueVar : env * TreeIL.var -> CLang.exp
14 :     (* translate a variable that occurs in a r-value context *)
15 :     val rvalueVar : env * TreeIL.var -> CLang.exp
16 :     (* translate a strand state variable that occurs in an l-value context *)
17 :     val lvalueStateVar : TreeIL.state_var -> CLang.exp
18 :     (* translate a strand state variable that occurs in a r-value context *)
19 :     val rvalueStateVar : TreeIL.state_var -> CLang.exp
20 :     end
21 :    
22 :     functor TreeToCFn (VarToC : TREE_VAR_TO_C) : sig
23 :    
24 :     type env = CLang.typed_var TreeIL.Var.Map.map
25 :    
26 :     val trType : TreeIL.Ty.ty -> CLang.ty
27 :    
28 :     val trBlock : env * TreeIL.block -> CLang.stm
29 :    
30 :     val trFragment : env * TreeIL.block -> env * CLang.stm list
31 :    
32 :     val trExp : env * TreeIL.exp -> CLang.exp
33 :    
34 :     (* vector indexing support. Arguments are: vector, arity, index *)
35 :     val ivecIndex : CLang.exp * int * int -> CLang.exp
36 :     val vecIndex : CLang.exp * int * int -> CLang.exp
37 :    
38 :     end = struct
39 :    
40 :     structure CL = CLang
41 :     structure N = CNames
42 :     structure IL = TreeIL
43 :     structure Op = IL.Op
44 :     structure Ty = IL.Ty
45 :     structure V = IL.Var
46 :    
47 :     datatype var = datatype CLang.typed_var
48 :     type env = CLang.typed_var TreeIL.Var.Map.map
49 :    
50 :     fun lookup (env, x) = (case V.Map.find (env, x)
51 :     of SOME(V(_, x')) => x'
52 :     | NONE => raise Fail(concat["lookup(_, ", V.name x, ")"])
53 :     (* end case *))
54 :    
55 :     (* integer literal expression *)
56 :     fun intExp (i : int) = CL.mkInt(IntInf.fromInt i)
57 :    
58 : jhr 1923 fun addrOf e = CL.mkUnOp(CL.%&, e)
59 :    
60 : jhr 1640 (* translate TreeIL types to CLang types *)
61 :     fun trType ty = (case ty
62 :     of Ty.BoolTy => CLang.T_Named "bool"
63 :     | Ty.StringTy => CL.charPtr
64 :     | Ty.IntTy => !N.gIntTy
65 :     | Ty.TensorTy[] => !N.gRealTy
66 :     | Ty.TensorTy[n] => CL.T_Named(N.vecTy n)
67 :     | Ty.TensorTy[n, m] => CL.T_Named(N.matTy(n,m))
68 :     | Ty.SeqTy(Ty.IntTy, n) => CL.T_Named(N.ivecTy n)
69 :     | Ty.SeqTy(ty, n) => CL.T_Array(trType ty, SOME n)
70 :     | Ty.AddrTy(ImageInfo.ImgInfo{ty=(_, rTy), ...}) => CL.T_Ptr(CL.T_Num rTy)
71 :     | Ty.ImageTy(ImageInfo.ImgInfo{dim, ...}) => CL.T_Ptr(CL.T_Named(N.imageTy dim))
72 :     | _ => raise Fail(concat["TreeToC.trType(", Ty.toString ty, ")"])
73 :     (* end case *))
74 :    
75 :     (* generate new variables *)
76 :     local
77 :     val count = ref 0
78 :     fun freshName prefix = let
79 :     val n = !count
80 :     in
81 :     count := n+1;
82 :     concat[prefix, "_", Int.toString n]
83 :     end
84 :     in
85 :     fun tmpVar ty = freshName "tmp"
86 :     fun freshVar prefix = freshName prefix
87 :     end (* local *)
88 :    
89 :     (* translate IL basis functions *)
90 :     local
91 :     fun mkLookup suffix = let
92 : jhr 1923 val tbl = MathFuns.Tbl.mkTable (16, Fail "basis table")
93 :     fun ins f = MathFuns.Tbl.insert tbl (f, MathFuns.toString f ^ suffix)
94 : jhr 1640 in
95 : jhr 1923 List.app ins MathFuns.allFuns;
96 :     MathFuns.Tbl.lookup tbl
97 : jhr 1640 end
98 :     val fLookup = mkLookup "f"
99 :     val dLookup = mkLookup ""
100 :     in
101 :     fun trApply (f, args) = let
102 :     val f' = if !N.doublePrecision then dLookup f else fLookup f
103 :     in
104 :     CL.mkApply(f', args)
105 :     end
106 :     end (* local *)
107 :    
108 :     (* vector indexing support. Arguments are: vector, arity, index *)
109 :     fun ivecIndex (v, n, ix) = let
110 :     val unionTy = CL.T_Named(concat["union", Int.toString n, !N.gIntSuffix, "_t"])
111 :     val e1 = CL.mkCast(unionTy, v)
112 :     val e2 = CL.mkSelect(e1, "i")
113 :     in
114 :     CL.mkSubscript(e2, intExp ix)
115 :     end
116 :    
117 :     fun vecIndex (v, n, ix) = let
118 :     val unionTy = CL.T_Named(concat["union", Int.toString n, !N.gRealSuffix, "_t"])
119 :     val e1 = CL.mkCast(unionTy, v)
120 :     val e2 = CL.mkSelect(e1, "r")
121 :     in
122 :     CL.mkSubscript(e2, intExp ix)
123 :     end
124 :    
125 :     (* matrix indexing *)
126 :     fun matIndex (m, ix, jx) =
127 :     CL.mkSubscript(CL.mkSelect(CL.mkSubscript(m, ix), "r"), jx)
128 :    
129 :     (* Translate a TreeIL operator application to a CLang expression *)
130 :     fun trOp (rator, args) = (case (rator, args)
131 :     of (Op.Add ty, [a, b]) => CL.mkBinOp(a, CL.#+, b)
132 :     | (Op.Sub ty, [a, b]) => CL.mkBinOp(a, CL.#-, b)
133 :     | (Op.Mul ty, [a, b]) => CL.mkBinOp(a, CL.#*, b)
134 :     | (Op.Div ty, [a, b]) => CL.mkBinOp(a, CL.#/, b)
135 :     | (Op.Neg ty, [a]) => CL.mkUnOp(CL.%-, a)
136 :     | (Op.Abs(Ty.IntTy), args) => CL.mkApply("abs", args)
137 :     | (Op.Abs(Ty.TensorTy[]), args) => CL.mkApply(N.fabs(), args)
138 :     | (Op.Abs ty, [a]) => raise Fail(concat["Abs<", Ty.toString ty, ">"])
139 :     | (Op.LT ty, [a, b]) => CL.mkBinOp(a, CL.#<, b)
140 :     | (Op.LTE ty, [a, b]) => CL.mkBinOp(a, CL.#<=, b)
141 :     | (Op.EQ ty, [a, b]) => CL.mkBinOp(a, CL.#==, b)
142 :     | (Op.NEQ ty, [a, b]) => CL.mkBinOp(a, CL.#!=, b)
143 :     | (Op.GTE ty, [a, b]) => CL.mkBinOp(a, CL.#>=, b)
144 :     | (Op.GT ty, [a, b]) => CL.mkBinOp(a, CL.#>, b)
145 :     | (Op.Not, [a]) => CL.mkUnOp(CL.%!, a)
146 :     | (Op.Max, args) => CL.mkApply(N.max(), args)
147 :     | (Op.Min, args) => CL.mkApply(N.min(), args)
148 :     | (Op.Clamp(Ty.TensorTy[]), args) => CL.mkApply(N.clamp 1, args)
149 :     | (Op.Clamp(Ty.TensorTy[n]), args) => CL.mkApply(N.clamp n, args)
150 :     | (Op.Lerp ty, args) => (case ty
151 :     of Ty.TensorTy[] => CL.mkApply(N.lerp 1, args)
152 :     | Ty.TensorTy[n] => CL.mkApply(N.lerp n, args)
153 :     | _ => raise Fail(concat[
154 :     "lerp<", Ty.toString ty, "> not supported"
155 :     ])
156 :     (* end case *))
157 :     | (Op.Dot d, args) => CL.E_Apply(N.dot d, args)
158 :     | (Op.MulVecMat(m, n), args) =>
159 :     if (1 < m) andalso (m < 4) andalso (m = n)
160 :     then CL.E_Apply(N.mulVecMat(m,n), args)
161 :     else raise Fail "unsupported vector-matrix multiply"
162 :     | (Op.MulMatVec(m, n), args) =>
163 :     if (1 < m) andalso (m < 4) andalso (m = n)
164 :     then CL.E_Apply(N.mulMatVec(m,n), args)
165 :     else raise Fail "unsupported matrix-vector multiply"
166 :     | (Op.MulMatMat(m, n, p), args) =>
167 :     if (1 < m) andalso (m < 4) andalso (m = n) andalso (n = p)
168 :     then CL.E_Apply(N.mulMatMat(m,n,p), args)
169 :     else raise Fail "unsupported matrix-matrix multiply"
170 :     | (Op.Cross, args) => CL.E_Apply(N.cross(), args)
171 :     | (Op.Norm(Ty.TensorTy[n]), args) => CL.E_Apply(N.length n, args)
172 : jhr 2356 | (Op.Norm(Ty.TensorTy[m,n]), args) => CL.E_Apply(N.normMat(m,n), args)
173 : jhr 1640 | (Op.Normalize d, args) => CL.E_Apply(N.normalize d, args)
174 :     | (Op.Scale(Ty.TensorTy[n]), args) => CL.E_Apply(N.scale n, args)
175 :     | (Op.PrincipleEvec ty, _) => raise Fail "PrincipleEvec unimplemented"
176 :     | (Op.Select(Ty.TupleTy tys, i), [a]) => raise Fail "Select unimplemented"
177 :     | (Op.Index(Ty.SeqTy(Ty.IntTy, n), i), [a]) => ivecIndex (a, n, i)
178 :     | (Op.Index(Ty.TensorTy[n], i), [a]) => vecIndex (a, n, i)
179 :     | (Op.Subscript(Ty.SeqTy(Ty.IntTy, n)), [v, ix]) => let
180 :     val unionTy = CL.T_Named(concat["union", Int.toString n, !N.gIntSuffix, "_t"])
181 :     val vecExp = CL.mkSelect(CL.mkCast(unionTy, v), "i")
182 :     in
183 :     CL.mkSubscript(vecExp, ix)
184 :     end
185 :     | (Op.Subscript(Ty.SeqTy(ty, n)), [v, ix]) => CL.mkSubscript(v, ix)
186 :     | (Op.Subscript(Ty.TensorTy[n]), [v, ix]) => let
187 :     val unionTy = CL.T_Named(concat["union", Int.toString n, !N.gRealSuffix, "_t"])
188 :     val vecExp = CL.mkSelect(CL.mkCast(unionTy, v), "r")
189 :     in
190 :     CL.mkSubscript(vecExp, ix)
191 :     end
192 :     | (Op.Subscript(Ty.TensorTy[_,_]), [m, ix, jx]) => matIndex (m, ix, jx)
193 :     | (Op.Subscript ty, t::(ixs as _::_)) =>
194 :     raise Fail(concat["Subscript<", Ty.toString ty, "> unsupported"])
195 :     | (Op.Ceiling d, args) => CL.mkApply(N.addTySuffix("ceil", d), args)
196 :     | (Op.Floor d, args) => CL.mkApply(N.addTySuffix("floor", d), args)
197 :     | (Op.Round d, args) => CL.mkApply(N.addTySuffix("round", d), args)
198 :     | (Op.Trunc d, args) => CL.mkApply(N.addTySuffix("trunc", d), args)
199 :     | (Op.IntToReal, [a]) => CL.mkCast(!N.gRealTy, a)
200 :     | (Op.RealToInt 1, [a]) => CL.mkCast(!N.gIntTy, a)
201 :     | (Op.RealToInt d, args) => CL.mkApply(N.vecftoi d, args)
202 :     (* FIXME: need type info *)
203 :     | (Op.ImageAddress(ImageInfo.ImgInfo{ty=(_,rTy), ...}), [a]) => let
204 :     val cTy = CL.T_Ptr(CL.T_Num rTy)
205 :     in
206 :     CL.mkCast(cTy, CL.mkIndirect(a, "data"))
207 :     end
208 :     | (Op.LoadVoxels(info, 1), [a]) => let
209 :     val realTy as CL.T_Num rTy = !N.gRealTy
210 :     val a = CL.E_UnOp(CL.%*, a)
211 :     in
212 :     if (rTy = ImageInfo.sampleTy info)
213 :     then a
214 :     else CL.E_Cast(realTy, a)
215 :     end
216 :     | (Op.LoadVoxels _, [a]) =>
217 :     raise Fail("impossible " ^ Op.toString rator)
218 :     | (Op.PosToImgSpace(ImageInfo.ImgInfo{dim, ...}), [img, pos]) =>
219 :     CL.mkApply(N.toImageSpace dim, [img, pos])
220 :     | (Op.TensorToWorldSpace(info, ty), [v, x]) =>
221 :     CL.mkApply(N.toWorldSpace ty, [v, x])
222 :     | (Op.LoadImage info, [a]) =>
223 :     raise Fail("impossible " ^ Op.toString rator)
224 :     | (Op.Inside(ImageInfo.ImgInfo{dim, ...}, s), [pos, img]) =>
225 :     CL.mkApply(N.inside dim, [pos, img, intExp s])
226 :     | (Op.Input(ty, desc, name), []) =>
227 :     raise Fail("impossible " ^ Op.toString rator)
228 :     | (Op.InputWithDefault(ty, desc, name), [a]) =>
229 :     raise Fail("impossible " ^ Op.toString rator)
230 :     | _ => raise Fail(concat[
231 :     "unknown or incorrect operator ", Op.toString rator
232 :     ])
233 :     (* end case *))
234 :    
235 :     fun trExp (env, e) = (case e
236 :     of IL.E_State x => VarToC.rvalueStateVar x
237 :     | IL.E_Var x => VarToC.rvalueVar (env, x)
238 :     | IL.E_Lit(Literal.Int n) => CL.mkIntTy(n, !N.gIntTy)
239 :     | IL.E_Lit(Literal.Bool b) => CL.mkBool b
240 :     | IL.E_Lit(Literal.Float f) => CL.mkFlt(f, !N.gRealTy)
241 :     | IL.E_Lit(Literal.String s) => CL.mkStr s
242 :     | IL.E_Op(rator, args) => trOp (rator, trExps(env, args))
243 :     | IL.E_Apply(f, args) => trApply(f, trExps(env, args))
244 :     | IL.E_Cons(Ty.TensorTy[n], args) => CL.mkApply(N.mkVec n, trExps(env, args))
245 :     | IL.E_Cons(ty, _) => raise Fail(concat["E_Cons(", Ty.toString ty, ", _) in expression"])
246 :     (* end case *))
247 :    
248 :     and trExps (env, exps) = List.map (fn exp => trExp(env, exp)) exps
249 :    
250 :     (* translate an expression to a variable form; return the variable and the
251 :     * (optional) declaration.
252 :     *)
253 :     fun expToVar (env, ty, name, exp) = (case trExp(env, exp)
254 :     of x as CL.E_Var _ => (x, [])
255 :     | exp => let
256 :     val x = freshVar name
257 :     in
258 :     (CL.mkVar x, [CL.mkDecl(ty, x, SOME(CL.I_Exp exp))])
259 :     end
260 :     (* end case *))
261 :    
262 :     (* translate a print statement *)
263 :     fun trPrint (env, tys, args) = let
264 :     (* assemble the format string by analysing the types and argument expressions *)
265 :     fun mkFmt (Ty.StringTy, IL.E_Lit(Literal.String s), (stms, fmt, args)) =
266 :     (stms, s::fmt, args)
267 :     | mkFmt (ty, exp, (stms, fmt, args)) = let
268 :     fun mk (f, e) = (stms, f::fmt, e::args)
269 :     in
270 :     case ty
271 :     of Ty.BoolTy => mk(
272 :     "%s",
273 :     CL.mkCond(trExp(env, exp), CL.mkStr "true", CL.mkStr "false"))
274 :     | Ty.StringTy => mk("%s", trExp(env, exp))
275 :     | Ty.IntTy => mk(!N.gIntFormat, trExp(env, exp))
276 :     | Ty.TensorTy[] => mk("%f", trExp(env, exp))
277 :     | Ty.TensorTy[n] => let
278 :     val (x, stm) = expToVar (env, trType ty, "vec", exp)
279 :     val elems = List.tabulate (n, fn i => vecIndex (x, n, i))
280 :     val (fmt, args) = mkSeqFmt (Ty.TensorTy[], elems, fmt, args)
281 :     in
282 :     (stm@stms, fmt, args)
283 :     end
284 :     (*
285 :     | Ty.TensorTy[n, m] =>
286 :     *)
287 :     | Ty.SeqTy(elemTy, n) => let
288 :     val (x, stm) = expToVar (env, trType ty, "vec", exp)
289 :     val elems = List.tabulate (n, fn i => ivecIndex (x, n, i))
290 :     val (fmt, args) = mkSeqFmt (elemTy, elems, fmt, args)
291 :     in
292 :     (stm@stms, fmt, args)
293 :     end
294 :     | _ => raise Fail(concat["TreeToC.trPrint(", Ty.toString ty, ")"])
295 :     (* end case *)
296 :     end
297 :     and mkElemFmt (elemTy, elem, (fmt, args)) = (case elemTy
298 :     of Ty.BoolTy =>
299 :     ("%s"::fmt, CL.mkCond(elem, CL.mkStr "true", CL.mkStr "false")::args)
300 :     | Ty.StringTy => ("%s"::fmt, elem::args)
301 :     | Ty.IntTy => (!N.gIntFormat::fmt, elem::args)
302 :     | Ty.TensorTy[] => ("%f"::fmt, elem::args)
303 :     | Ty.TensorTy[n] => let
304 :     val elems = List.tabulate (n, fn i => vecIndex (elem, n, i))
305 :     in
306 :     mkSeqFmt (Ty.TensorTy[], elems, fmt, args)
307 :     end
308 :     (*
309 :     | Ty.TensorTy[n, m] =>
310 :     *)
311 :     | Ty.SeqTy(elemTy, n) => let
312 :     val elems = List.tabulate (n, fn i => ivecIndex (elem, n, i))
313 :     in
314 :     mkSeqFmt (elemTy, elems, fmt, args)
315 :     end
316 :     | _ => raise Fail(concat["TreeToC.mkElemFmt(", Ty.toString elemTy, ")"])
317 :     (* end case *))
318 :     and mkSeqFmt (elemTy, elems, fmt, args) = let
319 :     fun mk (elem, acc) = mkFmt(elemTy, elem, acc)
320 :     val (seqFmt, args) =
321 :     List.foldr
322 :     (fn (elem, acc) => mkElemFmt(elemTy, elem, acc))
323 :     ([], args) elems
324 :     in
325 :     ("<" :: String.concatWith "," seqFmt :: ">" :: fmt, args)
326 :     end
327 :     val (stms, fmt, args) = ListPair.foldr mkFmt ([], [], []) (tys, args)
328 :     val stm = CL.mkCall("fprintf", CL.mkVar "stderr" :: CL.mkStr(String.concat fmt) :: args)
329 :     in
330 :     List.rev (stm :: stms)
331 :     end
332 :    
333 :     fun trAssign (env, lhs, rhs) = (
334 :     (* certain rhs forms, such as those that return a matrix,
335 :     * require a function call instead of an assignment
336 :     *)
337 :     case rhs
338 :     of IL.E_Op(Op.Add(Ty.TensorTy[m,n]), args) =>
339 :     [CL.mkCall(N.addMat(m,n), lhs :: trExps(env, args))]
340 :     | IL.E_Op(Op.Sub(Ty.TensorTy[m,n]), args) =>
341 :     [CL.mkCall(N.subMat(m,n), lhs :: trExps(env, args))]
342 :     | IL.E_Op(Op.Neg(Ty.TensorTy[m,n]), args) =>
343 :     [CL.mkCall(N.scaleMat(m,n), lhs :: intExp ~1 :: trExps(env, args))]
344 :     | IL.E_Op(Op.Scale(Ty.TensorTy[m,n]), args) =>
345 :     [CL.mkCall(N.scaleMat(m,n), lhs :: trExps(env, args))]
346 :     | IL.E_Op(Op.MulMatMat(m,n,p), args) =>
347 :     [CL.mkCall(N.mulMatMat(m,n,p), lhs :: trExps(env, args))]
348 :     | IL.E_Op(Op.EigenVals2x2, [m]) => let
349 :     val (m, stms) = expToVar (env, CL.T_Named(N.matTy(2,2)), "m", m)
350 :     in
351 :     stms @ [CL.mkCall(N.evals2x2, [
352 :     lhs,
353 :     matIndex (m, CL.mkInt 0, CL.mkInt 0),
354 :     matIndex (m, CL.mkInt 0, CL.mkInt 1),
355 :     matIndex (m, CL.mkInt 1, CL.mkInt 1)
356 :     ])]
357 :     end
358 :     | IL.E_Op(Op.EigenVals3x3, [m]) => let
359 :     val (m, stms) = expToVar (env, CL.T_Named(N.matTy(3,3)), "m", m)
360 :     in
361 :     stms @ [CL.mkCall(N.evals3x3, [
362 :     lhs,
363 :     matIndex (m, CL.mkInt 0, CL.mkInt 0),
364 :     matIndex (m, CL.mkInt 0, CL.mkInt 1),
365 :     matIndex (m, CL.mkInt 0, CL.mkInt 2),
366 :     matIndex (m, CL.mkInt 1, CL.mkInt 1),
367 :     matIndex (m, CL.mkInt 1, CL.mkInt 2),
368 :     matIndex (m, CL.mkInt 2, CL.mkInt 2)
369 :     ])]
370 :     end
371 :     | IL.E_Op(Op.Identity n, args) =>
372 :     [CL.mkCall(N.identityMat n, [lhs])]
373 :     | IL.E_Op(Op.Zero(Ty.TensorTy[m,n]), args) =>
374 :     [CL.mkCall(N.zeroMat(m,n), [lhs])]
375 :     | IL.E_Op(Op.TensorToWorldSpace(info, ty as Ty.TensorTy[_,_]), args) =>
376 :     [CL.mkCall(N.toWorldSpace ty, lhs :: trExps(env, args))]
377 :     | IL.E_Op(Op.LoadVoxels(info, n), [a]) =>
378 :     if (n > 1)
379 :     then let
380 :     val stride = ImageInfo.stride info
381 :     val rTy = ImageInfo.sampleTy info
382 :     val vp = freshVar "vp"
383 :     val needsCast = (CL.T_Num rTy <> !N.gRealTy)
384 :     fun mkLoad i = let
385 :     val e = CL.mkSubscript(CL.mkVar vp, intExp(i*stride))
386 :     in
387 :     if needsCast then CL.mkCast(!N.gRealTy, e) else e
388 :     end
389 :     in [
390 :     CL.mkDecl(CL.T_Ptr(CL.T_Num rTy), vp, SOME(CL.I_Exp(trExp(env, a)))),
391 :     CL.mkAssign(lhs,
392 :     CL.mkApply(N.mkVec n, List.tabulate (n, mkLoad)))
393 :     ] end
394 :     else [CL.mkAssign(lhs, trExp(env, rhs))]
395 :     | IL.E_Cons(Ty.TensorTy[n,m], args) => let
396 :     (* matrices are represented as arrays of union<d><ty>_t vectors *)
397 :     fun doRows (_, []) = []
398 :     | doRows (i, e::es) =
399 :     CL.mkAssign(CL.mkSelect(CL.mkSubscript(lhs, intExp i), "v"), e)
400 :     :: doRows (i+1, es)
401 :     in
402 :     doRows (0, trExps(env, args))
403 :     end
404 :     | IL.E_Var x => (case IL.Var.ty x
405 :     of Ty.TensorTy[n,m] => [CL.mkCall(N.copyMat(n,m), [lhs, VarToC.rvalueVar(env, x)])]
406 :     | _ => [CL.mkAssign(lhs, VarToC.rvalueVar(env, x))]
407 :     (* end case *))
408 :     | _ => [CL.mkAssign(lhs, trExp(env, rhs))]
409 :     (* end case *))
410 :    
411 :     fun trMultiAssign (env, lhs, IL.E_Op(rator, args)) = (case (lhs, rator, args)
412 :     of ([vals, vecs], Op.EigenVecs2x2, [m]) => let
413 :     val (m, stms) = expToVar (env, CL.T_Named(N.matTy(2,2)), "m", m)
414 :     in
415 :     stms @ [CL.mkCall(N.evecs2x2, [
416 :     vals, vecs,
417 :     matIndex (m, CL.mkInt 0, CL.mkInt 0),
418 :     matIndex (m, CL.mkInt 0, CL.mkInt 1),
419 :     matIndex (m, CL.mkInt 1, CL.mkInt 1)
420 :     ])]
421 :     end
422 :     | ([vals, vecs], Op.EigenVecs3x3, [m]) => let
423 :     val (m, stms) = expToVar (env, CL.T_Named(N.matTy(3,3)), "m", m)
424 :     in
425 :     stms @ [CL.mkCall(N.evecs3x3, [
426 :     vals, vecs,
427 :     matIndex (m, CL.mkInt 0, CL.mkInt 0),
428 :     matIndex (m, CL.mkInt 0, CL.mkInt 1),
429 :     matIndex (m, CL.mkInt 0, CL.mkInt 2),
430 :     matIndex (m, CL.mkInt 1, CL.mkInt 1),
431 :     matIndex (m, CL.mkInt 1, CL.mkInt 2),
432 :     matIndex (m, CL.mkInt 2, CL.mkInt 2)
433 :     ])]
434 :     end
435 :     | ([], Op.Print tys, args) => trPrint (env, tys, args)
436 :     | _ => raise Fail "bogus multi-assignment"
437 :     (* end case *))
438 :     | trMultiAssign (env, lhs, rhs) = raise Fail "bogus multi-assignment"
439 :    
440 :     fun trLocals (env : env, locals) =
441 :     List.foldl
442 :     (fn (x, env) => V.Map.insert(env, x, V(trType(V.ty x), V.name x)))
443 :     env locals
444 :    
445 :     (* generate code to check the status of runtime-system calls *)
446 :     fun checkSts mkDecl = let
447 :     val sts = freshVar "sts"
448 :     in
449 :     mkDecl sts @
450 :     [CL.mkIfThen(
451 :     CL.mkBinOp(CL.mkVar "DIDEROT_OK", CL.#!=, CL.mkVar sts),
452 :     CL.mkCall("exit", [intExp 1]))]
453 :     end
454 :    
455 :     fun trStms (env, stms) = let
456 :     fun trStmt (env, stm) = (case stm
457 :     of IL.S_Comment text => [CL.mkComment text]
458 :     | IL.S_Assign([x], exp) => trAssign (env, VarToC.lvalueVar (env, x), exp)
459 :     | IL.S_Assign(xs, exp) =>
460 :     trMultiAssign (env, List.map (fn x => VarToC.lvalueVar (env, x)) xs, exp)
461 :     | IL.S_IfThen(cond, thenBlk) =>
462 :     [CL.mkIfThen(trExp(env, cond), trBlk(env, thenBlk))]
463 :     | IL.S_IfThenElse(cond, thenBlk, elseBlk) =>
464 :     [CL.mkIfThenElse(trExp(env, cond),
465 :     trBlk(env, thenBlk),
466 :     trBlk(env, elseBlk))]
467 :     | IL.S_New _ => raise Fail "new not supported yet" (* FIXME *)
468 :     | IL.S_Save([x], exp) => trAssign (env, VarToC.lvalueStateVar x, exp)
469 :     | IL.S_Save(xs, exp) =>
470 :     trMultiAssign (env, List.map VarToC.lvalueStateVar xs, exp)
471 :     | IL.S_LoadImage(lhs, dim, name) => checkSts (fn sts => let
472 :     val lhs = VarToC.lvalueVar (env, lhs)
473 :     val name = trExp(env, name)
474 :     val imgTy = CL.T_Named(N.imageTy dim)
475 :     val loadFn = N.loadImage dim
476 :     in [
477 :     CL.mkDecl(
478 :     CL.T_Named N.statusTy, sts,
479 :     SOME(CL.I_Exp(CL.E_Apply(loadFn, [name, CL.mkUnOp(CL.%&, lhs)]))))
480 :     ] end)
481 :     | IL.S_Input(lhs, name, desc, optDflt) => let
482 :     val inputFn = N.input(V.ty lhs)
483 :     val lhs = VarToC.lvalueVar (env, lhs)
484 :     val (initCode, hasDflt) = (case optDflt
485 :     of SOME e => ([CL.mkAssign(lhs, trExp(env, e))], true)
486 :     | NONE => ([], false)
487 :     (* end case *))
488 :     val code = [CL.mkCall(inputFn, [
489 :     CL.mkVar "opts",
490 :     CL.mkStr name,
491 :     CL.mkStr desc,
492 :     CL.mkUnOp(CL.%&, lhs),
493 :     CL.mkBool hasDflt])]
494 :     in
495 :     initCode @ code
496 :     end
497 :     | IL.S_Exit args => [CL.mkReturn NONE]
498 :     | IL.S_Active => [CL.mkReturn(SOME(CL.mkVar N.kActive))]
499 :     | IL.S_Stabilize => [CL.mkReturn(SOME(CL.mkVar N.kStabilize))]
500 :     | IL.S_Die => [CL.mkReturn(SOME(CL.mkVar N.kDie))]
501 :     (* end case *))
502 :     in
503 :     List.foldr (fn (stm, stms) => trStmt(env, stm)@stms) [] stms
504 :     end
505 :    
506 :     and trBlk (env, IL.Block{locals, body}) = let
507 :     val env = trLocals (env, locals)
508 :     val stms = trStms (env, body)
509 :     fun mkDecl (x, stms) = (case V.Map.find (env, x)
510 :     of SOME(V(ty, x')) => CL.mkDecl(ty, x', NONE) :: stms
511 :     | NONE => raise Fail(concat["mkDecl(", V.name x, ", _)"])
512 :     (* end case *))
513 :     val stms = List.foldr mkDecl stms locals
514 :     in
515 :     CL.mkBlock stms
516 :     end
517 :    
518 :     fun trFragment (env, IL.Block{locals, body}) = let
519 :     val env = trLocals (env, locals)
520 :     val stms = trStms (env, body)
521 :     fun mkDecl (x, stms) = (case V.Map.find (env, x)
522 :     of SOME(V(ty, x')) => CL.mkDecl(ty, x', NONE) :: stms
523 :     | NONE => raise Fail(concat["mkDecl(", V.name x, ", _)"])
524 :     (* end case *))
525 :     val stms = List.foldr mkDecl stms locals
526 :     in
527 :     (env, stms)
528 :     end
529 :    
530 :     val trBlock = trBlk
531 :    
532 :     end

root@smlnj-gforge.cs.uchicago.edu
ViewVC Help
Powered by ViewVC 1.0.0