Home My Page Projects Code Snippets Project Openings diderot
Summary Activity Tracker Tasks SCM

SCM Repository

[diderot] View of /branches/charisee/src/compiler/translate/translate-basis.sml
ViewVC logotype

View of /branches/charisee/src/compiler/translate/translate-basis.sml

Parent Directory Parent Directory | Revision Log Revision Log


Revision 2515 - (download) (annotate)
Mon Dec 2 03:42:14 2013 UTC (5 years, 11 months ago) by cchiw
File size: 14975 byte(s)
 
(* translate-basis.sml
 *
 * COPYRIGHT (c) 2010 The Diderot Project (http://diderot-language.cs.uchicago.edu)
 * All rights reserved.
 *
 * Translation for basis operations in Simple AST to HighIL code
 *)

structure TranslateBasis : sig

  (* translate(lhs, f, mvs, args) translates the application of f (specialized
   * to the instantiated meta variables mvs) to a list of SSA assignments in
   * reverse order.
   *)
    val translate : (HighIL.var * Var.var * SimpleTypes.meta_arg list * HighIL.var list)
          -> HighIL.assignment list

  end = struct

    structure BV = BasisVars
    structure IL = HighIL
    structure DstTy = HighILTypes
    structure Op = HighOps
    structure Ty = SimpleTypes
    structure VTbl = Var.Tbl

    structure mk= mkOperators

    fun trType (Ty.TY ty) = TranslateTy.tr ty
      | trType _ = raise Fail "expected type"
    fun dimVarToInt (Ty.DIM d) = d
      | dimVarToInt _ = raise Fail "expected dim"
    fun dimVarToTensor dv = DstTy.tensorTy[dimVarToInt dv]
    fun dimVarToMatrix dv = let
          val d = dimVarToInt dv
          in
            DstTy.tensorTy[d, d]        (* square matrix type *)
          end
    fun shapeVarToTensor (Ty.SHAPE shp) = DstTy.tensorTy shp
      | shapeVarToTensor _ = raise Fail "expected shape"

    fun assign (y, rator, xs) = [IL.ASSGN(y, IL.OP(rator, xs))]

    fun basisFn name (y, [], xs) = [IL.ASSGN(y, IL.APPLY(name, xs))]

    fun simpleOp rator (y, [], xs) = assign (y, rator, xs)

    fun tensorOp rator (y, [sv], xs) = assign (y, rator(shapeVarToTensor sv), xs)

    fun vectorOp rator (y, [dv], xs) = assign (y, rator(dimVarToTensor dv), xs)

    fun kernel h (y, [], []) = assign(y, Op.Kernel(h, 0), [])

  (* utility functions for synthesizing eigenvector/eigenvalue code *)
    fun eigenVec (rator, dim) = let
          val ty = DstTy.SeqTy(DstTy.realTy, dim)
          in
            fn (y, _, [m]) => let
                val v = IL.Var.new("evals", ty)
                in
                  [IL.MASSGN([v, y], rator, [m])]
                end
          end
    fun eigenVal (rator, dim) = let
          val ty = DstTy.SeqTy(DstTy.vecTy dim, dim)
          in
            fn (y, _, [m]) => let
                val v = IL.Var.new("evecs", ty)
                in
                  [IL.MASSGN([y, v], rator, [m])]
                end
          end

    fun assignEin (y, rator, xs) = IL.ASSGN(y, IL.EINAPP(rator, xs))

    fun  simpleEOp rator (y, _,xs) = [assignEin(y, rator, xs)]





(* shape is an int list, DIM is in int|variable, k-level of differntiation *)

 (* build a table that maps Basis variables to their translation functions *)
    val tbl : ((IL.var * Ty.meta_arg list * IL.var list) -> IL.assignment list) VTbl.hash_table = let
          val tbl = VTbl.mkTable (128, Fail "Translate table")
          val insert = VTbl.insert tbl
          in
            List.app insert [
                (BV.lt_ii,              simpleOp(Op.LT DstTy.IntTy)),
                (BV.lt_rr,              simpleOp(Op.LT DstTy.realTy)),
                (BV.lte_ii,             simpleOp(Op.LTE DstTy.IntTy)),
                (BV.lte_rr,             simpleOp(Op.LTE DstTy.realTy)),
                (BV.gte_ii,             simpleOp(Op.GTE DstTy.IntTy)),
                (BV.gte_rr,             simpleOp(Op.GTE(DstTy.realTy))),
                (BV.gt_ii,              simpleOp(Op.GT DstTy.IntTy)),
                (BV.gt_rr,              simpleOp(Op.GT(DstTy.realTy))),
                (BV.equ_bb,             simpleOp(Op.EQ DstTy.BoolTy)),
                (BV.equ_ii,             simpleOp(Op.EQ DstTy.IntTy)),
                (BV.equ_ss,             simpleOp(Op.EQ DstTy.StringTy)),
                (BV.equ_rr,             simpleOp(Op.EQ(DstTy.realTy))),
                (BV.neq_bb,             simpleOp(Op.NEQ DstTy.BoolTy)),
                (BV.neq_ii,             simpleOp(Op.NEQ DstTy.IntTy)),
                (BV.neq_ss,             simpleOp(Op.NEQ DstTy.StringTy)),
                (BV.neq_rr,             simpleOp(Op.NEQ(DstTy.realTy))),
                (BV.add_ii,             simpleOp Op.IAdd),
                (BV.add_tt,             fn (y, [shp], xs) => let
                                        val ty1 as DstTy.TensorTy dd1 = shapeVarToTensor shp
                                        val rator =mk.addTen(dd1)
                                        in
                                            [assignEin(y, rator,xs)]
                                        end),
                (BV.add_ff,             fn (y, [_,Ty.DIM d, Ty.SHAPE dd], xs) =>
                                            [assignEin(y, mk.addField(d, dd),xs)]),

                (BV.add_fr,             fn (y, [_,Ty.DIM d], [f,s]) =>
                                            [assignEin(y, mk.addTenField(d),[s,f])]),

                (BV.add_rf,             fn (y, [_,Ty.DIM d], xs) =>
                                            [assignEin(y, mk.addTenField(d),xs)]),


                (BV.sub_ii,             simpleOp Op.ISub),
                (BV.sub_tt,             fn (y, [shp], xs) => let
                                        val ty1 as DstTy.TensorTy dd1 = shapeVarToTensor shp
                                        val rator =mk.subTen(dd1)
                                        in
                                            [assignEin(y, rator,xs)]
                                        end),
                (BV.sub_ff,             fn (y, [_,Ty.DIM d, Ty.SHAPE dd], xs) =>
                                              [assignEin(y, mk.subField(d, dd),xs)]),


                (BV.sub_fr,             fn (y, [_,Ty.DIM d], xs) =>
                                            [assignEin(y, mk.subFieldTen(d),xs)]),

                (BV.sub_rf,             fn (y, [_,Ty.DIM d], xs) =>
                                          [assignEin(y, mk.subTenField(d),xs)]),

                (BV.mul_ii,             simpleOp Op.IMul),
                (BV.mul_rr,             fn (y,_,args) => [assignEin(y, mk.prodScalar,args)]),
                (BV.mul_rt,             fn (y, [shp], xs) => let
                                        val ty1 as DstTy.TensorTy dd1 = shapeVarToTensor shp
                                        val rator =mk.scaleTen(dd1)
                                        in
                                            [assignEin(y, rator,xs)]
                                        end),
                (BV.mul_tr,             fn (y, [shp], [t, r]) => let
                                          val ty1 as DstTy.TensorTy dd1 = shapeVarToTensor shp
                                          val rator = mk.scaleTen dd1
                                          in
                                            [assignEin(y, rator,[r,t])]
                                          end),
                (BV.mul_rf,             fn (y, [_,Ty.DIM d, Ty.SHAPE dd], xs) =>
                                            [assignEin(y, mk.scaleField(d, dd),xs)]),
                (BV.mul_fr,             fn (y, [_,Ty.DIM d, Ty.SHAPE dd], [f, s]) =>
                                            [assignEin(y, mk.scaleField(d, dd),[s,f])]),
                (BV.div_ii,             simpleOp Op.IDiv),
                (BV.div_rr,             fn (y,_,args) => [assignEin(y, mk.divScalar,args)]),
                (BV.div_tr,             fn (y, [shp], xs) => let
                                        val ty1 as DstTy.TensorTy dd1 = shapeVarToTensor shp
                                        val rator =mk.divTen(dd1)
                                        in
                                            [assignEin(y, rator,xs)]
                                        end),
                (BV.div_fr,             fn (y, [_,Ty.DIM d, Ty.SHAPE dd], xs) =>
                                            [assignEin(y, mk.divideField(d, dd),xs)]),
                (BV.exp_ri,             simpleOp(Op.Power)),
                (BV.exp_rr,             basisFn MathFuns.pow),
                (BV.curl2D,              simpleEOp mk.curl2d),
                (BV.curl3D,              simpleEOp mk.curl3d),
                (BV.convolve_vk,        fn (y, [_, Ty.DIM d,  Ty.SHAPE dd], xs) =>
                                           [assignEin(y, mk.conv(d, dd),xs)]),
                (BV.convolve_kv,        fn (y, [_, Ty.DIM d,  Ty.SHAPE dd], [k, v]) =>
                                             [assignEin(y, mk.conv(d, dd),[v,k])]),
                (BV.neg_i,              simpleOp Op.INeg),
                (BV.neg_t,              fn (y, [shp], xs) => let
                                        val ty1 as DstTy.TensorTy dd1 = shapeVarToTensor shp
                                        val rator =mk.negTen(dd1)
                                        in
                                            [assignEin(y, rator,xs)]
                                        end),
                (BV.neg_f,              fn (y, [_,Ty.DIM d, Ty.SHAPE dd], xs) =>
                                        [assignEin(y, mk.negField(d, dd),xs)]),
                (BV.op_probe,           fn (y, [_, Ty.DIM d, Ty.SHAPE dd], xs) => 
					    [assignEin(y, (mk.probe(dd,d)),xs)]),
                (BV.op_D,               fn (y, [_, Ty.DIM d], xs) =>  [assignEin(y, mk.grad([d]),xs)]),
               
                (BV.op_Dotimes,         fn (y, [_, Ty.DIM d1, Ty.SHAPE dd, Ty.DIM d2], xs) => let
                                    val x= print (String.concat[" d1:",Int.toString(d1)," d2:",Int.toString(d2),
                                        " shape:",Int.toString(length(dd)), "\n"])
                        in
                                    [assignEin(y, mk.dotimes(d1, dd@[d2]),xs)] end ),
                (BV.op_Ddot,         fn (y, [_, Ty.DIM d1,  Ty.SHAPE dd, Ty.DIM d2], xs) =>
                                        [assignEin(y, mk.divergence(d1, dd),xs)]),


                (BV.op_norm,            fn (y, [sv], xs) => (case shapeVarToTensor sv
                                           of DstTy.TensorTy[] => assign(y, Op.Abs DstTy.realTy, xs)
                                            | ty => assign(y, Op.Norm ty, xs)
                                          (* end case *))),
                (BV.op_not,             simpleOp Op.Not),
                (BV.op_cross,            simpleEOp mk.crossProduct),
                (BV.op_outer,           fn (y, [Ty.DIM d1, Ty.DIM d2], xs) =>
                                [assignEin(y, (mk.outerProduct(d1, d2)), xs)]),
                (BV.op_inner,           fn (y, [sh1, sh2, _], xs) => let
                                            val ty1 as DstTy.TensorTy dd1 = shapeVarToTensor sh1
                                            val ty2 as DstTy.TensorTy dd2 = shapeVarToTensor sh2
                                        in
                                            [assignEin(y, (mk.innerProduct(dd1,dd2)),xs)]
                                        end),
                (BV.op_colon,           fn (y, [sh1, sh2, _], xs) => let
                                            val ty1 as DstTy.TensorTy dd1 = shapeVarToTensor sh1
                                            val ty2 as DstTy.TensorTy dd2 = shapeVarToTensor sh2
                                        in
                                            [assignEin(y, (mk.doubleDot(dd1,dd2)),xs)]
                                        end),
                (BV.fn_inside,          fn (y, [_, Ty.DIM d, _], xs) => assign(y, Op.Inside d, xs)),
                (BV.clamp_rrr,          simpleOp (Op.Clamp DstTy.realTy)),
                (BV.clamp_vvv,          vectorOp Op.Clamp),
                (BV.lerp3,              tensorOp Op.Lerp),
                (BV.lerp5,              fn (y, [sv], [a, b, x0, x, x1]) => let 
                                          val t1 = IL.Var.new("t1", DstTy.realTy)
                                          val t2 = IL.Var.new("t2", DstTy.realTy)
                                          val t3 = IL.Var.new("t3", DstTy.realTy)
                                          in [
                                            assignEin(t1, mk.subScalar,[x,x0]),
                                            assignEin(t2, mk.subScalar,[x1,x0]),
                                            assignEin(t3, mk.divScalar,[t1,t2]),
                                            IL.ASSGN(y,  IL.OP(Op.Lerp(shapeVarToTensor sv), [a, b, t3]))
                                          ] end),
                (BV.evals2x2,           eigenVal (Op.Eigen2x2, 2)),
                (BV.evals3x3,           eigenVal (Op.Eigen3x3, 3)),
                (BV.evecs2x2,           eigenVec (Op.Eigen2x2, 2)),
                (BV.evecs3x3,           eigenVec (Op.Eigen3x3, 3)),
                (BV.fn_max,             simpleOp Op.Max),
                (BV.fn_min,             simpleOp Op.Min),

                (*  modulate is vector * vector pointwise multiplication *)
                (BV.fn_modulate,        fn (y,[Ty.DIM dd1], xs) =>
                                [assignEin(y, (mk.modulate dd1),xs)]),
                (BV.fn_normalize,       vectorOp Op.Normalize),
                (BV.fn_principleEvec,   vectorOp Op.PrincipleEvec),
                (BV.fn_trace,           fn (y, [Ty.DIM d], xs) =>
					  [assignEin(y,(mk.trace d), xs)]),
                (BV.fn_transpose,       fn (y, [Ty.DIM d1, Ty.DIM d2], xs) =>
					  [assignEin(y, (mk.transpose [d1,d2]), xs)]),
                (BV.kn_bspln3,          kernel Kernel.bspln3),
                (BV.kn_bspln5,          kernel Kernel.bspln5),
                (BV.kn_ctmr,            kernel Kernel.ctmr),
                (BV.kn_c2ctmr,          kernel Kernel.ctmr),
                (BV.kn_c4hexic,         kernel Kernel.c4hexic),
                (BV.kn_tent,            kernel Kernel.tent),
                (BV.kn_c1tent,          kernel Kernel.tent),
                (BV.i2r,                simpleOp Op.IntToReal),
                (BV.identity,           fn (y, [Ty.DIM d], xs) =>
					  [assignEin(y, (mk.identity d), xs)]),
             (*   (BV.zero,               fn (y, [sv], []) =>
                                          assign(y, Op.Zero(shapeVarToTensor sv), [])),*)
                (BV.subscript,          fn (y, [ty, Ty.DIM d], xs) =>
					  assign (y, Op.SeqSub(DstTy.SeqTy(trType ty, d)), xs))
(*,
                  (BV.dynSubscript,     fn (y, [tv], args) =>
                                          assign(y, Op.SeqSub(DstTy.DynSeqTy(pruneTy tv)), args))
*)
                ];
          (* add C math functions *)
            List.app (fn (n, x) => insert(x, basisFn n)) BV.mathFns;
            tbl
          end

    fun translate (y, f, mvs, xs) = (case VTbl.find tbl f
           of SOME transFn => transFn(y, mvs, xs)
            | NONE => raise Fail("TranslateBasis.translate: unknown basis function " ^ Var.uniqueNameOf f)
          (* end case *))
handle ex => (print(concat["translate (", IL.Var.toString y, ", ",
Var.uniqueNameOf f, ", ...)\n"]); raise ex)

  end

root@smlnj-gforge.cs.uchicago.edu
ViewVC Help
Powered by ViewVC 1.0.0