Home My Page Projects Code Snippets Project Openings diderot
Summary Activity Tracker Tasks SCM

SCM Repository

[diderot] Annotation of /branches/vis12/src/compiler/codegen/clang.sml
ViewVC logotype

Annotation of /branches/vis12/src/compiler/codegen/clang.sml

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1115 - (view) (download)
Original Path: trunk/src/compiler/codegen/clang.sml

1 : jhr 1115 (* clang.sml
2 :     *
3 :     * COPYRIGHT (c) 2011 The Diderot Project (http://diderot-language.cs.uchicago.edu)
4 :     * All rights reserved.
5 :     *
6 :     * An tree representation of programs in a C-like language (e.g., C, CUDA,
7 :     * or OpenCL). The purpose of this code is to commonality between the various
8 :     * backends, which are all generating C-like code.
9 :     *)
10 :    
11 :     structure CLang =
12 :     struct
13 :    
14 :     type var = string
15 :     type attr = string (* e.g., "static", "kernel", etc ... *)
16 :    
17 :     datatype ty
18 :     = T_Num of RawTypes.ty
19 :     | T_Ptr of ty
20 :     | T_Array of ty * int option
21 :     | T_Named of string
22 :    
23 :     val voidTy = T_Named "void"
24 :     val charPtr = T_Ptr(T_Named "char")
25 :     val int32 = T_Num(RawTypes.RT_Int32)
26 :     val uint32 = T_Num(RawTypes.RT_UInt32)
27 :     val int64 = T_Num(RawTypes.RT_Int64)
28 :     val float = T_Num(RawTypes.RT_Float)
29 :     val double = T_Num(RawTypes.RT_Double)
30 :    
31 :     datatype decl
32 :     = D_Comment of string list
33 :     (* verbatim text (e.g., preprocessor directives) *)
34 :     | D_Verbatim of string list
35 :     (* global variable declaration *)
36 :     | D_Var of attr list * ty * var * initializer option
37 :     (* function definition *)
38 :     | D_Func of attr list * ty * string * param list * stm
39 :     (* typedef of struct type *)
40 :     | D_StructDef of (ty * string) list * string
41 :    
42 :     and initializer
43 :     = I_Exp of exp
44 :     | I_Struct of (string * initializer) list
45 :     | I_Array of (int * initializer) list
46 :    
47 :     and param = PARAM of attr list * ty * var
48 :    
49 :     and stm
50 :     = S_Block of stm list (* "{" stms "}" *)
51 :     | S_Comment of string list
52 :     | S_Decl of ty * var * initializer option (* ty var [ '=' exp ]';' *)
53 :     | S_Exp of exp (* exp ';' *)
54 :     | S_If of exp * stm * stm (* 'if' exp stm 'else' stm *)
55 :     | S_While of exp * stm (* 'while' exp stm *)
56 :     | S_For of (ty * var * exp) list * exp * exp list * stm
57 :     (* 'for' '(' inits ';' exp ';' incrs ')' stm *)
58 :     | S_Call of string * exp list (* func '(' args ')' *)
59 :     | S_Return of exp option (* 'return' [ exp ] ';' *)
60 :     | S_Break (* 'break' ';' *)
61 :     | S_Continue (* 'continue' ';' *)
62 :    
63 :     and exp
64 :     = E_Grp of exp (* "(" e ")" *)
65 :     | E_AssignOp of exp * assignop * exp (* lvalue op= e *)
66 :     | E_BinOp of exp * binop * exp (* e op e *)
67 :     | E_UnOp of unop * exp (* op e *)
68 :     | E_PostOp of exp * postfix (* e op *)
69 :     | E_Apply of string * exp list (* f "(" ... ")" *)
70 :     | E_Subscript of exp * exp (* e "[" e "]" *)
71 :     | E_Select of exp * string (* e "." f *)
72 :     | E_Indirect of exp * string (* e "->" f *)
73 :     | E_Cast of ty * exp (* "(" ty ")" e *)
74 :     | E_Var of var
75 :     | E_Int of IntegerLit.integer * ty
76 :     | E_Flt of FloatLit.float * ty
77 :     | E_Bool of bool
78 :     | E_Str of string
79 :     | E_Sizeof of ty (* "sizeof(" ty ")" *)
80 :    
81 :     (* assignment operators *)
82 :     and assignop
83 :     = $= | += | *= | /= | %= | <<= | >>= | &= | ^= | |=
84 :    
85 :     (* binary operators in increasing order of precedence *)
86 :     and binop
87 :     = #||
88 :     | #&&
89 :     | #== | #!=
90 :     | #< | #<= | #>= | #>
91 :     | #<< | #>>
92 :     | #+ | #-
93 :     | #* | #/ | #%
94 :    
95 :     and unop = %- | %! | %& | %* | %~ | %++ | %--
96 :    
97 :     and postfix = ^++ | ^--
98 :    
99 :     (* smart constructors that add E_Grp wrappers based on operator precedence *)
100 :     local
101 :     val commaP = 0
102 :     val assignP = 1
103 :     val condP = 2
104 :     val lorP = 3
105 :     val landP = 4
106 :     val borP = 5
107 :     val bandP = 6
108 :     val eqP = 7
109 :     val relP = 8
110 :     val shiftP = 9
111 :     val addP = 10
112 :     val mulP = 11
113 :     val unaryP = 12
114 :     val preP = 13
115 :     val compundP = 14 (* compound literal *)
116 :     val postP = 15
117 :     val callP = 16
118 :     val subP = 17
119 :     val atomP = 18
120 :     fun precOfBinop rator = (case rator
121 :     of #|| => lorP
122 :     | #&& => landP
123 :     | #== => eqP | #!= => eqP
124 :     | #< => relP | #<= => relP | #>= => relP | #> => relP
125 :     | #<< => shiftP | #>> => shiftP
126 :     | #+ => addP | #- => addP
127 :     | #* => mulP | #/ => mulP | #% => mulP
128 :     (* end case *))
129 :     fun prec (E_Grp _) = atomP
130 :     | prec (E_AssignOp _) = assignP
131 :     | prec (E_BinOp(_, rator, _)) = precOfBinop rator
132 :     | prec (E_UnOp _) = preP
133 :     | prec (E_PostOp _) = postP
134 :     | prec (E_Apply _) = callP
135 :     | prec (E_Subscript _) = postP
136 :     | prec (E_Select _) = postP
137 :     | prec (E_Indirect _) = postP
138 :     | prec (E_Cast _) = unaryP
139 :     | prec (E_Var _) = atomP
140 :     | prec (E_Int _) = atomP
141 :     | prec (E_Flt _) = atomP
142 :     | prec (E_Bool _) = atomP
143 :     | prec (E_Str _) = atomP
144 :     | prec (E_Sizeof _) = callP
145 :     in
146 :     fun mkGrp e = if (prec e < atomP) then E_Grp e else e
147 :     fun mkAssignOp (e1, rator, e2) = let
148 :     val e1' = if prec e1 < unaryP then E_Grp e1 else e1
149 :     val e2' = if prec e2 < assignP then E_Grp e2 else e2
150 :     in
151 :     E_AssignOp(e1', rator, e2')
152 :     end
153 :     (* Note that all C binary operators are left associative. *)
154 :     fun mkBinOp (e1, #-, e2 as E_UnOp(%-, _)) = let
155 :     val e1' = if prec e1 < addP then E_Grp e1 else e1
156 :     val e2' = E_Grp e2
157 :     in
158 :     E_BinOp(e1', #-, e2')
159 :     end
160 :     | mkBinOp (e1, rator, e2) = let
161 :     val p = precOfBinop rator
162 :     val e1' = if prec e1 < p then E_Grp e1 else e1
163 :     val e2' = if prec e2 <= p then E_Grp e2 else e2
164 :     in
165 :     E_BinOp(e1', rator, e2')
166 :     end
167 :     fun mkUnOp (%-, e as E_UnOp(%-, _)) = E_UnOp(%-, E_Grp e)
168 :     | mkUnOp (%-, e as E_UnOp(%--, _)) = E_UnOp(%-, E_Grp e)
169 :     | mkUnOp (%--, e as E_UnOp(%-, _)) = E_UnOp(%--, E_Grp e)
170 :     | mkUnOp (%--, e as E_UnOp(%--, _)) = E_UnOp(%--, E_Grp e)
171 :     | mkUnOp (rator, e) = if prec e < unaryP
172 :     then E_UnOp(rator, E_Grp e)
173 :     else E_UnOp(rator, e)
174 :     fun mkPostOp (e, rator) = if prec e < postP
175 :     then E_PostOp(E_Grp e, rator)
176 :     else E_PostOp(e, rator)
177 :     fun mkApply (f, args) = E_Apply(f, args)
178 :     fun mkSubscript(e1, e2) = if prec e1 < postP
179 :     then E_Subscript(E_Grp e1, e2)
180 :     else E_Subscript(e1, e2)
181 :     fun mkSelect (e, f) = if prec e < postP
182 :     then E_Select(E_Grp e, f)
183 :     else E_Select(e, f)
184 :     fun mkIndirect (e, f) = if prec e < postP
185 :     then E_Indirect(E_Grp e, f)
186 :     else E_Indirect(e, f)
187 :     fun mkCast (ty, e) = E_Cast(ty, e)
188 :     val mkVar = E_Var
189 :     fun mkInt (n, ty) = if n < 0 then E_UnOp(%-, E_Int(~n, ty)) else E_Int(n, ty)
190 :     fun mkFlt (f, ty) = if FloatLit.isNeg f
191 :     then E_UnOp(%-, E_Flt(FloatLit.negate f, ty))
192 :     else E_Flt(f, ty)
193 :     val mkBool = E_Bool
194 :     val mkStr = E_Str
195 :     val mkSizeof = E_Sizeof
196 :     end (* local *)
197 :    
198 :     val skip = S_Block[]
199 :    
200 :     local
201 :     fun paren (e as E_Grp _) = e
202 :     | paren e = E_Grp e
203 :     in
204 :     val mkComment = S_Comment
205 :     fun mkBlock [stm] = stm
206 :     | mkBlock stms = S_Block stms
207 :     val mkDecl = S_Decl
208 :     val mkExpStm = S_Exp
209 :     fun mkAssign (e1, e2) = S_Exp(mkAssignOp(e1, $=, e2))
210 :     fun mkIfThenElse (e, b1, b2) = S_If(paren e, b1, b2)
211 :     fun mkIfThen (e, b) = mkIfThenElse (e, b, skip)
212 :     val mkFor = S_For
213 :     fun mkWhile (e, b) = S_While(paren e, b)
214 :     val mkCall = S_Call
215 :     val mkReturn = S_Return
216 :     val mkBreak = S_Break
217 :     val mkContinue = S_Continue
218 :     end (* local *)
219 :    
220 :     (* utility functions *)
221 :    
222 :     fun varToString x = x
223 :    
224 :     fun assignopToString rator = (case rator
225 :     of $= => "="
226 :     | += => "+="
227 :     | *= => "*="
228 :     | /= => "/="
229 :     | %= => "%="
230 :     | <<= => "<<="
231 :     | >>= => ">>="
232 :     | &= => "&="
233 :     | ^= => "^="
234 :     | |= => "|="
235 :     (* end case *))
236 :    
237 :     fun binopToString rator = (case rator
238 :     of #|| => "||"
239 :     | #&& => "&&"
240 :     | #== => "=="
241 :     | #!= => "!="
242 :     | #< => "<"
243 :     | #<= => "<="
244 :     | #>= => ">="
245 :     | #> => ">"
246 :     | #<< => "<<"
247 :     | #>> => ">>"
248 :     | #+ => "+"
249 :     | #- => "-"
250 :     | #* => "*"
251 :     | #/ => "/"
252 :     | #% => "%"
253 :     (* end case *))
254 :    
255 :     fun unopToString rator = (case rator
256 :     of %- => "-"
257 :     | %! => "!"
258 :     | %& => "&"
259 :     | %* => "*"
260 :     | %~ => "~"
261 :     | %++ => "++"
262 :     | %-- => "--"
263 :     (* end case *))
264 :    
265 :     fun postopToString rator = (case rator
266 :     of ^++ => "++"
267 :     | ^-- => "--"
268 :     (* end case *))
269 :    
270 :     fun expToString e = let
271 :     fun e2s (e, l) = (case e
272 :     of E_Grp e => "(" :: e2s(e, ")"::l)
273 :     | E_AssignOp(e1, rator, e2) => e2s(e1, assignopToString rator :: e2s(e2, l))
274 :     | E_BinOp(e1, rator, e2) => e2s(e1, binopToString rator :: e2s(e2, l))
275 :     | E_UnOp(rator, e) => unopToString rator :: e2s(e, l)
276 :     | E_PostOp(e, rator) => e2s(e, postopToString rator :: l)
277 :     | E_Apply(f, es) => let
278 :     fun args2s ([], l) = l
279 :     | args2s ([e], l) = e2s(e, l)
280 :     | args2s (e::es, l) = e2s(e, ","::args2s(es, l))
281 :     in
282 :     f :: "(" :: args2s(es, ")"::l)
283 :     end
284 :     | E_Subscript(e1, e2) => e2s(e1, "[" :: e2s(e2, "]"::l))
285 :     | E_Select(e, f) => e2s(e, "." :: f :: l)
286 :     | E_Indirect(e, f) => e2s(e, "->" :: f :: l)
287 :     | E_Cast(ty, e) => "(ty)" :: e2s(e, l) (* FIXME *)
288 :     | E_Var x => x::l
289 :     | E_Int(n, _) => IntegerLit.toString n :: l
290 :     | E_Flt(f, _) => FloatLit.toString f :: l
291 :     | E_Bool b => Bool.toString b :: l
292 :     | E_Str s => concat["\"", String.toCString s, "\""] :: l
293 :     | E_Sizeof ty => "sizeof(ty)" :: l
294 :     (* end case *))
295 :     in
296 :     String.concat(e2s(e, []))
297 :     end
298 :    
299 :     end

root@smlnj-gforge.cs.uchicago.edu
ViewVC Help
Powered by ViewVC 1.0.0