Home My Page Projects Code Snippets Project Openings diderot
Summary Activity Tracker Tasks SCM

SCM Repository

[diderot] View of /branches/vis12/test/mandel.diderot
ViewVC logotype

View of /branches/vis12/test/mandel.diderot

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1948 - (download) (annotate)
Sat Jul 7 04:34:11 2012 UTC (7 years, 5 months ago) by glk
File size: 1388 byte(s)
aesthetic tweaks, now using log
/*! \file mandel.diderot
 *
 * \author Gordon Kindlmann
 */

/*
 * COPYRIGHT (c) 2012 The Diderot Project (http://diderot-language.cs.uchicago.edu)
 * All rights reserved.
 */

// ../bin/diderotc --exec mandel.diderot && ./mandel && unu quantize -b 8 -i rgb.nrrd -o mandel.png 

// Global definitions
input int reso = 2000;
input real escape = 4.0;
input int maxiter = 2000;
input vec2 center = [-1.2, -0.3]; // [0.0,0.0] for whole thing
input real fov = 0.16; // 2.0 for whole thing

// Strand definition
strand mandel(vec2 c) {
   vec2 z = [0.0, 0.0];
   int iter = 0;
   output vec3 rgb = [0.0, 0.0, 0.0];
   update  {
      z = [z[0]^2 - z[1]^2, 2.0*z[0]*z[1]] + c; // z = z^2 + c
      iter += 1;
      if (|z| > escape) {
         // point has escaped; set continuous color from iter and radius
         real t = 4.0*log(real(iter) - log(log(|z|)/log(escape))/log(2.0));
         rgb = [sin(-t), cos(t), sin(t)];
         rgb = ([1.8, 1.8, 1.8] + rgb)/2.8;
         stabilize;
      }
      if (iter > maxiter) {
         rgb = [0.0, 0.0, 0.0];
         stabilize;
      }
   }
}

// Strand initialization
initially [ mandel([lerp(center[0]-fov, center[0]+fov, 
                         1.0, real(crIdx), real(reso)),
                    lerp(center[1]-fov, center[1]+fov,
                         1.0, real(ciIdx), real(reso))])
            | ciIdx in 1..reso, crIdx in 1..reso ];

root@smlnj-gforge.cs.uchicago.edu
ViewVC Help
Powered by ViewVC 1.0.0