Home My Page Projects Code Snippets Project Openings diderot

# SCM Repository

[diderot] View of /branches/pure-cfg/test/iso2d.diderot
 [diderot] / branches / pure-cfg / test / iso2d.diderot

# View of /branches/pure-cfg/test/iso2d.diderot

Sat Apr 23 12:22:43 2011 UTC (9 years, 1 month ago) by glk
File size: 1959 byte(s)
`demo of 2D isocontour sampling`
```// iso2d
//
// Demo of finding isocontours via Newton-Raphson method.
// Initializes positions on a grid, and each update applies one
// step of Newton-Raphson.
//
// Process output with:
// unu jhisto -i mip.txt -b 512 512 -min 0 0 -max 63 63 | unu 2op neq - 0 | unu quantize -b 8  -o iso2d.png

int gridSize = 100;
real isoval = 30.0;
field#1(2)[] F = img ⊛ ctmr;
int stepsMax = 10;
real epsilon = 0.001;

strand sample (int ui, int vi) {
output vec2 pos = [lerp(1.0, 62.0, -0.5, real(ui), real(gridSize)-0.5),
lerp(1.0, 62.0, -0.5, real(vi), real(gridSize)-0.5)];
int steps = 0;
update {
// We bail if we're no longer inside or taken too many steps.
// We tag this strand result as garbage by setting it to a
// non-finite position; these will be filtered later.
// This is really what "die" is for, though (see below).
if (!inside(pos, F) || steps > stepsMax) {
// HEY (BUG) not able to use NaN as in "pos = [nan,nan]"
// generated C code "vec2f(nanf, nanf)" causes problems
pos = [∞,∞];
// HEY (BUG) we shouldn't even have to use non-finite values;
// we should be able to just say "die;".  Currently, using
// "die" leads to the program never finishing...
stabilize;
}
// If |∇F|=0 we can't compute update; we have to bail
if (gmsq == 0.0) {
pos = [∞,∞];
stabilize;
}
// delta = Newton-Raphson step
vec2 delta = -(F(pos) - isoval)*grad/gmsq;
// We've converged if the update is small enough
if (|delta| < epsilon) {
stabilize;
}
pos = pos + delta;
steps = steps + 1;
}
}

initially [ sample(ui, vi) | vi in 0..(gridSize-1), ui in 0..(gridSize-1) ];
```