Home My Page Projects Code Snippets Project Openings diderot
 Summary Activity Tracker Tasks SCM

# SCM Repository

[diderot] View of /branches/fem/test/mandel.diderot
 [diderot] / branches / fem / test / mandel.diderot

# View of /branches/fem/test/mandel.diderot

Revision 1938 - (download) (annotate)
Mon Jul 2 20:14:36 2012 UTC (7 years, 2 months ago) by jhr
Original Path: branches/vis12/test/mandel.diderot
File size: 1337 byte(s)
```  added file header
```
```/*! \file mandel.diderot
*
* \author Gordon Kindlmann
*/

/*
* COPYRIGHT (c) 2012 The Diderot Project (http://diderot-language.cs.uchicago.edu)
* All rights reserved.
*/

// ../bin/diderotc --exec mandel.diderot && ./mandel && unu quantize -b 8 -i rgb.nrrd -o mandel.png

// Global definitions
input int reso = 2000;
input int maxiter = 2000;
input vec2 center = [-1.2, -0.3]; // [0.0,0.0] for whole thing
input real fov = 0.15; // 2.0 for whole thing

// Strand definition
strand mandel(vec2 c) {
vec2 z = [0.0, 0.0];
int iter = 0;
output vec3 rgb = [0.0, 0.0, 0.0];
update  {
z = [z[0]^2 - z[1]^2, 2.0*z[0]*z[1]] + c; // z = z^2 + c
iter += 1;
if (z•z > 4.0) {
// point has escaped; set color based on iteration
real t = 11.0*real(iter)^0.2;
rgb = [sin(t), sin(t + 2.0*π/3.0), sin(t - 2.0*π/3.0)];
rgb = ([1.7, 1.7, 1.7] + rgb)/2.7;
stabilize;
}
if (iter > maxiter) {
rgb = [0.0, 0.0, 0.0];
stabilize;
}
}
}

// Strand initialization
initially [ mandel([lerp(center[0]-fov, center[0]+fov,
1.0, real(crIdx), real(reso)),
lerp(center[1]-fov, center[1]+fov,
1.0, real(ciIdx), real(reso))])
| ciIdx in 1..reso, crIdx in 1..reso ];
```

 root@smlnj-gforge.cs.uchicago.edu ViewVC Help Powered by ViewVC 1.0.0