Home My Page Projects Code Snippets Project Openings diderot
Summary Activity Tracker Tasks SCM

SCM Repository

[diderot] Annotation of /branches/staging/src/compiler/c-util/print-as-c.sml
ViewVC logotype

Annotation of /branches/staging/src/compiler/c-util/print-as-c.sml

Parent Directory Parent Directory | Revision Log Revision Log


Revision 3349 - (view) (download)

1 : jhr 1115 (* print-as-c.sml
2 :     *
3 : jhr 3349 * This code is part of the Diderot Project (http://diderot-language.cs.uchicago.edu)
4 :     *
5 :     * COPYRIGHT (c) 2015 The University of Chicago
6 : jhr 1115 * All rights reserved.
7 :     *
8 :     * Print the CLang representation using C99 syntax.
9 :     *)
10 :    
11 :     structure PrintAsC : sig
12 :    
13 :     type strm
14 :    
15 :     val new : TextIO.outstream -> strm
16 :    
17 :     val close : strm -> unit
18 :    
19 :     val output : strm * CLang.decl -> unit
20 :    
21 :     end = struct
22 :    
23 :     structure CL = CLang
24 :     structure PP = TextIOPP
25 :    
26 :     type strm = PP.stream
27 :    
28 : jhr 1766 val indent0 = (PP.Abs 0)
29 : jhr 2115 val indent = (PP.Abs 4) (* standard indentation amount *)
30 : jhr 1115
31 : jhr 2115 fun new outs = PP.openOut {dst = outs, wid = 120}
32 : jhr 1115
33 :     val close = PP.closeStream
34 :    
35 :     fun output (strm, decl) = let
36 : jhr 2115 val str = PP.string strm
37 :     fun sp () = PP.space strm 1
38 :     fun inHBox f = (PP.openHBox strm; f(); PP.closeBox strm)
39 : jhr 2644 fun ppCom s = inHBox (fn () => (str "// "; str s))
40 :     fun ppComLn s = (ppCom s; PP.newline strm)
41 : jhr 2115 fun ppList {pp, sep, l} = let
42 :     fun ppList' [] = ()
43 :     | ppList' [x] = pp x
44 :     | ppList' (x::xs) = (pp x; sep(); ppList' xs)
45 :     in
46 :     ppList' l
47 :     end
48 :     fun ppTy (ty, optVar) = let
49 :     fun getBaseTy (CL.T_Ptr ty) = getBaseTy ty
50 :     | getBaseTy (CL.T_Array(ty, _)) = getBaseTy ty
51 :     | getBaseTy (CL.T_Num rty) = (case rty
52 :     of RawTypes.RT_Int8 => "int8_t"
53 :     | RawTypes.RT_UInt8 => "uint8_t"
54 :     | RawTypes.RT_Int16 => "int16_t"
55 :     | RawTypes.RT_UInt16 => "uint16_t"
56 :     | RawTypes.RT_Int32 => "int32_t"
57 :     | RawTypes.RT_UInt32 => "uint32_t"
58 :     | RawTypes.RT_Int64 => "int64_t"
59 :     | RawTypes.RT_UInt64 => "uint64_t"
60 :     | RawTypes.RT_Float => "float"
61 :     | RawTypes.RT_Double => "double"
62 :     (* end case *))
63 :     | getBaseTy (CL.T_Named ty) = ty
64 : jhr 1444 | getBaseTy (CL.T_Qual(attr, ty)) =
65 :     concat[attr, " ", getBaseTy ty]
66 : jhr 2115 fun pp (isFirst, CL.T_Ptr ty, optVar) = (
67 :     if isFirst then sp() else ();
68 :     case ty
69 :     of CL.T_Array _ => (
70 :     str "(*"; pp(false, ty, optVar); str ")")
71 :     | _ => (str "*"; pp(false, ty, optVar))
72 :     (* end case *))
73 :     | pp (isFirst, CL.T_Array(ty, optN), optVar) = (
74 :     pp (isFirst, ty, optVar);
75 :     case optN
76 :     of NONE => str "[]"
77 :     | SOME n => (str "["; str(Int.toString n); str "]")
78 :     (* end case *))
79 : jhr 1444 | pp (isFirst, CL.T_Qual(_, ty), optVar) =
80 :     pp (isFirst, ty, optVar)
81 : jhr 2115 | pp (isFirst, _, SOME x) = (
82 :     if isFirst then sp() else ();
83 :     str x)
84 :     | pp (_, _, NONE) = ()
85 :     in
86 :     str (getBaseTy ty);
87 :     pp (true, ty, optVar)
88 :     end
89 : jhr 1368 fun ppAttrs [] = ()
90 :     | ppAttrs attrs = (
91 :     ppList {pp=str, sep=sp, l = attrs};
92 :     sp())
93 : jhr 2115 fun ppDecl dcl = (case dcl
94 : jhr 2152 of CL.D_Pragma l => (
95 :     inHBox (fn () => (
96 :     str "#pragma";
97 :     List.app (fn s => (sp(); str s)) l));
98 :     PP.newline strm)
99 :     | CL.D_Comment l => List.app ppComLn l
100 : jhr 1640 | CL.D_Verbatim l => List.app str l
101 : jhr 2115 | CL.D_Var(attrs, ty, x, optInit) => (
102 :     inHBox (fn () => (
103 :     ppAttrs attrs;
104 :     ppTy (ty, SOME x);
105 :     case optInit
106 :     of SOME init => (sp(); str "="; sp(); ppInit init)
107 :     | NONE => ()
108 :     (* end case *);
109 :     str ";"));
110 :     PP.newline strm)
111 : jhr 1766 | CL.D_Proto(attrs, ty, f, params) => (
112 :     inHBox (fn () => (
113 :     ppAttrs attrs;
114 :     ppTy(ty, SOME f);
115 :     sp(); str "(";
116 :     ppList {pp=ppParam, sep=fn () => (str ","; sp()), l=params};
117 :     str ");"));
118 :     PP.newline strm)
119 : jhr 2115 | CL.D_Func(attrs, ty, f, params, body) => (
120 :     PP.openVBox strm indent0;
121 :     inHBox (fn () => (
122 :     ppAttrs attrs;
123 :     ppTy(ty, SOME f);
124 :     sp(); str "(";
125 :     ppList {pp=ppParam, sep=fn () => (str ","; sp()), l=params};
126 :     str ")"));
127 :     PP.newline strm;
128 :     ppBlock (case body of CL.S_Block stms => stms | stm => [stm]);
129 :     PP.closeBox strm;
130 : jhr 1368 PP.newline strm)
131 : jhr 2115 | CL.D_StructDef(SOME name, fields, NONE) => (
132 :     PP.openVBox strm indent0;
133 :     inHBox (fn () => (str "struct"; sp(); str name; sp(); str "{"));
134 :     PP.openVBox strm indent;
135 :     List.app (fn (ty, x) => (
136 :     PP.newline strm;
137 :     inHBox (fn () => (ppTy(ty, SOME x); str ";"))))
138 :     fields;
139 :     PP.closeBox strm;
140 :     PP.newline strm;
141 :     str "};";
142 :     PP.closeBox strm;
143 :     PP.newline strm)
144 :     | CL.D_StructDef(optStruct, fields, SOME tyName) => (
145 :     PP.openVBox strm indent0;
146 :     str "typedef struct {";
147 :     PP.openVBox strm indent;
148 :     List.app (fn (ty, x) => (
149 :     PP.newline strm;
150 :     inHBox (fn () => (ppTy(ty, SOME x); str ";"))))
151 :     fields;
152 :     PP.closeBox strm;
153 :     PP.newline strm;
154 :     inHBox (fn () => (str "}"; sp(); str tyName; str ";"));
155 :     PP.closeBox strm;
156 :     PP.newline strm)
157 :     (* end case *))
158 :     and ppParam (CL.PARAM(attrs, ty, x)) = (
159 :     ppAttrs attrs;
160 :     ppTy(ty, SOME(CL.varToString x)))
161 :     and ppInit init = (case init
162 :     of CL.I_Exp e => ppExp e
163 : jhr 2746 | CL.I_Exps fields => (
164 :     str "{";
165 :     PP.openHVBox strm indent;
166 :     List.app (fn init => (
167 :     PP.break strm;
168 :     inHBox (fn () => (ppInit init; str ","))))
169 :     fields;
170 :     PP.closeBox strm;
171 :     str "}")
172 : jhr 2115 | CL.I_Struct fields => (
173 :     str "{";
174 :     PP.openHVBox strm indent;
175 :     List.app (fn (lab, init) => (
176 :     PP.break strm;
177 :     inHBox (fn () => (
178 :     str("." ^ lab); sp(); str "="; sp(); ppInit init; str ","))))
179 :     fields;
180 :     PP.closeBox strm;
181 :     str "}")
182 :     | CL.I_Array elems => (
183 :     str "{";
184 :     PP.openHVBox strm indent;
185 :     List.app (fn (i, init) => (
186 :     PP.break strm;
187 :     inHBox (fn () => (
188 :     str(concat["[", Int.toString i, "]"]); sp(); str "="; sp();
189 :     ppInit init; str ","))))
190 :     elems;
191 :     PP.closeBox strm;
192 :     str "}")
193 :     (* end case *))
194 :     and ppBlock stms = (
195 :     str "{";
196 :     PP.openVBox strm indent;
197 :     List.app (fn stm => (PP.newline strm; ppStm stm)) stms;
198 :     PP.closeBox strm;
199 :     PP.newline strm;
200 :     str "}")
201 :     and ppStm stm = (case stm
202 :     of CL.S_Block stms => ppBlock stms
203 : jhr 2644 | CL.S_Comment l => List.app ppCom l
204 : jhr 2152 | CL.S_Verbatim [] => ()
205 :     | CL.S_Verbatim (stm::stms) => (
206 :     str stm;
207 :     List.app (fn stm => (PP.newline strm; str stm)) stms)
208 : jhr 2115 | CL.S_Decl(attrs, ty, x, NONE) => inHBox (fn () => (
209 :     ppAttrs attrs;
210 :     ppTy(ty, SOME x); str ";"))
211 :     | CL.S_Decl(attrs, ty, x, SOME e) => inHBox (fn () => (
212 :     ppAttrs attrs;
213 :     ppTy(ty, SOME x); sp(); str "="; sp(); ppInit e; str ";"))
214 :     | CL.S_Exp e => inHBox (fn () => (ppExp e; str ";"))
215 :     | CL.S_If(e, blk, CL.S_Block[]) =>
216 :     inHBox (fn () => (str "if"; sp(); ppExp e; ppStms blk))
217 :     | CL.S_If(e, blk1, blk2) => (
218 :     PP.openVBox strm indent0;
219 :     inHBox (fn () => (str "if"; sp(); ppExp e; ppStms blk1));
220 :     PP.newline strm;
221 :     inHBox (fn () => (str "else"; ppStms blk2));
222 :     PP.closeBox strm)
223 :     | CL.S_While(e, blk) =>
224 :     inHBox (fn () => (str "while"; sp(); ppExp e; ppStms blk))
225 :     | CL.S_DoWhile(blk, e) =>
226 :     inHBox (fn () => (
227 :     str "do"; ppStms blk; sp(); str "while"; sp(); ppExp e))
228 :     | CL.S_For(inits, cond, incrs, blk) => let
229 :     fun ppInit (ty, x, e) = inHBox (fn () => (
230 :     ppTy(ty, SOME x);
231 :     sp(); str "="; sp();
232 :     ppExp e))
233 :     in
234 :     inHBox (fn () => (
235 :     str "for"; sp(); str "(";
236 :     ppList {pp = ppInit, sep = fn () => str ",", l = inits};
237 :     str ";"; sp();
238 :     ppExp cond; str ";"; sp();
239 :     ppList {pp = ppExp, sep = fn () => str ",", l = incrs};
240 :     str ")";
241 :     ppStms blk))
242 :     end
243 :     | CL.S_Return(SOME e) => inHBox (fn () => (str "return"; sp(); ppExp e; str ";"))
244 :     | CL.S_Return _ => str "return;"
245 :     | CL.S_Break => str "break;"
246 :     | CL.S_Continue => str "continue;"
247 :     (* end case *))
248 :     and ppStms (CL.S_Block stms) = (sp(); ppBlock stms)
249 :     | ppStms stm = (
250 :     PP.openHOVBox strm indent;
251 :     sp ();
252 :     ppStm stm;
253 :     PP.closeBox strm)
254 :     and ppExp e = (case e
255 :     of CL.E_Grp e => (str "("; ppExp e; str ")")
256 :     | CL.E_AssignOp(lhs, rator, rhs) => (
257 :     ppExp lhs; sp(); str(CL.assignopToString rator); sp(); ppExp rhs)
258 : jhr 1640 | CL.E_Cond(e1, e2, e3) => (
259 :     ppExp e1; sp(); str "?"; sp(); ppExp e2; sp(); str ":"; sp(); ppExp e3)
260 : jhr 2115 | CL.E_BinOp(e1, rator, e2) => (ppExp e1; str(CL.binopToString rator); ppExp e2)
261 :     | CL.E_UnOp(rator, e) => (str(CL.unopToString rator); ppExp e)
262 :     | CL.E_PostOp(e, rator) => (ppExp e; str(CL.postopToString rator))
263 : jhr 2746 | CL.E_Apply(e, args) => (ppExp e; ppArgs args)
264 : jhr 2115 | CL.E_Subscript(e1, e2) => (ppExp e1; str "["; ppExp e2; str "]")
265 :     | CL.E_Select(e, f) => (ppExp e; str "."; str f)
266 :     | CL.E_Indirect(e, f) => (ppExp e; str "->"; str f)
267 :     | CL.E_Cast(ty, e) => (
268 :     str "("; ppTy(ty, NONE); str ")"; ppExp e)
269 :     | CL.E_Var x => str(CL.varToString x)
270 :     | CL.E_Int(n, CL.T_Num(RawTypes.RT_Int64)) =>
271 :     str(IntegerLit.toString n ^ "l")
272 :     | CL.E_Int(n, _) => str(IntegerLit.toString n)
273 :     | CL.E_Flt(f, ty) => let
274 :     val isDouble = (case ty
275 :     of CL.T_Num(RawTypes.RT_Float) => false
276 :     | _ => true
277 :     (* end case *))
278 :     (* NOTE: the CLang.mkFlt function guarantees that f is non-negative *)
279 :     val f = if FloatLit.same(FloatLit.posInf, f)
280 :     then if isDouble
281 :     then "HUGE_VAL"
282 :     else "HUGE_VALF"
283 :     else if FloatLit.same(FloatLit.nan, f)
284 :     then if isDouble
285 :     then "nan(\"\")"
286 :     else "nanf(\"\")"
287 :     else if isDouble
288 :     then FloatLit.toString f
289 :     else FloatLit.toString f ^ "f"
290 :     in
291 :     str f
292 :     end
293 :     | CL.E_Bool b => str(Bool.toString b)
294 :     | CL.E_Str s => str(concat["\"", String.toCString s, "\""])
295 : jhr 2746 | CL.E_Char c => str(concat["'", Char.toCString c, "'"])
296 : jhr 2115 | CL.E_Sizeof ty => (str "sizeof("; ppTy(ty, NONE); str ")")
297 :     (* end case *))
298 :     and ppArgs args = (
299 :     str "(";
300 :     PP.openHOVBox strm indent;
301 :     PP.cut strm;
302 :     ppList {
303 :     pp = fn e => (PP.openHBox strm; ppExp e; PP.closeBox strm),
304 :     sep = fn () => (str ","; sp()),
305 :     l = args
306 :     };
307 :     str ")";
308 :     PP.closeBox strm)
309 :     in
310 :     ppDecl decl
311 :     end
312 : jhr 1115
313 :     end

root@smlnj-gforge.cs.uchicago.edu
ViewVC Help
Powered by ViewVC 1.0.0