(* tree-to-c.sml
 *
 * COPYRIGHT (c) 2011 The Diderot Project (http://diderot-language.cs.uchicago.edu)
 * All rights reserved.
 *
 * Translate TreeIL to the C version of CLang.
 *)

structure TreeToC : sig

    datatype var = V of (CLang.ty * CLang.var)

    type env = var TreeIL.Var.Map.map

    val trType : TreeIL.Ty.ty -> CLang.ty

    val trBlock : env * (env * TreeIL.exp list * CLang.stm -> CLang.stm list) * TreeIL.block -> CLang.stm

    val trAssign : env * TreeIL.var * TreeIL.exp -> CLang.stm list

    val trExp : env * TreeIL.exp -> CLang.exp

  (* vector indexing support.  Arguments are: vector, arity, index *)
    val ivecIndex : CLang.exp * int * int -> CLang.exp
    val vecIndex : CLang.exp * int * int -> CLang.exp

  end = struct

    structure CL = CLang
    structure RN = RuntimeNames
    structure IL = TreeIL
    structure Op = IL.Op
    structure Ty = IL.Ty
    structure V = IL.Var

    datatype var = V of (CLang.ty * CLang.var)

    type env = var TreeIL.Var.Map.map

    fun lookup (env, x) = (case V.Map.find (env, x)
	   of SOME(V(_, x')) => x'
	    | NONE => raise Fail(concat["lookup(_, ", V.name x, ")"])
	  (* end case *))

  (* integer literal expression *)
    fun intExp (i : int) = CL.mkInt(IntInf.fromInt i, CL.int32)

  (* translate TreeIL types to CLang types *)
    fun trType ty = (case ty
	   of Ty.BoolTy => CLang.T_Named "bool"
	    | Ty.StringTy => CL.charPtr
	    | Ty.IVecTy 1 => !RN.gIntTy
	    | Ty.IVecTy n => CL.T_Named(RN.ivecTy n)
	    | Ty.TensorTy[] => !RN.gRealTy
	    | Ty.TensorTy[n] => CL.T_Named(RN.vecTy n)
	    | Ty.TensorTy[n, m] => CL.T_Named(RN.matTy(n,m))
	    | Ty.AddrTy(ImageInfo.ImgInfo{ty=([], rTy), ...}) => CL.T_Ptr(CL.T_Num rTy)
	    | Ty.ImageTy(ImageInfo.ImgInfo{dim, ...}) => CL.T_Ptr(CL.T_Named(RN.imageTy dim))
	    | _ => raise Fail(concat["TreeToC.trType(", Ty.toString ty, ")"])
	  (* end case *))

  (* generate new variables *)
    local
      val count = ref 0
      fun freshName prefix = let
	    val n = !count
	    in
	      count := n+1;
	      concat[prefix, "_", Int.toString n]
	    end
    in
    fun tmpVar ty = freshName "tmp"
    fun freshVar prefix = freshName prefix
    end (* local *)

  (* translate IL basis functions *)
    local
      fun mkLookup suffix = let
	    val tbl = ILBasis.Tbl.mkTable (16, Fail "basis table")
	    fun ins f = ILBasis.Tbl.insert tbl (f, ILBasis.toString f ^ suffix)
	    in
	      List.app ins ILBasis.allFuns;
	      ILBasis.Tbl.lookup tbl
	    end
      val fLookup = mkLookup "f"
      val dLookup = mkLookup ""
    in
    fun trApply (f, args) = let
	  val f' = if !Controls.doublePrecision then dLookup f else fLookup f
	  in
	    CL.mkApply(f', args)
	  end
    end (* local *)

  (* vector indexing support.  Arguments are: vector, arity, index *)
    fun ivecIndex (v, n, ix) = let
	  val unionTy = CL.T_Named(concat["union", Int.toString n, !RN.gIntSuffix, "_t"])
	  val e1 = CL.mkCast(unionTy, v)
	  val e2 = CL.mkSelect(e1, "i")
	  in
	    CL.mkSubscript(e2, intExp ix)
	  end

    fun vecIndex (v, n, ix) = let
	  val unionTy = CL.T_Named(concat["union", Int.toString n, !RN.gRealSuffix, "_t"])
	  val e1 = CL.mkCast(unionTy, v)
	  val e2 = CL.mkSelect(e1, "r")
	  in
	    CL.mkSubscript(e2, intExp ix)
	  end

  (* translate a variable use *)
    fun trVar (env, x) = (case V.kind x
	   of IL.VK_Global => CL.mkVar(lookup(env, x))
	    | IL.VK_State strand => CL.mkIndirect(CL.mkVar "selfIn", lookup(env, x))
	    | IL.VK_Local => CL.mkVar(lookup(env, x))
	  (* end case *))

  (* Translate a TreeIL operator application to a CLang expression *)
    fun trOp (rator, args) = (case (rator, args)
	   of (Op.Add ty, [a, b]) =>
		CL.mkBinOp(a, CL.#+, b)
	    | (Op.Sub ty, [a, b]) =>
		CL.mkBinOp(a, CL.#-, b)
	    | (Op.Mul ty, [a, b]) =>
		CL.mkBinOp(a, CL.#*, b)
	    | (Op.Div ty, [a, b]) =>
		CL.mkBinOp(a, CL.#/, b)
	    | (Op.Neg ty, [a]) =>
		CL.mkUnOp(CL.%-, a)
	    | (Op.Abs(Ty.IVecTy 1), args) =>
		CL.mkApply("abs", args)
	    | (Op.Abs(Ty.TensorTy[]), args) =>
		CL.mkApply(RN.fabs(), args)
	    | (Op.Abs ty, [a]) =>
		raise Fail(concat["Abs<", Ty.toString ty, ">"])
	    | (Op.LT ty, [a, b]) =>
		CL.mkBinOp(a, CL.#<, b)
	    | (Op.LTE ty, [a, b]) =>
		CL.mkBinOp(a, CL.#<=, b)
	    | (Op.EQ ty, [a, b]) =>
		CL.mkBinOp(a, CL.#==, b)
	    | (Op.NEQ ty, [a, b]) =>
		CL.mkBinOp(a, CL.#!=, b)
	    | (Op.GTE ty, [a, b]) =>
		CL.mkBinOp(a, CL.#>=, b)
	    | (Op.GT ty, [a, b]) =>
		CL.mkBinOp(a, CL.#>, b)
	    | (Op.Not, [a]) =>
		CL.mkUnOp(CL.%!, a)
	    | (Op.Max, args) =>
		CL.mkApply(RN.max(), args)
	    | (Op.Min, args) =>
		CL.mkApply(RN.min(), args)
	    | (Op.Lerp ty, args) => (case ty
		 of Ty.TensorTy[] => CL.mkApply(RN.lerp 1, args)
		  | Ty.TensorTy[n] => CL.mkApply(RN.lerp n, args)
		  | _ => raise Fail(concat[
			"lerp<", Ty.toString ty, "> not supported"
		      ])
		(* end case *))
	    | (Op.Dot d, args) =>
		CL.E_Apply(RN.dot d, args)
	    | (Op.MulVecMat(m, n), args) =>
		if (1 < m) andalso (m < 4) andalso (m = n)
		  then CL.E_Apply(RN.mulVecMat(m,n), args)
		  else raise Fail "unsupported vector-matrix multiply"
	    | (Op.MulMatVec(m, n), args) =>
		if (1 < m) andalso (m < 4) andalso (m = n)
		  then CL.E_Apply(RN.mulMatVec(m,n), args)
		  else raise Fail "unsupported matrix-vector multiply"
	    | (Op.MulMatMat(m, n, p), args) =>
		if (1 < m) andalso (m < 4) andalso (m = n) andalso (n = p)
		  then CL.E_Apply(RN.mulMatMat(m,n,p), args)
		  else raise Fail "unsupported matrix-matrix multiply"
	    | (Op.Cross, args) =>
		CL.E_Apply(RN.cross(), args)
	    | (Op.Select(Ty.IVecTy n, i), [a]) =>
		ivecIndex (a, n, i)
	    | (Op.Select(Ty.TensorTy[n], i), [a]) =>
		vecIndex (a, n, i)
	    | (Op.Norm(Ty.TensorTy[n]), args) =>
		CL.E_Apply(RN.length n, args)
	    | (Op.Norm(Ty.TensorTy[m,n]), args) =>
		CL.E_Apply(RN.norm(m,n), args)
	    | (Op.Normalize d, args) =>
		CL.E_Apply(RN.normalize d, args)
	    | (Op.Trace n, args) =>
		CL.E_Apply(RN.trace n, args)
	    | (Op.Scale(Ty.TensorTy[n]), args) =>
		CL.E_Apply(RN.scale n, args)
	    | (Op.CL, _) =>
		raise Fail "CL unimplemented"
	    | (Op.PrincipleEvec ty, _) =>
		raise Fail "PrincipleEvec unimplemented"
	    | (Op.Subscript(Ty.IVecTy n), [v, ix]) => let
		val unionTy = CL.T_Named(concat["union", Int.toString n, !RN.gIntSuffix, "_t"])
		val vecExp = CL.mkSelect(CL.mkCast(unionTy, v), "i")
		in
		  CL.mkSubscript(vecExp, ix)
		end
	    | (Op.Subscript(Ty.TensorTy[n]), [v, ix]) => let
		val unionTy = CL.T_Named(concat["union", Int.toString n, !RN.gRealSuffix, "_t"])
		val vecExp = CL.mkSelect(CL.mkCast(unionTy, v), "r")
		in
		  CL.mkSubscript(vecExp, ix)
		end
	    | (Op.Subscript(Ty.TensorTy[_,_]), [m, ix, jx]) =>
		CL.mkSubscript(CL.mkSelect(CL.mkSubscript(m, ix), "r"), jx)
	    | (Op.Subscript ty, t::(ixs as _::_)) =>
		raise Fail(concat["Subscript<", Ty.toString ty, "> unsupported"])
	    | (Op.Ceiling d, args) =>
		CL.mkApply(RN.addTySuffix("ceil", d), args)
	    | (Op.Floor d, args) =>
		CL.mkApply(RN.addTySuffix("floor", d), args)
	    | (Op.Round d, args) =>
		CL.mkApply(RN.addTySuffix("round", d), args)
	    | (Op.Trunc d, args) =>
		CL.mkApply(RN.addTySuffix("trunc", d), args)
	    | (Op.IntToReal, [a]) =>
		CL.mkCast(!RN.gRealTy, a)
	    | (Op.RealToInt 1, [a]) =>
		CL.mkCast(!RN.gIntTy, a)
	    | (Op.RealToInt d, args) =>
		CL.mkApply(RN.vecftoi d, args)
(* FIXME: need type info *)
	    | (Op.ImageAddress(ImageInfo.ImgInfo{ty=(_,rTy), ...}), [a]) => let
		val cTy = CL.T_Ptr(CL.T_Num rTy)
		in
		  CL.mkCast(cTy, CL.mkIndirect(a, "data"))
		end
	    | (Op.LoadVoxels(info, 1), [a]) => let
		val realTy as CL.T_Num rTy = !RN.gRealTy
		val a = CL.E_UnOp(CL.%*, a)
		in
		  if (rTy = ImageInfo.sampleTy info)
		    then a
		    else CL.E_Cast(realTy, a)
		end
	    | (Op.LoadVoxels _, [a]) =>
		raise Fail("impossible " ^ Op.toString rator)
	    | (Op.PosToImgSpace(ImageInfo.ImgInfo{dim, ...}), [img, pos]) =>
		CL.mkApply(RN.toImageSpace dim, [img, pos])
	    | (Op.GradToWorldSpace d, [v, x]) =>
		raise Fail "GradToWorldSpace unimplemented"
	    | (Op.LoadImage info, [a]) =>
		raise Fail("impossible " ^ Op.toString rator)
	    | (Op.Inside(ImageInfo.ImgInfo{dim, ...}, s), [pos, img]) =>
		CL.mkApply(RN.inside dim, [pos, img, intExp s])
	    | (Op.Input(ty, name), []) =>
		raise Fail("impossible " ^ Op.toString rator)
	    | (Op.InputWithDefault(ty, name), [a]) =>
		raise Fail("impossible " ^ Op.toString rator)
	    | _ => raise Fail(concat[
		  "unknown or incorrect operator ", Op.toString rator
		])
	  (* end case *))

    fun trExp (env, e) = (case e
	   of IL.E_Var x => trVar (env, x)
	    | IL.E_Lit(Literal.Int n) => CL.mkInt(n, !RN.gIntTy)
	    | IL.E_Lit(Literal.Bool b) => CL.mkBool b
	    | IL.E_Lit(Literal.Float f) => CL.mkFlt(f, !RN.gRealTy)
	    | IL.E_Lit(Literal.String s) => CL.mkStr s
	    | IL.E_Op(rator, args) => trOp (rator, trExps(env, args))
	    | IL.E_Apply(f, args) => trApply(f, trExps(env, args))
	    | IL.E_Cons(Ty.TensorTy[n], args) => CL.mkApply(RN.mkVec n, trExps(env, args))
	    | IL.E_Cons(ty, _) => raise Fail(concat["E_Cons(", Ty.toString ty, ", _) in expression"])
	  (* end case *))

    and trExps (env, exps) = List.map (fn exp => trExp(env, exp)) exps

    fun trAssign (env, lhs, rhs) = let
	  val lhs = (case V.kind lhs
		 of IL.VK_Global => CL.mkVar(lookup(env, lhs))
		  | IL.VK_State strand => CL.mkIndirect(CL.mkVar "selfOut", lookup(env, lhs))
		  | IL.VK_Local => CL.mkVar(lookup(env, lhs))
		(* end case *))
	  in
	  (* certain rhs forms, such as those that return a matrix,
	   * require a function call instead of an assignment
	   *)
	    case rhs
	     of IL.E_Op(Op.Add(Ty.TensorTy[m,n]), args) =>
		  [CL.mkCall(RN.addMat(m,n),  lhs :: trExps(env, args))]
	      | IL.E_Op(Op.Sub(Ty.TensorTy[m,n]), args) =>
		  [CL.mkCall(RN.subMat(m,n),  lhs :: trExps(env, args))]
	      | IL.E_Op(Op.Neg(Ty.TensorTy[m,n]), args) =>
		  [CL.mkCall(RN.scaleMat(m,n),  lhs :: intExp ~1 :: trExps(env, args))]
	      | IL.E_Op(Op.Scale(Ty.TensorTy[m,n]), args) =>
		  [CL.mkCall(RN.scaleMat(m,n),  lhs :: trExps(env, args))]
	      | IL.E_Op(Op.MulMatMat(m,n,p), args) =>
		  [CL.mkCall(RN.mulMatMat(m,n,p), lhs :: trExps(env, args))]
	      | IL.E_Op(Op.Identity n, args) =>
		  [CL.mkCall(RN.identityMat n, [lhs])]
	      | IL.E_Op(Op.Zero(Ty.TensorTy[n,m]), args) =>
		  [CL.mkCall(RN.zeroMat(m,n), [lhs])]
	      | IL.E_Op(Op.LoadVoxels(info, n), [a]) =>
		  if (n > 1)
		    then let
		      val stride = ImageInfo.stride info
		      val rTy = ImageInfo.sampleTy info
		      val vp = freshVar "vp"
		      val needsCast = (CL.T_Num rTy <> !RN.gRealTy)
		      fun mkLoad i = let
			    val e = CL.mkSubscript(CL.mkVar vp, intExp(i*stride))
			    in
			      if needsCast then CL.mkCast(!RN.gRealTy, e) else e
			    end
		      in [
			CL.mkDecl(CL.T_Ptr(CL.T_Num rTy), vp, SOME(CL.I_Exp(trExp(env, a)))),
			CL.mkAssign(lhs,
			  CL.mkApply(RN.mkVec n, List.tabulate (n, mkLoad)))
		      ] end
		  else [CL.mkAssign(lhs, trExp(env, rhs))]
	      | IL.E_Cons(Ty.TensorTy[n,m], args) => let
		(* matrices are represented as arrays of union<d><ty>_t vectors *)
		  fun doRows (_, []) = []
		    | doRows (i, e::es) =
			CL.mkAssign(CL.mkSelect(CL.mkSubscript(lhs, intExp i), "v"), e)
			  :: doRows (i+1, es)
		  in
		    doRows (0, trExps(env, args))
		  end
	      | IL.E_Var x => (case IL.Var.ty x
		   of Ty.TensorTy[n,m] => [CL.mkCall(RN.copyMat(n,m), [lhs, trVar(env, x)])]
		    | _ => [CL.mkAssign(lhs, trVar(env, x))]
		  (* end case *))
	      | _ => [CL.mkAssign(lhs, trExp(env, rhs))]
	    (* end case *)
	  end

    fun trBlock (env : env, saveState, blk) = let
	(* generate code to check the status of runtime-system calls *)
	  fun checkSts mkDecl = let
		val sts = freshVar "sts"
		in
		  mkDecl sts @
		  [CL.mkIfThen(
		    CL.mkBinOp(CL.mkVar "DIDEROT_OK", CL.#!=, CL.mkVar sts),
		    CL.mkCall("exit", [intExp 1]))]
		end
	  fun trStmt (env, stm) = (case stm
		 of IL.S_Comment text => [CL.mkComment text]
		  | IL.S_Assign(x, exp) => trAssign (env, x, exp)
		  | IL.S_IfThen(cond, thenBlk) =>
		      [CL.mkIfThen(trExp(env, cond), trBlk(env, thenBlk))]
		  | IL.S_IfThenElse(cond, thenBlk, elseBlk) =>
		      [CL.mkIfThenElse(trExp(env, cond),
			trBlk(env, thenBlk),
			trBlk(env, elseBlk))]
		  | IL.S_LoadImage(lhs, dim, name) => checkSts (fn sts => let
		      val lhs = lookup(env, lhs)
		      val name = trExp(env, name)
		      val imgTy = CL.T_Named(RN.imageTy dim)
		      val loadFn = RN.loadImage dim
		      in [
			CL.mkDecl(
			  CL.T_Named RN.statusTy, sts,
			  SOME(CL.I_Exp(CL.E_Apply(loadFn, [name, CL.mkUnOp(CL.%&, CL.E_Var lhs)]))))
		      ] end)
		  | IL.S_Input(lhs, name, optDflt) => checkSts (fn sts => let
		      val inputFn = RN.input(V.ty lhs)
		      val lhs = lookup(env, lhs)
		      val lhs = CL.E_Var lhs
		      val (initCode, hasDflt) = (case optDflt
			     of SOME e => ([CL.mkAssign(lhs, trExp(env, e))], true)
			      | NONE => ([], false)
			    (* end case *))
		      val code = [
			    CL.mkDecl(
			      CL.T_Named RN.statusTy, sts,
			      SOME(CL.I_Exp(CL.E_Apply(inputFn, [
				  CL.E_Str name, CL.mkUnOp(CL.%&, lhs), CL.mkBool hasDflt
				]))))
			    ]
		      in
			initCode @ code
		      end)
(* FIXME: what about the args? *)
		  | IL.S_Exit args => [CL.mkReturn NONE]
		  | IL.S_Active args =>
		      saveState (env, args, CL.mkReturn(SOME(CL.mkVar RN.kActive)))
		  | IL.S_Stabilize args =>
		      saveState (env, args, CL.mkReturn(SOME(CL.mkVar RN.kStabilize)))
		  | IL.S_Die => [CL.mkReturn(SOME(CL.mkVar RN.kDie))]
		(* end case *))
	  and trBlk (env, IL.Block{locals, body}) = let
		val env = List.foldl
		      (fn (x, env) => V.Map.insert(env, x, V(trType(V.ty x), V.name x)))
			env locals
		val stms = List.foldr (fn (stm, stms) => trStmt(env, stm)@stms) [] body
		fun mkDecl (x, stms) = (case V.Map.find (env, x)
		       of SOME(V(ty, x')) => CL.mkDecl(ty, x', NONE) :: stms
			| NONE => raise Fail(concat["mkDecl(", V.name x, ", _)"])
		      (* end case *))
		val stms = List.foldr mkDecl stms locals
		in
		  CL.mkBlock stms
		end
	  in
	    trBlk (env, blk)
	  end

  end