Home My Page Projects Code Snippets Project Openings diderot
Summary Activity Tracker Tasks SCM

SCM Repository

[diderot] Annotation of /branches/vis12-cl/src/compiler/c-util/tree-to-c.sml
ViewVC logotype

Annotation of /branches/vis12-cl/src/compiler/c-util/tree-to-c.sml

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1690 - (view) (download)
Original Path: branches/vis12/src/compiler/c-util/tree-to-c-fn.sml

1 : jhr 1640 (* tree-to-c.sml
2 :     *
3 :     * COPYRIGHT (c) 2011 The Diderot Project (http://diderot-language.cs.uchicago.edu)
4 :     * All rights reserved.
5 :     *
6 :     * Translate TreeIL to the C version of CLang.
7 :     *)
8 :    
9 :     signature TREE_VAR_TO_C =
10 :     sig
11 :     type env = CLang.typed_var TreeIL.Var.Map.map
12 :     (* translate a variable that occurs in an l-value context (i.e., as the target of an assignment) *)
13 :     val lvalueVar : env * TreeIL.var -> CLang.exp
14 :     (* translate a variable that occurs in a r-value context *)
15 :     val rvalueVar : env * TreeIL.var -> CLang.exp
16 :     (* translate a strand state variable that occurs in an l-value context *)
17 :     val lvalueStateVar : TreeIL.state_var -> CLang.exp
18 :     (* translate a strand state variable that occurs in a r-value context *)
19 :     val rvalueStateVar : TreeIL.state_var -> CLang.exp
20 :     end
21 :    
22 :     functor TreeToCFn (VarToC : TREE_VAR_TO_C) : sig
23 :    
24 :     type env = CLang.typed_var TreeIL.Var.Map.map
25 :    
26 :     val trType : TreeIL.Ty.ty -> CLang.ty
27 :    
28 :     val trBlock : env * TreeIL.block -> CLang.stm
29 :    
30 :     val trFragment : env * TreeIL.block -> env * CLang.stm list
31 :    
32 :     val trExp : env * TreeIL.exp -> CLang.exp
33 :    
34 :     (* vector indexing support. Arguments are: vector, arity, index *)
35 :     val ivecIndex : CLang.exp * int * int -> CLang.exp
36 :     val vecIndex : CLang.exp * int * int -> CLang.exp
37 :    
38 :     end = struct
39 :    
40 :     structure CL = CLang
41 :     structure N = CNames
42 :     structure IL = TreeIL
43 :     structure Op = IL.Op
44 :     structure Ty = IL.Ty
45 :     structure V = IL.Var
46 :    
47 :     datatype var = datatype CLang.typed_var
48 :     type env = CLang.typed_var TreeIL.Var.Map.map
49 :    
50 :     fun lookup (env, x) = (case V.Map.find (env, x)
51 :     of SOME(V(_, x')) => x'
52 :     | NONE => raise Fail(concat["lookup(_, ", V.name x, ")"])
53 :     (* end case *))
54 :    
55 :     (* integer literal expression *)
56 :     fun intExp (i : int) = CL.mkInt(IntInf.fromInt i)
57 :    
58 :     (* translate TreeIL types to CLang types *)
59 :     fun trType ty = (case ty
60 :     of Ty.BoolTy => CLang.T_Named "bool"
61 :     | Ty.StringTy => CL.charPtr
62 :     | Ty.IntTy => !N.gIntTy
63 :     | Ty.TensorTy[] => !N.gRealTy
64 :     | Ty.TensorTy[n] => CL.T_Named(N.vecTy n)
65 :     | Ty.TensorTy[n, m] => CL.T_Named(N.matTy(n,m))
66 :     | Ty.SeqTy(Ty.IntTy, n) => CL.T_Named(N.ivecTy n)
67 :     | Ty.SeqTy(ty, n) => CL.T_Array(trType ty, SOME n)
68 : jhr 1690 | Ty.DynSeqTy _ => CL.T_Named N.dynSeqTy
69 : jhr 1640 | Ty.AddrTy(ImageInfo.ImgInfo{ty=(_, rTy), ...}) => CL.T_Ptr(CL.T_Num rTy)
70 :     | Ty.ImageTy(ImageInfo.ImgInfo{dim, ...}) => CL.T_Ptr(CL.T_Named(N.imageTy dim))
71 :     | _ => raise Fail(concat["TreeToC.trType(", Ty.toString ty, ")"])
72 :     (* end case *))
73 :    
74 :     (* generate new variables *)
75 :     local
76 :     val count = ref 0
77 :     fun freshName prefix = let
78 :     val n = !count
79 :     in
80 :     count := n+1;
81 :     concat[prefix, "_", Int.toString n]
82 :     end
83 :     in
84 :     fun tmpVar ty = freshName "tmp"
85 :     fun freshVar prefix = freshName prefix
86 :     end (* local *)
87 :    
88 :     (* translate IL basis functions *)
89 :     local
90 :     fun mkLookup suffix = let
91 :     val tbl = ILBasis.Tbl.mkTable (16, Fail "basis table")
92 :     fun ins f = ILBasis.Tbl.insert tbl (f, ILBasis.toString f ^ suffix)
93 :     in
94 :     List.app ins ILBasis.allFuns;
95 :     ILBasis.Tbl.lookup tbl
96 :     end
97 :     val fLookup = mkLookup "f"
98 :     val dLookup = mkLookup ""
99 :     in
100 :     fun trApply (f, args) = let
101 :     val f' = if !N.doublePrecision then dLookup f else fLookup f
102 :     in
103 :     CL.mkApply(f', args)
104 :     end
105 :     end (* local *)
106 :    
107 :     (* vector indexing support. Arguments are: vector, arity, index *)
108 :     fun ivecIndex (v, n, ix) = let
109 :     val unionTy = CL.T_Named(concat["union", Int.toString n, !N.gIntSuffix, "_t"])
110 :     val e1 = CL.mkCast(unionTy, v)
111 :     val e2 = CL.mkSelect(e1, "i")
112 :     in
113 :     CL.mkSubscript(e2, intExp ix)
114 :     end
115 :    
116 :     fun vecIndex (v, n, ix) = let
117 :     val unionTy = CL.T_Named(concat["union", Int.toString n, !N.gRealSuffix, "_t"])
118 :     val e1 = CL.mkCast(unionTy, v)
119 :     val e2 = CL.mkSelect(e1, "r")
120 :     in
121 :     CL.mkSubscript(e2, intExp ix)
122 :     end
123 :    
124 :     (* matrix indexing *)
125 :     fun matIndex (m, ix, jx) =
126 :     CL.mkSubscript(CL.mkSelect(CL.mkSubscript(m, ix), "r"), jx)
127 :    
128 :     (* Translate a TreeIL operator application to a CLang expression *)
129 :     fun trOp (rator, args) = (case (rator, args)
130 :     of (Op.Add ty, [a, b]) => CL.mkBinOp(a, CL.#+, b)
131 :     | (Op.Sub ty, [a, b]) => CL.mkBinOp(a, CL.#-, b)
132 :     | (Op.Mul ty, [a, b]) => CL.mkBinOp(a, CL.#*, b)
133 :     | (Op.Div ty, [a, b]) => CL.mkBinOp(a, CL.#/, b)
134 :     | (Op.Neg ty, [a]) => CL.mkUnOp(CL.%-, a)
135 :     | (Op.Abs(Ty.IntTy), args) => CL.mkApply("abs", args)
136 :     | (Op.Abs(Ty.TensorTy[]), args) => CL.mkApply(N.fabs(), args)
137 :     | (Op.Abs ty, [a]) => raise Fail(concat["Abs<", Ty.toString ty, ">"])
138 :     | (Op.LT ty, [a, b]) => CL.mkBinOp(a, CL.#<, b)
139 :     | (Op.LTE ty, [a, b]) => CL.mkBinOp(a, CL.#<=, b)
140 :     | (Op.EQ ty, [a, b]) => CL.mkBinOp(a, CL.#==, b)
141 :     | (Op.NEQ ty, [a, b]) => CL.mkBinOp(a, CL.#!=, b)
142 :     | (Op.GTE ty, [a, b]) => CL.mkBinOp(a, CL.#>=, b)
143 :     | (Op.GT ty, [a, b]) => CL.mkBinOp(a, CL.#>, b)
144 :     | (Op.Not, [a]) => CL.mkUnOp(CL.%!, a)
145 :     | (Op.Max, args) => CL.mkApply(N.max(), args)
146 :     | (Op.Min, args) => CL.mkApply(N.min(), args)
147 :     | (Op.Clamp(Ty.TensorTy[]), args) => CL.mkApply(N.clamp 1, args)
148 :     | (Op.Clamp(Ty.TensorTy[n]), args) => CL.mkApply(N.clamp n, args)
149 :     | (Op.Lerp ty, args) => (case ty
150 :     of Ty.TensorTy[] => CL.mkApply(N.lerp 1, args)
151 :     | Ty.TensorTy[n] => CL.mkApply(N.lerp n, args)
152 :     | _ => raise Fail(concat[
153 :     "lerp<", Ty.toString ty, "> not supported"
154 :     ])
155 :     (* end case *))
156 :     | (Op.Dot d, args) => CL.E_Apply(N.dot d, args)
157 :     | (Op.MulVecMat(m, n), args) =>
158 :     if (1 < m) andalso (m < 4) andalso (m = n)
159 :     then CL.E_Apply(N.mulVecMat(m,n), args)
160 :     else raise Fail "unsupported vector-matrix multiply"
161 :     | (Op.MulMatVec(m, n), args) =>
162 :     if (1 < m) andalso (m < 4) andalso (m = n)
163 :     then CL.E_Apply(N.mulMatVec(m,n), args)
164 :     else raise Fail "unsupported matrix-vector multiply"
165 :     | (Op.MulMatMat(m, n, p), args) =>
166 :     if (1 < m) andalso (m < 4) andalso (m = n) andalso (n = p)
167 :     then CL.E_Apply(N.mulMatMat(m,n,p), args)
168 :     else raise Fail "unsupported matrix-matrix multiply"
169 :     | (Op.Cross, args) => CL.E_Apply(N.cross(), args)
170 :     | (Op.Norm(Ty.TensorTy[n]), args) => CL.E_Apply(N.length n, args)
171 :     | (Op.Norm(Ty.TensorTy[m,n]), args) => CL.E_Apply(N.norm(m,n), args)
172 :     | (Op.Normalize d, args) => CL.E_Apply(N.normalize d, args)
173 :     | (Op.Scale(Ty.TensorTy[n]), args) => CL.E_Apply(N.scale n, args)
174 :     | (Op.PrincipleEvec ty, _) => raise Fail "PrincipleEvec unimplemented"
175 :     | (Op.Select(Ty.TupleTy tys, i), [a]) => raise Fail "Select unimplemented"
176 :     | (Op.Index(Ty.SeqTy(Ty.IntTy, n), i), [a]) => ivecIndex (a, n, i)
177 :     | (Op.Index(Ty.TensorTy[n], i), [a]) => vecIndex (a, n, i)
178 :     | (Op.Subscript(Ty.SeqTy(Ty.IntTy, n)), [v, ix]) => let
179 :     val unionTy = CL.T_Named(concat["union", Int.toString n, !N.gIntSuffix, "_t"])
180 :     val vecExp = CL.mkSelect(CL.mkCast(unionTy, v), "i")
181 :     in
182 :     CL.mkSubscript(vecExp, ix)
183 :     end
184 :     | (Op.Subscript(Ty.SeqTy(ty, n)), [v, ix]) => CL.mkSubscript(v, ix)
185 :     | (Op.Subscript(Ty.TensorTy[n]), [v, ix]) => let
186 :     val unionTy = CL.T_Named(concat["union", Int.toString n, !N.gRealSuffix, "_t"])
187 :     val vecExp = CL.mkSelect(CL.mkCast(unionTy, v), "r")
188 :     in
189 :     CL.mkSubscript(vecExp, ix)
190 :     end
191 :     | (Op.Subscript(Ty.TensorTy[_,_]), [m, ix, jx]) => matIndex (m, ix, jx)
192 :     | (Op.Subscript ty, t::(ixs as _::_)) =>
193 :     raise Fail(concat["Subscript<", Ty.toString ty, "> unsupported"])
194 : jhr 1690 | (Op.MkDynamic(ty, n), [seq]) => CL.mkApply("DYNSEQ_MK(", [
195 :     CL.mkSizeof(trType ty), CL.mkInt(IntInf.fromInt n), seq
196 :     ])
197 :     | (Op.Append ty, [seq, x]) => CL.mkApply("DYNSEQ_APPEND(", [
198 :     CL.mkSizeof(trType ty), seq, x
199 :     ])
200 :     | (Op.Prepend ty, [x, seq]) => CL.mkApply("DYNSEQ_PREPEND(", [
201 :     CL.mkSizeof(trType ty), x, seq
202 :     ])
203 :     | (Op.Concat ty, [seq1, seq2]) => CL.mkApply("DYNSEQ_CONCAT(", [
204 :     CL.mkSizeof(trType ty), seq1, seq2
205 :     ])
206 : jhr 1640 | (Op.Ceiling d, args) => CL.mkApply(N.addTySuffix("ceil", d), args)
207 :     | (Op.Floor d, args) => CL.mkApply(N.addTySuffix("floor", d), args)
208 :     | (Op.Round d, args) => CL.mkApply(N.addTySuffix("round", d), args)
209 :     | (Op.Trunc d, args) => CL.mkApply(N.addTySuffix("trunc", d), args)
210 :     | (Op.IntToReal, [a]) => CL.mkCast(!N.gRealTy, a)
211 :     | (Op.RealToInt 1, [a]) => CL.mkCast(!N.gIntTy, a)
212 :     | (Op.RealToInt d, args) => CL.mkApply(N.vecftoi d, args)
213 :     (* FIXME: need type info *)
214 :     | (Op.ImageAddress(ImageInfo.ImgInfo{ty=(_,rTy), ...}), [a]) => let
215 :     val cTy = CL.T_Ptr(CL.T_Num rTy)
216 :     in
217 :     CL.mkCast(cTy, CL.mkIndirect(a, "data"))
218 :     end
219 :     | (Op.LoadVoxels(info, 1), [a]) => let
220 :     val realTy as CL.T_Num rTy = !N.gRealTy
221 :     val a = CL.E_UnOp(CL.%*, a)
222 :     in
223 :     if (rTy = ImageInfo.sampleTy info)
224 :     then a
225 :     else CL.E_Cast(realTy, a)
226 :     end
227 :     | (Op.LoadVoxels _, [a]) =>
228 :     raise Fail("impossible " ^ Op.toString rator)
229 :     | (Op.PosToImgSpace(ImageInfo.ImgInfo{dim, ...}), [img, pos]) =>
230 :     CL.mkApply(N.toImageSpace dim, [img, pos])
231 :     | (Op.TensorToWorldSpace(info, ty), [v, x]) =>
232 :     CL.mkApply(N.toWorldSpace ty, [v, x])
233 :     | (Op.LoadImage info, [a]) =>
234 :     raise Fail("impossible " ^ Op.toString rator)
235 :     | (Op.Inside(ImageInfo.ImgInfo{dim, ...}, s), [pos, img]) =>
236 :     CL.mkApply(N.inside dim, [pos, img, intExp s])
237 :     | (Op.Input(ty, desc, name), []) =>
238 :     raise Fail("impossible " ^ Op.toString rator)
239 :     | (Op.InputWithDefault(ty, desc, name), [a]) =>
240 :     raise Fail("impossible " ^ Op.toString rator)
241 :     | _ => raise Fail(concat[
242 :     "unknown or incorrect operator ", Op.toString rator
243 :     ])
244 :     (* end case *))
245 :    
246 :     fun trExp (env, e) = (case e
247 :     of IL.E_State x => VarToC.rvalueStateVar x
248 :     | IL.E_Var x => VarToC.rvalueVar (env, x)
249 :     | IL.E_Lit(Literal.Int n) => CL.mkIntTy(n, !N.gIntTy)
250 :     | IL.E_Lit(Literal.Bool b) => CL.mkBool b
251 :     | IL.E_Lit(Literal.Float f) => CL.mkFlt(f, !N.gRealTy)
252 :     | IL.E_Lit(Literal.String s) => CL.mkStr s
253 :     | IL.E_Op(rator, args) => trOp (rator, trExps(env, args))
254 :     | IL.E_Apply(f, args) => trApply(f, trExps(env, args))
255 :     | IL.E_Cons(Ty.TensorTy[n], args) => CL.mkApply(N.mkVec n, trExps(env, args))
256 : jhr 1690 | IL.E_Cons(Ty.SeqTy(ty, n), args) => CL.mkApply("Diderot_MkSeq",
257 :     CL.mkSizeof(trType ty) :: CL.mkInt(IntInf.fromInt n) :: trExps(env, args))
258 : jhr 1640 | IL.E_Cons(ty, _) => raise Fail(concat["E_Cons(", Ty.toString ty, ", _) in expression"])
259 :     (* end case *))
260 :    
261 :     and trExps (env, exps) = List.map (fn exp => trExp(env, exp)) exps
262 :    
263 :     (* translate an expression to a variable form; return the variable and the
264 :     * (optional) declaration.
265 :     *)
266 :     fun expToVar (env, ty, name, exp) = (case trExp(env, exp)
267 :     of x as CL.E_Var _ => (x, [])
268 :     | exp => let
269 :     val x = freshVar name
270 :     in
271 :     (CL.mkVar x, [CL.mkDecl(ty, x, SOME(CL.I_Exp exp))])
272 :     end
273 :     (* end case *))
274 :    
275 :     (* translate a print statement *)
276 :     fun trPrint (env, tys, args) = let
277 :     (* assemble the format string by analysing the types and argument expressions *)
278 :     fun mkFmt (Ty.StringTy, IL.E_Lit(Literal.String s), (stms, fmt, args)) =
279 :     (stms, s::fmt, args)
280 :     | mkFmt (ty, exp, (stms, fmt, args)) = let
281 :     fun mk (f, e) = (stms, f::fmt, e::args)
282 :     in
283 :     case ty
284 :     of Ty.BoolTy => mk(
285 :     "%s",
286 :     CL.mkCond(trExp(env, exp), CL.mkStr "true", CL.mkStr "false"))
287 :     | Ty.StringTy => mk("%s", trExp(env, exp))
288 :     | Ty.IntTy => mk(!N.gIntFormat, trExp(env, exp))
289 :     | Ty.TensorTy[] => mk("%f", trExp(env, exp))
290 :     | Ty.TensorTy[n] => let
291 :     val (x, stm) = expToVar (env, trType ty, "vec", exp)
292 :     val elems = List.tabulate (n, fn i => vecIndex (x, n, i))
293 :     val (fmt, args) = mkSeqFmt (Ty.TensorTy[], elems, fmt, args)
294 :     in
295 :     (stm@stms, fmt, args)
296 :     end
297 :     (*
298 :     | Ty.TensorTy[n, m] =>
299 :     *)
300 :     | Ty.SeqTy(elemTy, n) => let
301 :     val (x, stm) = expToVar (env, trType ty, "vec", exp)
302 :     val elems = List.tabulate (n, fn i => ivecIndex (x, n, i))
303 :     val (fmt, args) = mkSeqFmt (elemTy, elems, fmt, args)
304 :     in
305 :     (stm@stms, fmt, args)
306 :     end
307 :     | _ => raise Fail(concat["TreeToC.trPrint(", Ty.toString ty, ")"])
308 :     (* end case *)
309 :     end
310 :     and mkElemFmt (elemTy, elem, (fmt, args)) = (case elemTy
311 :     of Ty.BoolTy =>
312 :     ("%s"::fmt, CL.mkCond(elem, CL.mkStr "true", CL.mkStr "false")::args)
313 :     | Ty.StringTy => ("%s"::fmt, elem::args)
314 :     | Ty.IntTy => (!N.gIntFormat::fmt, elem::args)
315 :     | Ty.TensorTy[] => ("%f"::fmt, elem::args)
316 :     | Ty.TensorTy[n] => let
317 :     val elems = List.tabulate (n, fn i => vecIndex (elem, n, i))
318 :     in
319 :     mkSeqFmt (Ty.TensorTy[], elems, fmt, args)
320 :     end
321 :     (*
322 :     | Ty.TensorTy[n, m] =>
323 :     *)
324 :     | Ty.SeqTy(elemTy, n) => let
325 :     val elems = List.tabulate (n, fn i => ivecIndex (elem, n, i))
326 :     in
327 :     mkSeqFmt (elemTy, elems, fmt, args)
328 :     end
329 :     | _ => raise Fail(concat["TreeToC.mkElemFmt(", Ty.toString elemTy, ")"])
330 :     (* end case *))
331 :     and mkSeqFmt (elemTy, elems, fmt, args) = let
332 :     fun mk (elem, acc) = mkFmt(elemTy, elem, acc)
333 :     val (seqFmt, args) =
334 :     List.foldr
335 :     (fn (elem, acc) => mkElemFmt(elemTy, elem, acc))
336 :     ([], args) elems
337 :     in
338 :     ("<" :: String.concatWith "," seqFmt :: ">" :: fmt, args)
339 :     end
340 :     val (stms, fmt, args) = ListPair.foldr mkFmt ([], [], []) (tys, args)
341 :     val stm = CL.mkCall("fprintf", CL.mkVar "stderr" :: CL.mkStr(String.concat fmt) :: args)
342 :     in
343 :     List.rev (stm :: stms)
344 :     end
345 :    
346 :     fun trAssign (env, lhs, rhs) = (
347 :     (* certain rhs forms, such as those that return a matrix,
348 :     * require a function call instead of an assignment
349 :     *)
350 :     case rhs
351 :     of IL.E_Op(Op.Add(Ty.TensorTy[m,n]), args) =>
352 :     [CL.mkCall(N.addMat(m,n), lhs :: trExps(env, args))]
353 :     | IL.E_Op(Op.Sub(Ty.TensorTy[m,n]), args) =>
354 :     [CL.mkCall(N.subMat(m,n), lhs :: trExps(env, args))]
355 :     | IL.E_Op(Op.Neg(Ty.TensorTy[m,n]), args) =>
356 :     [CL.mkCall(N.scaleMat(m,n), lhs :: intExp ~1 :: trExps(env, args))]
357 :     | IL.E_Op(Op.Scale(Ty.TensorTy[m,n]), args) =>
358 :     [CL.mkCall(N.scaleMat(m,n), lhs :: trExps(env, args))]
359 :     | IL.E_Op(Op.MulMatMat(m,n,p), args) =>
360 :     [CL.mkCall(N.mulMatMat(m,n,p), lhs :: trExps(env, args))]
361 :     | IL.E_Op(Op.EigenVals2x2, [m]) => let
362 :     val (m, stms) = expToVar (env, CL.T_Named(N.matTy(2,2)), "m", m)
363 :     in
364 :     stms @ [CL.mkCall(N.evals2x2, [
365 :     lhs,
366 :     matIndex (m, CL.mkInt 0, CL.mkInt 0),
367 :     matIndex (m, CL.mkInt 0, CL.mkInt 1),
368 :     matIndex (m, CL.mkInt 1, CL.mkInt 1)
369 :     ])]
370 :     end
371 :     | IL.E_Op(Op.EigenVals3x3, [m]) => let
372 :     val (m, stms) = expToVar (env, CL.T_Named(N.matTy(3,3)), "m", m)
373 :     in
374 :     stms @ [CL.mkCall(N.evals3x3, [
375 :     lhs,
376 :     matIndex (m, CL.mkInt 0, CL.mkInt 0),
377 :     matIndex (m, CL.mkInt 0, CL.mkInt 1),
378 :     matIndex (m, CL.mkInt 0, CL.mkInt 2),
379 :     matIndex (m, CL.mkInt 1, CL.mkInt 1),
380 :     matIndex (m, CL.mkInt 1, CL.mkInt 2),
381 :     matIndex (m, CL.mkInt 2, CL.mkInt 2)
382 :     ])]
383 :     end
384 :     | IL.E_Op(Op.Identity n, args) =>
385 :     [CL.mkCall(N.identityMat n, [lhs])]
386 :     | IL.E_Op(Op.Zero(Ty.TensorTy[m,n]), args) =>
387 :     [CL.mkCall(N.zeroMat(m,n), [lhs])]
388 :     | IL.E_Op(Op.TensorToWorldSpace(info, ty as Ty.TensorTy[_,_]), args) =>
389 :     [CL.mkCall(N.toWorldSpace ty, lhs :: trExps(env, args))]
390 :     | IL.E_Op(Op.LoadVoxels(info, n), [a]) =>
391 :     if (n > 1)
392 :     then let
393 :     val stride = ImageInfo.stride info
394 :     val rTy = ImageInfo.sampleTy info
395 :     val vp = freshVar "vp"
396 :     val needsCast = (CL.T_Num rTy <> !N.gRealTy)
397 :     fun mkLoad i = let
398 :     val e = CL.mkSubscript(CL.mkVar vp, intExp(i*stride))
399 :     in
400 :     if needsCast then CL.mkCast(!N.gRealTy, e) else e
401 :     end
402 :     in [
403 :     CL.mkDecl(CL.T_Ptr(CL.T_Num rTy), vp, SOME(CL.I_Exp(trExp(env, a)))),
404 :     CL.mkAssign(lhs,
405 :     CL.mkApply(N.mkVec n, List.tabulate (n, mkLoad)))
406 :     ] end
407 :     else [CL.mkAssign(lhs, trExp(env, rhs))]
408 :     | IL.E_Cons(Ty.TensorTy[n,m], args) => let
409 :     (* matrices are represented as arrays of union<d><ty>_t vectors *)
410 :     fun doRows (_, []) = []
411 :     | doRows (i, e::es) =
412 :     CL.mkAssign(CL.mkSelect(CL.mkSubscript(lhs, intExp i), "v"), e)
413 :     :: doRows (i+1, es)
414 :     in
415 :     doRows (0, trExps(env, args))
416 :     end
417 :     | IL.E_Var x => (case IL.Var.ty x
418 :     of Ty.TensorTy[n,m] => [CL.mkCall(N.copyMat(n,m), [lhs, VarToC.rvalueVar(env, x)])]
419 :     | _ => [CL.mkAssign(lhs, VarToC.rvalueVar(env, x))]
420 :     (* end case *))
421 :     | _ => [CL.mkAssign(lhs, trExp(env, rhs))]
422 :     (* end case *))
423 :    
424 :     fun trMultiAssign (env, lhs, IL.E_Op(rator, args)) = (case (lhs, rator, args)
425 :     of ([vals, vecs], Op.EigenVecs2x2, [m]) => let
426 :     val (m, stms) = expToVar (env, CL.T_Named(N.matTy(2,2)), "m", m)
427 :     in
428 :     stms @ [CL.mkCall(N.evecs2x2, [
429 :     vals, vecs,
430 :     matIndex (m, CL.mkInt 0, CL.mkInt 0),
431 :     matIndex (m, CL.mkInt 0, CL.mkInt 1),
432 :     matIndex (m, CL.mkInt 1, CL.mkInt 1)
433 :     ])]
434 :     end
435 :     | ([vals, vecs], Op.EigenVecs3x3, [m]) => let
436 :     val (m, stms) = expToVar (env, CL.T_Named(N.matTy(3,3)), "m", m)
437 :     in
438 :     stms @ [CL.mkCall(N.evecs3x3, [
439 :     vals, vecs,
440 :     matIndex (m, CL.mkInt 0, CL.mkInt 0),
441 :     matIndex (m, CL.mkInt 0, CL.mkInt 1),
442 :     matIndex (m, CL.mkInt 0, CL.mkInt 2),
443 :     matIndex (m, CL.mkInt 1, CL.mkInt 1),
444 :     matIndex (m, CL.mkInt 1, CL.mkInt 2),
445 :     matIndex (m, CL.mkInt 2, CL.mkInt 2)
446 :     ])]
447 :     end
448 :     | ([], Op.Print tys, args) => trPrint (env, tys, args)
449 :     | _ => raise Fail "bogus multi-assignment"
450 :     (* end case *))
451 :     | trMultiAssign (env, lhs, rhs) = raise Fail "bogus multi-assignment"
452 :    
453 :     fun trLocals (env : env, locals) =
454 :     List.foldl
455 :     (fn (x, env) => V.Map.insert(env, x, V(trType(V.ty x), V.name x)))
456 :     env locals
457 :    
458 :     (* generate code to check the status of runtime-system calls *)
459 :     fun checkSts mkDecl = let
460 :     val sts = freshVar "sts"
461 :     in
462 :     mkDecl sts @
463 :     [CL.mkIfThen(
464 :     CL.mkBinOp(CL.mkVar "DIDEROT_OK", CL.#!=, CL.mkVar sts),
465 :     CL.mkCall("exit", [intExp 1]))]
466 :     end
467 :    
468 :     fun trStms (env, stms) = let
469 :     fun trStmt (env, stm) = (case stm
470 :     of IL.S_Comment text => [CL.mkComment text]
471 :     | IL.S_Assign([x], exp) => trAssign (env, VarToC.lvalueVar (env, x), exp)
472 :     | IL.S_Assign(xs, exp) =>
473 :     trMultiAssign (env, List.map (fn x => VarToC.lvalueVar (env, x)) xs, exp)
474 :     | IL.S_IfThen(cond, thenBlk) =>
475 :     [CL.mkIfThen(trExp(env, cond), trBlk(env, thenBlk))]
476 :     | IL.S_IfThenElse(cond, thenBlk, elseBlk) =>
477 :     [CL.mkIfThenElse(trExp(env, cond),
478 :     trBlk(env, thenBlk),
479 :     trBlk(env, elseBlk))]
480 :     | IL.S_New _ => raise Fail "new not supported yet" (* FIXME *)
481 :     | IL.S_Save([x], exp) => trAssign (env, VarToC.lvalueStateVar x, exp)
482 :     | IL.S_Save(xs, exp) =>
483 :     trMultiAssign (env, List.map VarToC.lvalueStateVar xs, exp)
484 :     | IL.S_LoadImage(lhs, dim, name) => checkSts (fn sts => let
485 :     val lhs = VarToC.lvalueVar (env, lhs)
486 :     val name = trExp(env, name)
487 :     val imgTy = CL.T_Named(N.imageTy dim)
488 :     val loadFn = N.loadImage dim
489 :     in [
490 :     CL.mkDecl(
491 :     CL.T_Named N.statusTy, sts,
492 :     SOME(CL.I_Exp(CL.E_Apply(loadFn, [name, CL.mkUnOp(CL.%&, lhs)]))))
493 :     ] end)
494 :     | IL.S_Input(lhs, name, desc, optDflt) => let
495 :     val inputFn = N.input(V.ty lhs)
496 :     val lhs = VarToC.lvalueVar (env, lhs)
497 :     val (initCode, hasDflt) = (case optDflt
498 :     of SOME e => ([CL.mkAssign(lhs, trExp(env, e))], true)
499 :     | NONE => ([], false)
500 :     (* end case *))
501 :     val code = [CL.mkCall(inputFn, [
502 :     CL.mkVar "opts",
503 :     CL.mkStr name,
504 :     CL.mkStr desc,
505 :     CL.mkUnOp(CL.%&, lhs),
506 :     CL.mkBool hasDflt])]
507 :     in
508 :     initCode @ code
509 :     end
510 :     | IL.S_Exit args => [CL.mkReturn NONE]
511 :     | IL.S_Active => [CL.mkReturn(SOME(CL.mkVar N.kActive))]
512 :     | IL.S_Stabilize => [CL.mkReturn(SOME(CL.mkVar N.kStabilize))]
513 :     | IL.S_Die => [CL.mkReturn(SOME(CL.mkVar N.kDie))]
514 :     (* end case *))
515 :     in
516 :     List.foldr (fn (stm, stms) => trStmt(env, stm)@stms) [] stms
517 :     end
518 :    
519 :     and trBlk (env, IL.Block{locals, body}) = let
520 :     val env = trLocals (env, locals)
521 :     val stms = trStms (env, body)
522 :     fun mkDecl (x, stms) = (case V.Map.find (env, x)
523 :     of SOME(V(ty, x')) => CL.mkDecl(ty, x', NONE) :: stms
524 :     | NONE => raise Fail(concat["mkDecl(", V.name x, ", _)"])
525 :     (* end case *))
526 :     val stms = List.foldr mkDecl stms locals
527 :     in
528 :     CL.mkBlock stms
529 :     end
530 :    
531 :     fun trFragment (env, IL.Block{locals, body}) = let
532 :     val env = trLocals (env, locals)
533 :     val stms = trStms (env, body)
534 :     fun mkDecl (x, stms) = (case V.Map.find (env, x)
535 :     of SOME(V(ty, x')) => CL.mkDecl(ty, x', NONE) :: stms
536 :     | NONE => raise Fail(concat["mkDecl(", V.name x, ", _)"])
537 :     (* end case *))
538 :     val stms = List.foldr mkDecl stms locals
539 :     in
540 :     (env, stms)
541 :     end
542 :    
543 :     val trBlock = trBlk
544 :    
545 :     end

root@smlnj-gforge.cs.uchicago.edu
ViewVC Help
Powered by ViewVC 1.0.0