Home My Page Projects Code Snippets Project Openings diderot
Summary Activity Tracker Tasks SCM

SCM Repository

[diderot] View of /branches/vis12/test/mandel.diderot
ViewVC logotype

View of /branches/vis12/test/mandel.diderot

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1897 - (download) (annotate)
Fri Jun 1 21:11:10 2012 UTC (7 years, 4 months ago) by glk
File size: 1023 byte(s)
move ridge3d.diderot ridge3d/ridge3d.diderot
// ../bin/diderotc --exec mandel.diderot && ./mandel && unu quantize -b 8 -i rgb.nrrd -o mandel.png 

// Global definitions
input int reso = 800;
input int maxiter = 1000;

// Strand definition
strand mandel(vec2 c) {
   vec2 z = [0.0, 0.0];
   int iter = 0;
   output vec3 rgb = [0.0, 0.0, 0.0];
   update  {
      z = [z[0]^2 - z[1]^2, 2.0*z[0]*z[1]] + c; // z = z^2 + c
      iter += 1;
      if (z•z > 4.0) {
         // point has escaped; set color based on iteration
         real t = 11.0*real(iter)^0.2;
         rgb = [sin(t), sin(t + 2.0*π/3.0), sin(t - 2.0*π/3.0)];
         rgb = ([1.7, 1.7, 1.7] + rgb)/2.7;
         stabilize;
      }
      if (iter > maxiter) {
         // no escape yet, seems to be in set, so color black
         rgb = [0.0, 0.0, 0.0];
         stabilize;
      }
   }
}

// Strand initialization
initially [ mandel([lerp(-2.0, 2.0, 1.0, real(crIdx), real(reso)),
                    lerp(-2.0, 2.0, 1.0, real(ciIdx), real(reso))])
            | ciIdx in 1..reso, crIdx in 1..reso ];

root@smlnj-gforge.cs.uchicago.edu
ViewVC Help
Powered by ViewVC 1.0.0