Home My Page Projects Code Snippets Project Openings diderot
Summary Activity Tracker Tasks SCM

SCM Repository

[diderot] Annotation of /branches/vis12/src/compiler/c-util/tree-to-c-fn.sml
ViewVC logotype

Annotation of /branches/vis12/src/compiler/c-util/tree-to-c-fn.sml

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1939 - (view) (download)

1 : jhr 1640 (* tree-to-c.sml
2 :     *
3 :     * COPYRIGHT (c) 2011 The Diderot Project (http://diderot-language.cs.uchicago.edu)
4 :     * All rights reserved.
5 :     *
6 :     * Translate TreeIL to the C version of CLang.
7 :     *)
8 :    
9 :     signature TREE_VAR_TO_C =
10 :     sig
11 :     type env = CLang.typed_var TreeIL.Var.Map.map
12 :     (* translate a variable that occurs in an l-value context (i.e., as the target of an assignment) *)
13 :     val lvalueVar : env * TreeIL.var -> CLang.exp
14 :     (* translate a variable that occurs in a r-value context *)
15 :     val rvalueVar : env * TreeIL.var -> CLang.exp
16 :     (* translate a strand state variable that occurs in an l-value context *)
17 :     val lvalueStateVar : TreeIL.state_var -> CLang.exp
18 :     (* translate a strand state variable that occurs in a r-value context *)
19 :     val rvalueStateVar : TreeIL.state_var -> CLang.exp
20 :     end
21 :    
22 :     functor TreeToCFn (VarToC : TREE_VAR_TO_C) : sig
23 :    
24 :     type env = CLang.typed_var TreeIL.Var.Map.map
25 :    
26 :     val trType : TreeIL.Ty.ty -> CLang.ty
27 :    
28 :     val trBlock : env * TreeIL.block -> CLang.stm
29 :    
30 : nseltzer 1870 val trFree : env * TreeIL.block -> CLang.stm
31 :    
32 : jhr 1640 val trFragment : env * TreeIL.block -> env * CLang.stm list
33 :    
34 :     val trExp : env * TreeIL.exp -> CLang.exp
35 :    
36 :     (* vector indexing support. Arguments are: vector, arity, index *)
37 :     val ivecIndex : CLang.exp * int * int -> CLang.exp
38 :     val vecIndex : CLang.exp * int * int -> CLang.exp
39 :    
40 :     end = struct
41 :    
42 :     structure CL = CLang
43 :     structure N = CNames
44 :     structure IL = TreeIL
45 :     structure Op = IL.Op
46 :     structure Ty = IL.Ty
47 :     structure V = IL.Var
48 :    
49 :     datatype var = datatype CLang.typed_var
50 :     type env = CLang.typed_var TreeIL.Var.Map.map
51 :    
52 :     fun lookup (env, x) = (case V.Map.find (env, x)
53 :     of SOME(V(_, x')) => x'
54 :     | NONE => raise Fail(concat["lookup(_, ", V.name x, ")"])
55 :     (* end case *))
56 :    
57 :     (* integer literal expression *)
58 :     fun intExp (i : int) = CL.mkInt(IntInf.fromInt i)
59 :    
60 : jhr 1691 fun addrOf e = CL.mkUnOp(CL.%&, e)
61 :    
62 : jhr 1640 (* translate TreeIL types to CLang types *)
63 : jhr 1820 val trType = CTyTranslate.toType
64 : jhr 1640
65 :     (* generate new variables *)
66 :     local
67 :     val count = ref 0
68 :     fun freshName prefix = let
69 :     val n = !count
70 :     in
71 :     count := n+1;
72 :     concat[prefix, "_", Int.toString n]
73 :     end
74 :     in
75 :     fun tmpVar ty = freshName "tmp"
76 :     fun freshVar prefix = freshName prefix
77 :     end (* local *)
78 :    
79 :     (* translate IL basis functions *)
80 :     local
81 :     fun mkLookup suffix = let
82 : jhr 1922 val tbl = MathFuns.Tbl.mkTable (16, Fail "basis table")
83 :     fun ins f = MathFuns.Tbl.insert tbl (f, MathFuns.toString f ^ suffix)
84 : jhr 1640 in
85 : jhr 1922 List.app ins MathFuns.allFuns;
86 :     MathFuns.Tbl.lookup tbl
87 : jhr 1640 end
88 :     val fLookup = mkLookup "f"
89 :     val dLookup = mkLookup ""
90 :     in
91 :     fun trApply (f, args) = let
92 :     val f' = if !N.doublePrecision then dLookup f else fLookup f
93 :     in
94 :     CL.mkApply(f', args)
95 :     end
96 :     end (* local *)
97 :    
98 :     (* vector indexing support. Arguments are: vector, arity, index *)
99 :     fun ivecIndex (v, n, ix) = let
100 : jhr 1858 val e1 = CL.mkCast(CL.T_Named(N.iunionTy n), v)
101 : jhr 1640 val e2 = CL.mkSelect(e1, "i")
102 :     in
103 :     CL.mkSubscript(e2, intExp ix)
104 :     end
105 :    
106 :     fun vecIndex (v, n, ix) = let
107 : jhr 1858 val e1 = CL.mkCast(CL.T_Named(N.unionTy n), v)
108 : jhr 1640 val e2 = CL.mkSelect(e1, "r")
109 :     in
110 :     CL.mkSubscript(e2, intExp ix)
111 :     end
112 :    
113 :     (* matrix indexing *)
114 :     fun matIndex (m, ix, jx) =
115 :     CL.mkSubscript(CL.mkSelect(CL.mkSubscript(m, ix), "r"), jx)
116 :    
117 :     (* Translate a TreeIL operator application to a CLang expression *)
118 :     fun trOp (rator, args) = (case (rator, args)
119 :     of (Op.Add ty, [a, b]) => CL.mkBinOp(a, CL.#+, b)
120 :     | (Op.Sub ty, [a, b]) => CL.mkBinOp(a, CL.#-, b)
121 :     | (Op.Mul ty, [a, b]) => CL.mkBinOp(a, CL.#*, b)
122 :     | (Op.Div ty, [a, b]) => CL.mkBinOp(a, CL.#/, b)
123 :     | (Op.Neg ty, [a]) => CL.mkUnOp(CL.%-, a)
124 :     | (Op.Abs(Ty.IntTy), args) => CL.mkApply("abs", args)
125 :     | (Op.Abs(Ty.TensorTy[]), args) => CL.mkApply(N.fabs(), args)
126 :     | (Op.Abs ty, [a]) => raise Fail(concat["Abs<", Ty.toString ty, ">"])
127 :     | (Op.LT ty, [a, b]) => CL.mkBinOp(a, CL.#<, b)
128 :     | (Op.LTE ty, [a, b]) => CL.mkBinOp(a, CL.#<=, b)
129 :     | (Op.EQ ty, [a, b]) => CL.mkBinOp(a, CL.#==, b)
130 :     | (Op.NEQ ty, [a, b]) => CL.mkBinOp(a, CL.#!=, b)
131 :     | (Op.GTE ty, [a, b]) => CL.mkBinOp(a, CL.#>=, b)
132 :     | (Op.GT ty, [a, b]) => CL.mkBinOp(a, CL.#>, b)
133 :     | (Op.Not, [a]) => CL.mkUnOp(CL.%!, a)
134 :     | (Op.Max, args) => CL.mkApply(N.max(), args)
135 :     | (Op.Min, args) => CL.mkApply(N.min(), args)
136 :     | (Op.Clamp(Ty.TensorTy[]), args) => CL.mkApply(N.clamp 1, args)
137 :     | (Op.Clamp(Ty.TensorTy[n]), args) => CL.mkApply(N.clamp n, args)
138 :     | (Op.Lerp ty, args) => (case ty
139 :     of Ty.TensorTy[] => CL.mkApply(N.lerp 1, args)
140 :     | Ty.TensorTy[n] => CL.mkApply(N.lerp n, args)
141 :     | _ => raise Fail(concat[
142 :     "lerp<", Ty.toString ty, "> not supported"
143 :     ])
144 :     (* end case *))
145 :     | (Op.Dot d, args) => CL.E_Apply(N.dot d, args)
146 :     | (Op.MulVecMat(m, n), args) =>
147 : jhr 1939 if (1 < m) andalso (m <= 4) andalso (m = n)
148 : jhr 1640 then CL.E_Apply(N.mulVecMat(m,n), args)
149 :     else raise Fail "unsupported vector-matrix multiply"
150 :     | (Op.MulMatVec(m, n), args) =>
151 : jhr 1939 if (1 < m) andalso (m <= 4) andalso (m = n)
152 : jhr 1640 then CL.E_Apply(N.mulMatVec(m,n), args)
153 :     else raise Fail "unsupported matrix-vector multiply"
154 :     | (Op.MulMatMat(m, n, p), args) =>
155 : jhr 1939 if (1 < m) andalso (m <= 4) andalso (m = n) andalso (n = p)
156 : jhr 1640 then CL.E_Apply(N.mulMatMat(m,n,p), args)
157 :     else raise Fail "unsupported matrix-matrix multiply"
158 :     | (Op.Cross, args) => CL.E_Apply(N.cross(), args)
159 :     | (Op.Norm(Ty.TensorTy[n]), args) => CL.E_Apply(N.length n, args)
160 : jhr 1939 | (Op.Norm(Ty.TensorTy[m,n]), args) => CL.E_Apply(N.normMat(m,n), args)
161 :     | (Op.Norm(Ty.TensorTy[m,n,p]), args) => CL.E_Apply(N.normTen3(m,n,p), args)
162 : jhr 1640 | (Op.Normalize d, args) => CL.E_Apply(N.normalize d, args)
163 :     | (Op.Scale(Ty.TensorTy[n]), args) => CL.E_Apply(N.scale n, args)
164 :     | (Op.PrincipleEvec ty, _) => raise Fail "PrincipleEvec unimplemented"
165 :     | (Op.Select(Ty.TupleTy tys, i), [a]) => raise Fail "Select unimplemented"
166 :     | (Op.Index(Ty.SeqTy(Ty.IntTy, n), i), [a]) => ivecIndex (a, n, i)
167 :     | (Op.Index(Ty.TensorTy[n], i), [a]) => vecIndex (a, n, i)
168 :     | (Op.Subscript(Ty.SeqTy(Ty.IntTy, n)), [v, ix]) => let
169 : jhr 1858 val unionTy = CL.T_Named(N.iunionTy n)
170 : jhr 1640 val vecExp = CL.mkSelect(CL.mkCast(unionTy, v), "i")
171 :     in
172 :     CL.mkSubscript(vecExp, ix)
173 :     end
174 :     | (Op.Subscript(Ty.SeqTy(ty, n)), [v, ix]) => CL.mkSubscript(v, ix)
175 :     | (Op.Subscript(Ty.TensorTy[n]), [v, ix]) => let
176 : jhr 1858 val unionTy = CL.T_Named(N.unionTy n)
177 : jhr 1640 val vecExp = CL.mkSelect(CL.mkCast(unionTy, v), "r")
178 :     in
179 :     CL.mkSubscript(vecExp, ix)
180 :     end
181 :     | (Op.Subscript(Ty.TensorTy[_,_]), [m, ix, jx]) => matIndex (m, ix, jx)
182 :     | (Op.Subscript ty, t::(ixs as _::_)) =>
183 :     raise Fail(concat["Subscript<", Ty.toString ty, "> unsupported"])
184 : jhr 1691 | (Op.MkDynamic(ty, n), [seq]) => CL.mkApply("Diderot_DynSeqMk", [
185 :     CL.mkSizeof(trType ty), CL.mkInt(IntInf.fromInt n),
186 :     addrOf (CL.mkSubscript(seq, intExp 0))
187 : jhr 1690 ])
188 : jhr 1691 | (Op.Append ty, [seq, x]) => CL.mkApply("Diderot_DynSeqAppend", [
189 :     CL.mkSizeof(trType ty), seq, addrOf x
190 : jhr 1690 ])
191 : jhr 1691 | (Op.Prepend ty, [x, seq]) => CL.mkApply("Diderot_DynSeqPrepend", [
192 :     CL.mkSizeof(trType ty), addrOf x, seq
193 : jhr 1690 ])
194 : jhr 1691 | (Op.Concat ty, [seq1, seq2]) => CL.mkApply("Diderot_DynSeqConcat", [
195 : jhr 1690 CL.mkSizeof(trType ty), seq1, seq2
196 :     ])
197 : jhr 1925 | (Op.Length _, [seq]) => CL.mkApply("Diderot_DynSeqLength", [seq])
198 : jhr 1640 | (Op.Ceiling d, args) => CL.mkApply(N.addTySuffix("ceil", d), args)
199 :     | (Op.Floor d, args) => CL.mkApply(N.addTySuffix("floor", d), args)
200 :     | (Op.Round d, args) => CL.mkApply(N.addTySuffix("round", d), args)
201 :     | (Op.Trunc d, args) => CL.mkApply(N.addTySuffix("trunc", d), args)
202 :     | (Op.IntToReal, [a]) => CL.mkCast(!N.gRealTy, a)
203 :     | (Op.RealToInt 1, [a]) => CL.mkCast(!N.gIntTy, a)
204 :     | (Op.RealToInt d, args) => CL.mkApply(N.vecftoi d, args)
205 : jhr 1793 | (Op.ImageAddress info, [a]) => let
206 :     val cTy = CL.T_Ptr(CL.T_Num(ImageInfo.sampleTy info))
207 : jhr 1640 in
208 :     CL.mkCast(cTy, CL.mkIndirect(a, "data"))
209 :     end
210 :     | (Op.LoadVoxels(info, 1), [a]) => let
211 :     val realTy as CL.T_Num rTy = !N.gRealTy
212 :     val a = CL.E_UnOp(CL.%*, a)
213 :     in
214 :     if (rTy = ImageInfo.sampleTy info)
215 :     then a
216 :     else CL.E_Cast(realTy, a)
217 :     end
218 :     | (Op.LoadVoxels _, [a]) =>
219 :     raise Fail("impossible " ^ Op.toString rator)
220 : jhr 1793 | (Op.PosToImgSpace info, [img, pos]) =>
221 :     CL.mkApply(N.toImageSpace(ImageInfo.dim info), [img, pos])
222 : jhr 1640 | (Op.TensorToWorldSpace(info, ty), [v, x]) =>
223 :     CL.mkApply(N.toWorldSpace ty, [v, x])
224 :     | (Op.LoadImage info, [a]) =>
225 :     raise Fail("impossible " ^ Op.toString rator)
226 : jhr 1793 | (Op.Inside(info, s), [pos, img]) =>
227 :     CL.mkApply(N.inside(ImageInfo.dim info), [pos, img, intExp s])
228 : jhr 1640 | (Op.Input(ty, desc, name), []) =>
229 :     raise Fail("impossible " ^ Op.toString rator)
230 :     | (Op.InputWithDefault(ty, desc, name), [a]) =>
231 :     raise Fail("impossible " ^ Op.toString rator)
232 :     | _ => raise Fail(concat[
233 :     "unknown or incorrect operator ", Op.toString rator
234 :     ])
235 :     (* end case *))
236 :    
237 :     fun trExp (env, e) = (case e
238 :     of IL.E_State x => VarToC.rvalueStateVar x
239 :     | IL.E_Var x => VarToC.rvalueVar (env, x)
240 :     | IL.E_Lit(Literal.Int n) => CL.mkIntTy(n, !N.gIntTy)
241 :     | IL.E_Lit(Literal.Bool b) => CL.mkBool b
242 :     | IL.E_Lit(Literal.Float f) => CL.mkFlt(f, !N.gRealTy)
243 :     | IL.E_Lit(Literal.String s) => CL.mkStr s
244 :     | IL.E_Op(rator, args) => trOp (rator, trExps(env, args))
245 :     | IL.E_Apply(f, args) => trApply(f, trExps(env, args))
246 :     | IL.E_Cons(Ty.TensorTy[n], args) => CL.mkApply(N.mkVec n, trExps(env, args))
247 :     | IL.E_Cons(ty, _) => raise Fail(concat["E_Cons(", Ty.toString ty, ", _) in expression"])
248 :     (* end case *))
249 :    
250 :     and trExps (env, exps) = List.map (fn exp => trExp(env, exp)) exps
251 :    
252 :     (* translate an expression to a variable form; return the variable and the
253 :     * (optional) declaration.
254 :     *)
255 :     fun expToVar (env, ty, name, exp) = (case trExp(env, exp)
256 :     of x as CL.E_Var _ => (x, [])
257 :     | exp => let
258 :     val x = freshVar name
259 :     in
260 :     (CL.mkVar x, [CL.mkDecl(ty, x, SOME(CL.I_Exp exp))])
261 :     end
262 :     (* end case *))
263 :    
264 :     (* translate a print statement *)
265 :     fun trPrint (env, tys, args) = let
266 :     (* assemble the format string by analysing the types and argument expressions *)
267 :     fun mkFmt (Ty.StringTy, IL.E_Lit(Literal.String s), (stms, fmt, args)) =
268 :     (stms, s::fmt, args)
269 :     | mkFmt (ty, exp, (stms, fmt, args)) = let
270 :     fun mk (f, e) = (stms, f::fmt, e::args)
271 :     in
272 :     case ty
273 :     of Ty.BoolTy => mk(
274 :     "%s",
275 :     CL.mkCond(trExp(env, exp), CL.mkStr "true", CL.mkStr "false"))
276 :     | Ty.StringTy => mk("%s", trExp(env, exp))
277 :     | Ty.IntTy => mk(!N.gIntFormat, trExp(env, exp))
278 :     | Ty.TensorTy[] => mk("%f", trExp(env, exp))
279 :     | Ty.TensorTy[n] => let
280 :     val (x, stm) = expToVar (env, trType ty, "vec", exp)
281 :     val elems = List.tabulate (n, fn i => vecIndex (x, n, i))
282 :     val (fmt, args) = mkSeqFmt (Ty.TensorTy[], elems, fmt, args)
283 :     in
284 :     (stm@stms, fmt, args)
285 :     end
286 :     (*
287 :     | Ty.TensorTy[n, m] =>
288 :     *)
289 :     | Ty.SeqTy(elemTy, n) => let
290 :     val (x, stm) = expToVar (env, trType ty, "vec", exp)
291 :     val elems = List.tabulate (n, fn i => ivecIndex (x, n, i))
292 :     val (fmt, args) = mkSeqFmt (elemTy, elems, fmt, args)
293 :     in
294 :     (stm@stms, fmt, args)
295 :     end
296 :     | _ => raise Fail(concat["TreeToC.trPrint(", Ty.toString ty, ")"])
297 :     (* end case *)
298 :     end
299 :     and mkElemFmt (elemTy, elem, (fmt, args)) = (case elemTy
300 :     of Ty.BoolTy =>
301 :     ("%s"::fmt, CL.mkCond(elem, CL.mkStr "true", CL.mkStr "false")::args)
302 :     | Ty.StringTy => ("%s"::fmt, elem::args)
303 :     | Ty.IntTy => (!N.gIntFormat::fmt, elem::args)
304 :     | Ty.TensorTy[] => ("%f"::fmt, elem::args)
305 :     | Ty.TensorTy[n] => let
306 :     val elems = List.tabulate (n, fn i => vecIndex (elem, n, i))
307 :     in
308 :     mkSeqFmt (Ty.TensorTy[], elems, fmt, args)
309 :     end
310 :     (*
311 :     | Ty.TensorTy[n, m] =>
312 :     *)
313 :     | Ty.SeqTy(elemTy, n) => let
314 :     val elems = List.tabulate (n, fn i => ivecIndex (elem, n, i))
315 :     in
316 :     mkSeqFmt (elemTy, elems, fmt, args)
317 :     end
318 :     | _ => raise Fail(concat["TreeToC.mkElemFmt(", Ty.toString elemTy, ")"])
319 :     (* end case *))
320 :     and mkSeqFmt (elemTy, elems, fmt, args) = let
321 :     fun mk (elem, acc) = mkFmt(elemTy, elem, acc)
322 :     val (seqFmt, args) =
323 :     List.foldr
324 :     (fn (elem, acc) => mkElemFmt(elemTy, elem, acc))
325 :     ([], args) elems
326 :     in
327 :     ("<" :: String.concatWith "," seqFmt :: ">" :: fmt, args)
328 :     end
329 :     val (stms, fmt, args) = ListPair.foldr mkFmt ([], [], []) (tys, args)
330 :     val stm = CL.mkCall("fprintf", CL.mkVar "stderr" :: CL.mkStr(String.concat fmt) :: args)
331 :     in
332 :     List.rev (stm :: stms)
333 :     end
334 :    
335 :     fun trAssign (env, lhs, rhs) = (
336 :     (* certain rhs forms, such as those that return a matrix,
337 :     * require a function call instead of an assignment
338 :     *)
339 :     case rhs
340 :     of IL.E_Op(Op.Add(Ty.TensorTy[m,n]), args) =>
341 :     [CL.mkCall(N.addMat(m,n), lhs :: trExps(env, args))]
342 :     | IL.E_Op(Op.Sub(Ty.TensorTy[m,n]), args) =>
343 :     [CL.mkCall(N.subMat(m,n), lhs :: trExps(env, args))]
344 :     | IL.E_Op(Op.Neg(Ty.TensorTy[m,n]), args) =>
345 :     [CL.mkCall(N.scaleMat(m,n), lhs :: intExp ~1 :: trExps(env, args))]
346 :     | IL.E_Op(Op.Scale(Ty.TensorTy[m,n]), args) =>
347 :     [CL.mkCall(N.scaleMat(m,n), lhs :: trExps(env, args))]
348 :     | IL.E_Op(Op.MulMatMat(m,n,p), args) =>
349 :     [CL.mkCall(N.mulMatMat(m,n,p), lhs :: trExps(env, args))]
350 : jhr 1939 | IL.E_Op(Op.MulVecTen3(m, n, p), args) =>
351 :     if (1 < m) andalso (m <= 4) andalso (m = n) andalso (n = p)
352 :     then [CL.mkCall(N.mulVecTen3(m,n,p), lhs :: trExps(env, args))]
353 :     else raise Fail "unsupported vector-tensor multiply"
354 :     | IL.E_Op(Op.MulTen3Vec(m, n, p), args) =>
355 :     if (1 < m) andalso (m <= 4) andalso (m = n) andalso (n = p)
356 :     then [CL.mkCall(N.mulTen3Vec(m,n,p), lhs :: trExps(env, args))]
357 :     else raise Fail "unsupported tensor-vector multiply"
358 : jhr 1640 | IL.E_Op(Op.EigenVals2x2, [m]) => let
359 :     val (m, stms) = expToVar (env, CL.T_Named(N.matTy(2,2)), "m", m)
360 :     in
361 :     stms @ [CL.mkCall(N.evals2x2, [
362 :     lhs,
363 :     matIndex (m, CL.mkInt 0, CL.mkInt 0),
364 :     matIndex (m, CL.mkInt 0, CL.mkInt 1),
365 :     matIndex (m, CL.mkInt 1, CL.mkInt 1)
366 :     ])]
367 :     end
368 :     | IL.E_Op(Op.EigenVals3x3, [m]) => let
369 :     val (m, stms) = expToVar (env, CL.T_Named(N.matTy(3,3)), "m", m)
370 :     in
371 :     stms @ [CL.mkCall(N.evals3x3, [
372 :     lhs,
373 :     matIndex (m, CL.mkInt 0, CL.mkInt 0),
374 :     matIndex (m, CL.mkInt 0, CL.mkInt 1),
375 :     matIndex (m, CL.mkInt 0, CL.mkInt 2),
376 :     matIndex (m, CL.mkInt 1, CL.mkInt 1),
377 :     matIndex (m, CL.mkInt 1, CL.mkInt 2),
378 :     matIndex (m, CL.mkInt 2, CL.mkInt 2)
379 :     ])]
380 :     end
381 :     | IL.E_Op(Op.Identity n, args) =>
382 :     [CL.mkCall(N.identityMat n, [lhs])]
383 :     | IL.E_Op(Op.Zero(Ty.TensorTy[m,n]), args) =>
384 :     [CL.mkCall(N.zeroMat(m,n), [lhs])]
385 :     | IL.E_Op(Op.TensorToWorldSpace(info, ty as Ty.TensorTy[_,_]), args) =>
386 :     [CL.mkCall(N.toWorldSpace ty, lhs :: trExps(env, args))]
387 :     | IL.E_Op(Op.LoadVoxels(info, n), [a]) =>
388 :     if (n > 1)
389 :     then let
390 :     val stride = ImageInfo.stride info
391 :     val rTy = ImageInfo.sampleTy info
392 :     val vp = freshVar "vp"
393 :     val needsCast = (CL.T_Num rTy <> !N.gRealTy)
394 :     fun mkLoad i = let
395 :     val e = CL.mkSubscript(CL.mkVar vp, intExp(i*stride))
396 :     in
397 :     if needsCast then CL.mkCast(!N.gRealTy, e) else e
398 :     end
399 :     in [
400 :     CL.mkDecl(CL.T_Ptr(CL.T_Num rTy), vp, SOME(CL.I_Exp(trExp(env, a)))),
401 :     CL.mkAssign(lhs,
402 :     CL.mkApply(N.mkVec n, List.tabulate (n, mkLoad)))
403 :     ] end
404 :     else [CL.mkAssign(lhs, trExp(env, rhs))]
405 :     | IL.E_Cons(Ty.TensorTy[n,m], args) => let
406 :     (* matrices are represented as arrays of union<d><ty>_t vectors *)
407 :     fun doRows (_, []) = []
408 :     | doRows (i, e::es) =
409 :     CL.mkAssign(CL.mkSelect(CL.mkSubscript(lhs, intExp i), "v"), e)
410 :     :: doRows (i+1, es)
411 :     in
412 :     doRows (0, trExps(env, args))
413 :     end
414 : jhr 1797 | IL.E_Cons(Ty.TensorTy[n,m,l], args) => let
415 :     (* 3rd-order tensors are represented as 2D arrays of union<d><ty>_t vectors *)
416 :     fun lp1 (i, [], code) = code
417 :     | lp1 (i, e::es, code) = let
418 :     val lhs_i = CL.mkSubscript(lhs, intExp i)
419 :     fun lp2 j = if (j < m)
420 :     then CL.mkAssign(
421 :     CL.mkSelect(CL.mkSubscript(lhs_i, intExp j), "v"),
422 :     CL.mkSelect(CL.mkSubscript (e, intExp j), "v")
423 :     ) :: lp2(j+1)
424 :     else code
425 :     in
426 :     lp1 (i+1, es, lp2 0)
427 :     end
428 :     in
429 :     lp1 (0, trExps(env, args), [])
430 :     end
431 : jhr 1691 | IL.E_Cons(Ty.SeqTy(ty, n), args) => let
432 :     fun doAssign (_, []) = []
433 :     | doAssign (i, arg::args) =
434 :     CL.mkAssign(CL.mkSubscript(lhs, intExp i), arg) :: doAssign(i+1, args)
435 :     in
436 :     doAssign (0, trExps(env, args))
437 :     end
438 : jhr 1754 | IL.E_State x => (case IL.StateVar.ty x
439 :     of Ty.TensorTy[n,m] => [CL.mkCall(N.copyMat(n,m), [lhs, VarToC.rvalueStateVar x])]
440 :     | Ty.TensorTy[n,m,l] => [CL.mkCall(N.copyTen(n,m,l), [lhs, VarToC.rvalueStateVar x])]
441 :     | _ => [CL.mkAssign(lhs, VarToC.rvalueStateVar x)]
442 :     (* end case *))
443 : jhr 1640 | IL.E_Var x => (case IL.Var.ty x
444 :     of Ty.TensorTy[n,m] => [CL.mkCall(N.copyMat(n,m), [lhs, VarToC.rvalueVar(env, x)])]
445 : jhr 1754 | Ty.TensorTy[n,m,l] => [CL.mkCall(N.copyTen(n,m,l), [lhs, VarToC.rvalueVar(env, x)])]
446 : jhr 1640 | _ => [CL.mkAssign(lhs, VarToC.rvalueVar(env, x))]
447 :     (* end case *))
448 :     | _ => [CL.mkAssign(lhs, trExp(env, rhs))]
449 :     (* end case *))
450 :    
451 :     fun trMultiAssign (env, lhs, IL.E_Op(rator, args)) = (case (lhs, rator, args)
452 :     of ([vals, vecs], Op.EigenVecs2x2, [m]) => let
453 :     val (m, stms) = expToVar (env, CL.T_Named(N.matTy(2,2)), "m", m)
454 :     in
455 :     stms @ [CL.mkCall(N.evecs2x2, [
456 :     vals, vecs,
457 :     matIndex (m, CL.mkInt 0, CL.mkInt 0),
458 :     matIndex (m, CL.mkInt 0, CL.mkInt 1),
459 :     matIndex (m, CL.mkInt 1, CL.mkInt 1)
460 :     ])]
461 :     end
462 :     | ([vals, vecs], Op.EigenVecs3x3, [m]) => let
463 :     val (m, stms) = expToVar (env, CL.T_Named(N.matTy(3,3)), "m", m)
464 :     in
465 :     stms @ [CL.mkCall(N.evecs3x3, [
466 :     vals, vecs,
467 :     matIndex (m, CL.mkInt 0, CL.mkInt 0),
468 :     matIndex (m, CL.mkInt 0, CL.mkInt 1),
469 :     matIndex (m, CL.mkInt 0, CL.mkInt 2),
470 :     matIndex (m, CL.mkInt 1, CL.mkInt 1),
471 :     matIndex (m, CL.mkInt 1, CL.mkInt 2),
472 :     matIndex (m, CL.mkInt 2, CL.mkInt 2)
473 :     ])]
474 :     end
475 :     | ([], Op.Print tys, args) => trPrint (env, tys, args)
476 :     | _ => raise Fail "bogus multi-assignment"
477 :     (* end case *))
478 :     | trMultiAssign (env, lhs, rhs) = raise Fail "bogus multi-assignment"
479 :    
480 :     fun trLocals (env : env, locals) =
481 :     List.foldl
482 :     (fn (x, env) => V.Map.insert(env, x, V(trType(V.ty x), V.name x)))
483 :     env locals
484 :    
485 : jhr 1807 (* generate code to check the status of runtime-system calls; this code assumes that
486 :     * we are in a function with a boolean return type
487 :     *)
488 : jhr 1640 fun checkSts mkDecl = let
489 :     val sts = freshVar "sts"
490 :     in
491 :     mkDecl sts @
492 :     [CL.mkIfThen(
493 :     CL.mkBinOp(CL.mkVar "DIDEROT_OK", CL.#!=, CL.mkVar sts),
494 : jhr 1807 CL.mkReturn(SOME(CL.mkVar "true")))]
495 : jhr 1640 end
496 :    
497 : jhr 1872 (* given the global initialization code, generate code to free the storage that is heap
498 :     * allocated for globals.
499 :     *)
500 :     fun trFree (env, IL.Block{locals, body}) = let
501 :     val env = trLocals (env, locals)
502 : nseltzer 1870 fun trStmt (env, stm) = (case stm
503 :     of IL.S_Comment text => [CL.mkComment text]
504 :     | IL.S_LoadImage(lhs, dim, name) => checkSts (fn sts => let
505 :     val lhs = VarToC.lvalueVar (env, lhs)
506 :     val imgTy = CL.T_Named(N.imageTy dim)
507 :     val freeFn = N.freeImage dim
508 :     in [
509 :     CL.mkDecl(
510 :     CL.T_Named N.statusTy, sts,
511 :     SOME(CL.I_Exp(CL.E_Apply(freeFn, [
512 :     CL.mkCast(CL.T_Ptr(CL.T_Named "WorldPrefix_t"), CL.mkVar "wrld"),
513 :     addrOf lhs
514 :     ]))))
515 :     ] end)
516 :     | _ => []
517 :     (* end case *))
518 : jhr 1872 val stms = List.foldr (fn (stm, stms) => trStmt(env, stm)@stms) [] body
519 : nseltzer 1870 fun mkDecl (x, stms) = (case V.Map.find (env, x)
520 :     of SOME(V(ty, x')) => CL.mkDecl(ty, x', NONE) :: stms
521 :     | NONE => raise Fail(concat["mkDecl(", V.name x, ", _)"])
522 :     (* end case *))
523 :     val stms = List.foldr mkDecl stms locals
524 :     in
525 :     CL.mkBlock stms
526 :     end
527 :    
528 : jhr 1640 fun trStms (env, stms) = let
529 :     fun trStmt (env, stm) = (case stm
530 :     of IL.S_Comment text => [CL.mkComment text]
531 :     | IL.S_Assign([x], exp) => trAssign (env, VarToC.lvalueVar (env, x), exp)
532 :     | IL.S_Assign(xs, exp) =>
533 :     trMultiAssign (env, List.map (fn x => VarToC.lvalueVar (env, x)) xs, exp)
534 :     | IL.S_IfThen(cond, thenBlk) =>
535 :     [CL.mkIfThen(trExp(env, cond), trBlk(env, thenBlk))]
536 :     | IL.S_IfThenElse(cond, thenBlk, elseBlk) =>
537 :     [CL.mkIfThenElse(trExp(env, cond),
538 :     trBlk(env, thenBlk),
539 :     trBlk(env, elseBlk))]
540 :     | IL.S_New _ => raise Fail "new not supported yet" (* FIXME *)
541 :     | IL.S_Save([x], exp) => trAssign (env, VarToC.lvalueStateVar x, exp)
542 :     | IL.S_Save(xs, exp) =>
543 :     trMultiAssign (env, List.map VarToC.lvalueStateVar xs, exp)
544 :     | IL.S_LoadImage(lhs, dim, name) => checkSts (fn sts => let
545 :     val lhs = VarToC.lvalueVar (env, lhs)
546 :     val name = trExp(env, name)
547 :     val imgTy = CL.T_Named(N.imageTy dim)
548 :     val loadFn = N.loadImage dim
549 :     in [
550 :     CL.mkDecl(
551 :     CL.T_Named N.statusTy, sts,
552 : jhr 1807 SOME(CL.I_Exp(CL.E_Apply(loadFn, [
553 :     CL.mkCast(CL.T_Ptr(CL.T_Named "WorldPrefix_t"), CL.mkVar "wrld"),
554 :     name, addrOf lhs
555 :     ]))))
556 : jhr 1640 ] end)
557 : jhr 1803 | IL.S_Input(_, _, _, NONE) => []
558 :     | IL.S_Input(lhs, name, _, SOME dflt) => [
559 :     CL.mkAssign(VarToC.lvalueVar(env, lhs), trExp(env, dflt))
560 :     ]
561 : jhr 1807 | IL.S_Exit args => []
562 : jhr 1640 | IL.S_Active => [CL.mkReturn(SOME(CL.mkVar N.kActive))]
563 :     | IL.S_Stabilize => [CL.mkReturn(SOME(CL.mkVar N.kStabilize))]
564 :     | IL.S_Die => [CL.mkReturn(SOME(CL.mkVar N.kDie))]
565 :     (* end case *))
566 :     in
567 :     List.foldr (fn (stm, stms) => trStmt(env, stm)@stms) [] stms
568 :     end
569 :    
570 :     and trBlk (env, IL.Block{locals, body}) = let
571 :     val env = trLocals (env, locals)
572 :     val stms = trStms (env, body)
573 :     fun mkDecl (x, stms) = (case V.Map.find (env, x)
574 :     of SOME(V(ty, x')) => CL.mkDecl(ty, x', NONE) :: stms
575 :     | NONE => raise Fail(concat["mkDecl(", V.name x, ", _)"])
576 :     (* end case *))
577 :     val stms = List.foldr mkDecl stms locals
578 :     in
579 :     CL.mkBlock stms
580 :     end
581 :    
582 :     fun trFragment (env, IL.Block{locals, body}) = let
583 :     val env = trLocals (env, locals)
584 :     val stms = trStms (env, body)
585 :     fun mkDecl (x, stms) = (case V.Map.find (env, x)
586 :     of SOME(V(ty, x')) => CL.mkDecl(ty, x', NONE) :: stms
587 :     | NONE => raise Fail(concat["mkDecl(", V.name x, ", _)"])
588 :     (* end case *))
589 :     val stms = List.foldr mkDecl stms locals
590 :     in
591 :     (env, stms)
592 :     end
593 :    
594 :     val trBlock = trBlk
595 :    
596 :     end

root@smlnj-gforge.cs.uchicago.edu
ViewVC Help
Powered by ViewVC 1.0.0