(* check-low-il.sml
 *
 * COPYRIGHT (c) 2010 The Diderot Project (http://diderot-language.cs.uchicago.edu)
 * All rights reserved.
 *)

structure CheckOps : OPERATOR_TY = struct

    structure Op = LowOps
    structure Ty = LowILTypes

    type rator = Op.rator
    type ty = Ty.ty

    val vec3Ty = Ty.VecTy 3

  (* Return the signature of a LowIL operator. *)
    fun sigOf rator = (case rator
	   of Op.Add(Ty.AddrTy rTy) => (Ty.AddrTy rTy, [Ty.AddrTy rTy, Ty.intTy])
	    | Op.Add ty => (ty, [ty, ty])
	    | Op.Sub(Ty.AddrTy rTy) => (Ty.AddrTy rTy, [Ty.AddrTy rTy, Ty.intTy])
	    | Op.Sub ty => (ty, [ty, ty])
	    | Op.Mul ty => (ty, [ty, ty])
	    | Op.Div ty => (ty, [ty, ty])
	    | Op.Neg ty => (ty, [ty])
	    | Op.Abs ty => (ty, [ty])
	    | Op.LT ty => (Ty.BoolTy, [ty, ty])
	    | Op.LTE ty => (Ty.BoolTy, [ty, ty])
	    | Op.EQ ty => (Ty.BoolTy, [ty, ty])
	    | Op.NEQ ty => (Ty.BoolTy, [ty, ty])
	    | Op.GT ty => (Ty.BoolTy, [ty, ty])
	    | Op.GTE ty => (Ty.BoolTy, [ty, ty])
	    | Op.Not => (Ty.BoolTy, [Ty.BoolTy])
	    | Op.Max => (Ty.realTy, [Ty.realTy, Ty.realTy])
	    | Op.Min => (Ty.realTy, [Ty.realTy, Ty.realTy])
	    | Op.Dot d => (Ty.realTy, [Ty.VecTy d, Ty.VecTy d])
	    | Op.Cross => (vec3Ty, [vec3Ty, vec3Ty])
	    | Op.Select(ty as Ty.IVecTy d, _) => (Ty.intTy, [ty])
	    | Op.Select(ty as Ty.VecTy d, _) => (Ty.realTy, [ty])
	    | Op.Norm d => (Ty.realTy, [Ty.VecTy d])
	    | Op.Normalize d => (Ty.VecTy d, [Ty.VecTy d])
	    | Op.Scale d => (Ty.VecTy d, [Ty.realTy, Ty.VecTy d])
	    | Op.InvScale d => (Ty.VecTy d, [Ty.VecTy d, Ty.realTy])
	    | Op.CL => raise Fail "Op.CL unimplemented"
	    | Op.PrincipleEvec _ => raise Fail "Op.PrincipleEvec unimplemented"
	    | Op.Subscript(Ty.IVecTy d) => (Ty.intTy, [Ty.IVecTy d, Ty.intTy])
	    | Op.Subscript(Ty.VecTy d) => (Ty.realTy, [Ty.VecTy d, Ty.intTy])
	    | Op.Ceiling d => (Ty.VecTy d, [Ty.VecTy d])
	    | Op.Floor d => (Ty.VecTy d, [Ty.VecTy d])
	    | Op.Round d => (Ty.VecTy d, [Ty.VecTy d])
	    | Op.Trunc d => (Ty.VecTy d, [Ty.VecTy d])
	    | Op.IntToReal => (Ty.realTy, [Ty.intTy])
	    | Op.RealToInt d => (Ty.IVecTy d, [Ty.VecTy d])
	    | Op.ImageAddress info => (Ty.AddrTy info, [Ty.ImageTy info])
	    | Op.LoadVoxels(info, n) => (Ty.VecTy n, [Ty.AddrTy info])
	    | Op.PosToImgSpace info => let
		val dim = ImageInfo.dim info
		in
		  (Ty.VecTy dim, [Ty.ImageTy info, Ty.VecTy dim])
		end
	    | Op.GradToWorldSpace info => let
		val dim = ImageInfo.dim info
		in
		  (Ty.VecTy dim, [Ty.ImageTy info, Ty.VecTy dim])
		end
	    | Op.LoadImage info => (Ty.ImageTy info, [Ty.StringTy])
	    | Op.Inside(info, _) => (Ty.BoolTy, [Ty.VecTy(ImageInfo.dim info), Ty.ImageTy info])
	    | Op.Input(ty, _) => (ty, [])
	    | Op.InputWithDefault(ty, _) => (ty, [ty])
	    | _ => raise Fail("sigOf: invalid operator " ^ Op.toString rator)
	  (* end case *))

    fun typeOfCons [] = NONE
      | typeOfCons tys =
	  if List.all (fn ty => Ty.same(Ty.intTy, ty)) tys
	    then SOME(Ty.IVecTy(List.length tys))
	  else if List.all (fn ty => Ty.same(Ty.realTy, ty)) tys
	    then SOME(Ty.VecTy(List.length tys))
	    else NONE

  end

structure CheckLowIL = CheckILFn (
    structure IL = LowIL
    structure OpTy = CheckOps)