Home My Page Projects Code Snippets Project Openings diderot
Summary Activity Tracker Tasks SCM

SCM Repository

[diderot] Annotation of /branches/vis15/src/compiler/cxx-util/tree-to-cxx.sml
ViewVC logotype

Annotation of /branches/vis15/src/compiler/cxx-util/tree-to-cxx.sml

Parent Directory Parent Directory | Revision Log Revision Log


Revision 3896 - (view) (download)

1 : jhr 3866 (* tree-to-cxx.sml
2 : jhr 3768 *
3 :     * This code is part of the Diderot Project (http://diderot-language.cs.uchicago.edu)
4 :     *
5 :     * COPYRIGHT (c) 2016 The University of Chicago
6 :     * All rights reserved.
7 :     *
8 : jhr 3866 * Translate TreeIR to the C++ version of CLang.
9 : jhr 3768 *)
10 :    
11 :    
12 : jhr 3866 structure TreeToCxx : sig
13 : jhr 3768
14 : jhr 3886 val trType : CodeGenEnv.t * TreeTypes.t -> CLang.ty
15 : jhr 3768
16 : jhr 3896 val trAPIType : CodeGenEnv.t * APITypes.t -> CLang.ty
17 :    
18 : jhr 3873 val trBlock : CodeGenEnv.t * TreeIR.block -> CLang.stm
19 : jhr 3768
20 : jhr 3873 val trExp : CodeGenEnv.t * TreeIR.exp -> CLang.exp
21 : jhr 3768
22 : jhr 3866 (* translate an expression to a variable form; return the variable (as an expression)
23 : jhr 3768 * and the (optional) declaration.
24 :     *)
25 : jhr 3876 val trExpToVar : CodeGenEnv.t * CLang.ty * string * TreeIR.exp -> CLang.exp * CLang.stm list
26 : jhr 3768
27 : jhr 3873 val trAssign : CodeGenEnv.t * CLang.exp * TreeIR.exp -> CLang.stm list
28 : jhr 3768
29 :     end = struct
30 :    
31 :     structure CL = CLang
32 :     structure IR = TreeIR
33 :     structure Op = TreeOps
34 :     structure Ty = TreeTypes
35 : jhr 3866 structure V = TreeVar
36 : jhr 3873 structure Env = CodeGenEnv
37 : jhr 3768
38 : jhr 3886 fun trType (env, ty) = (case ty
39 :     of Ty.BoolTy => CL.boolTy
40 :     | Ty.StringTy => CL.T_Named "std::string"
41 :     | Ty.IntTy => Env.intTy env
42 :     | (Ty.VecTy(1, 1)) => Env.realTy env
43 :     | (Ty.VecTy(d, _)) => CL.T_Named("vec" ^ Int.toString d)
44 : jhr 3894 | (Ty.TupleTy tys) => raise Fail "FIXME: TupleTy"
45 : jhr 3886 | (Ty.TensorTy dd) => CL.T_Array(Env.realTy env, SOME(List.foldl Int.* 1 dd))
46 :     | (Ty.SeqTy(t, NONE)) => CL.T_Template("diderot::dynseq", [trType(env, t)])
47 :     | (Ty.SeqTy(t, SOME n)) => CL.T_Array(trType(env, t), SOME n)
48 :     | (Ty.ImageTy info) =>
49 :     CL.T_Template(
50 :     concat["diderot::image", Int.toString(ImageInfo.dim info), "d"],
51 :     [Env.realTy env])
52 :     | (Ty.StrandTy name) => CL.T_Named("strand_" ^ Atom.toString name)
53 :     (* end case *))
54 : jhr 3768
55 : jhr 3896 fun trAPIType (env, ty) = (case ty
56 :     of APITypes.IntTy => Env.intTy env
57 :     | APITypes.BoolTy => Env.boolTy env
58 :     | APITypes.TensorTy[] => Env.realTy env
59 :     | APITypes.TensorTy dd => CL.T_Array(Env.realTy env, SOME(List.foldl Int.* 1 dd))
60 :     | APITypes.StringTy => CL.charPtr (* const?? *)
61 :     | APITypes.ImageTy(dim, _) => CL.T_Ptr(CL.T_Named "nrrd")
62 :     | APITypes.SeqTy(ty, NONE) => CL.T_Ptr(CL.T_Named "nrrd")
63 :     | APITypes.SeqTy(ty, SOME n) => CL.T_Array(trAPIType(env, ty), SOME n)
64 :     (* end case *))
65 :    
66 : jhr 3866 (* translate a local variable that occurs in an l-value context *)
67 : jhr 3873 fun lvalueVar (env, x) = CL.mkVar(Env.lookup(env, x))
68 : jhr 3866 (* translate a variable that occurs in an r-value context *)
69 : jhr 3873 fun rvalueVar (env, x) = CL.mkVar(Env.lookup(env, x))
70 : jhr 3768
71 : jhr 3866 (* translate a global variable that occurs in an l-value context *)
72 : jhr 3876 fun lvalueGlobalVar (env, x) = CL.mkIndirect(CL.mkVar(Env.global env), TreeGlobalVar.name x)
73 : jhr 3866 (* translate a global variable that occurs in an r-value context *)
74 :     val rvalueGlobalVar = lvalueGlobalVar
75 :    
76 :     (* translate a strand state variable that occurs in an l-value context *)
77 : jhr 3876 fun lvalueStateVar (env, x) = CL.mkIndirect(CL.mkVar(Env.selfOut env), TreeStateVar.name x)
78 : jhr 3866 (* translate a strand state variable that occurs in an r-value context *)
79 : jhr 3876 fun rvalueStateVar (env, x) = CL.mkIndirect(CL.mkVar(Env.selfIn env), TreeStateVar.name x)
80 : jhr 3866
81 :     (* generate new variables *)
82 :     local
83 :     val count = ref 0
84 :     fun freshName prefix = let
85 :     val n = !count
86 :     in
87 :     count := n+1;
88 :     concat[prefix, "_", Int.toString n]
89 :     end
90 :     in
91 :     fun tmpVar () = freshName "tmp"
92 :     fun freshVar prefix = freshName prefix
93 :     end (* local *)
94 :    
95 :     (* integer literal expression *)
96 :     fun intExp (i : int) = CL.mkInt(IntInf.fromInt i)
97 :    
98 : jhr 3893 val zero = CL.mkInt 0
99 :    
100 : jhr 3866 fun addrOf e = CL.mkUnOp(CL.%&, e)
101 :    
102 :     (* make an application of a function from the "std" namespace *)
103 :     fun mkStdApply (f, args) = CL.mkApply("std::" ^ f, args)
104 :    
105 :     (* make an application of a function from the "diderot" namespace *)
106 :     fun mkDiderotApply (f, args) = CL.mkApply("diderot::" ^ f, args)
107 : jhr 3872 fun mkDiderotCall (f, args) = CL.mkCall("diderot::" ^ f, args)
108 : jhr 3866
109 : jhr 3810 (* Translate a TreeIR operator application to a CLang expression *)
110 : jhr 3886 fun trOp (env, rator, args) = (case (rator, args)
111 : jhr 3870 of (Op.IAdd, [a, b]) => CL.mkBinOp(a, CL.#+, b)
112 : jhr 3768 | (Op.ISub, [a, b]) => CL.mkBinOp(a, CL.#-, b)
113 :     | (Op.IMul, [a, b]) => CL.mkBinOp(a, CL.#*, b)
114 :     | (Op.IDiv, [a, b]) => CL.mkBinOp(a, CL.#/, b)
115 :     | (Op.IMod, [a, b]) => CL.mkBinOp(a, CL.#%, b)
116 :     | (Op.INeg, [a]) => CL.mkUnOp(CL.%-, a)
117 :     | (Op.RAdd, [a, b]) => CL.mkBinOp(a, CL.#+, b)
118 :     | (Op.RSub, [a, b]) => CL.mkBinOp(a, CL.#-, b)
119 :     | (Op.RMul, [a, b]) => CL.mkBinOp(a, CL.#*, b)
120 :     | (Op.RDiv, [a, b]) => CL.mkBinOp(a, CL.#/, b)
121 :     | (Op.RNeg, [a]) => CL.mkUnOp(CL.%-, a)
122 : jhr 3870 | (Op.RClamp, [a, b, c]) => CL.mkApply("clamp", [a, b, c])
123 :     | (Op.RLerp, [a, b, c]) => CL.mkApply("lerp", [a, b, c])
124 : jhr 3886 | (Op.RCeiling, [a]) => mkStdApply("ceil", [a])
125 :     | (Op.RFloor, [a]) => mkStdApply("floor", [a])
126 :     | (Op.RRound, [a]) => mkStdApply("round", [a])
127 :     | (Op.RTrunc, [a]) => mkStdApply("trunc", [a])
128 :     | (Op.RealToInt, [a]) => mkStdApply("lround", [a])
129 : jhr 3768 | (Op.LT ty, [a, b]) => CL.mkBinOp(a, CL.#<, b)
130 :     | (Op.LTE ty, [a, b]) => CL.mkBinOp(a, CL.#<=, b)
131 :     | (Op.EQ ty, [a, b]) => CL.mkBinOp(a, CL.#==, b)
132 :     | (Op.NEQ ty, [a, b]) => CL.mkBinOp(a, CL.#!=, b)
133 :     | (Op.GTE ty, [a, b]) => CL.mkBinOp(a, CL.#>=, b)
134 :     | (Op.GT ty, [a, b]) => CL.mkBinOp(a, CL.#>, b)
135 :     | (Op.Not, [a]) => CL.mkUnOp(CL.%!, a)
136 : jhr 3866 | (Op.Abs ty, args) => mkStdApply("abs", args)
137 :     | (Op.Max ty, args) => mkStdApply("min", args)
138 :     | (Op.Min ty, args) => mkStdApply("max", args)
139 :     | (Op.VAdd d, [a, b]) => CL.mkBinOp(a, CL.#+, b)
140 :     | (Op.VSub d, [a, b]) => CL.mkBinOp(a, CL.#-, b)
141 : jhr 3870 | (Op.VScale d, [a, b]) => CL.mkApply("vscale", [a, b])
142 : jhr 3866 | (Op.VMul d, [a, b]) => CL.mkBinOp(a, CL.#*, b)
143 :     | (Op.VNeg d, [a]) => CL.mkUnOp(CL.%-, a)
144 : jhr 3872 | (Op.VSum d, [a]) => CL.mkApply("vsum", [a])
145 : jhr 3886 | (Op.VIndex(w, p, i), [a]) => CL.mkSubscript(a, intExp i)
146 :     | (Op.VClamp d, [a, b, c]) => CL.mkApply("vclamp", [a, b, c])
147 :     | (Op.VMapClamp d, [a, b, c]) => CL.mkApply("vclamp", [a, b, c])
148 :     | (Op.VLerp d, [a, b, c]) => CL.mkApply("vlerp", [a, b, c])
149 :     | (Op.VCeiling d, [a]) => CL.mkApply("vceiling", [a])
150 :     | (Op.VFloor d, [a]) => CL.mkApply("vfloor", [a])
151 :     | (Op.VRound d, [a]) => CL.mkApply("vround", [a])
152 :     | (Op.VTrunc d, [a]) => CL.mkApply("vtrunc", [a])
153 :     | (Op.VToInt d, [a]) => CL.mkApply("vtoi", [a])
154 :     | (Op.TensorIndex(Ty.TensorTy(_::dd), idxs), [a]) => let
155 :     (* dimensions/indices are slowest to fastest *)
156 :     fun index ([], [i], acc) = acc + i
157 :     | index (d::dd, i::ii, acc) = index (dd, ii, d * (acc + i))
158 :     in
159 :     CL.mkSubscript(a, intExp(index (dd, idxs, 0)))
160 :     end
161 :     | (Op.ProjectLast(Ty.TensorTy(_::dd), idxs), [a]) => let
162 :     (* dimensions/indices are slowest to fastest *)
163 :     fun index ([], [], acc) = acc
164 :     | index (d::dd, i::ii, acc) = index (dd, ii, d * (acc + i))
165 :     in
166 :     CL.mkAddrOf(CL.mkSubscript(a, intExp(index (dd, idxs, 0))))
167 :     end
168 :     | (Op.EigenVals2x2, [a]) => raise Fail "FIXME: EigenVals2x2"
169 :     | (Op.EigenVals3x3, [a]) => raise Fail "FIXME: EigenVals3x3"
170 :     | (Op.Select(ty, i), [a]) => raise Fail "FIXME: Select"
171 :     | (Op.Subscript ty, [a, b]) => CL.mkSubscript(a, b)
172 :     | (Op.MkDynamic(ty, i), [a]) => raise Fail "FIXME: MkDynamic"
173 :     | (Op.Append ty, [a, b]) => raise Fail "FIXME: Append"
174 :     | (Op.Prepend ty, [a, b]) => raise Fail "FIXME: Prepend"
175 :     | (Op.Concat ty, [a, b]) => raise Fail "FIXME: Concat"
176 :     | (Op.Range, [a, b]) => raise Fail "FIXME: Range"
177 :     | (Op.Length ty, [a]) => raise Fail "FIXME: Length"
178 :     | (Op.SphereQuery(ty1, ty2), []) => raise Fail "FIXME: SphereQuery"
179 : jhr 3870 | (Op.Sqrt, [a]) => mkStdApply("sqrt", [a])
180 :     | (Op.Cos, [a]) => mkStdApply("cos", [a])
181 :     | (Op.ArcCos, [a]) => mkStdApply("acos", [a])
182 :     | (Op.Sin, [a]) => mkStdApply("sin", [a])
183 :     | (Op.ArcSin, [a]) => mkStdApply("asin", [a])
184 :     | (Op.Tan, [a]) => mkStdApply("tan", [a])
185 :     | (Op.ArcTan, [a]) => mkStdApply("atan", [a])
186 :     | (Op.Exp, [a]) => mkStdApply("exp", [a])
187 : jhr 3886 | (Op.IntToReal, [a]) => CL.mkStaticCast(Env.realTy env, a)
188 : jhr 3768 (*
189 :     | R_All of ty
190 :     | R_Exists of ty
191 :     | R_Max of ty
192 :     | R_Min of ty
193 :     | R_Sum of ty
194 :     | R_Product of ty
195 :     | R_Mean of ty
196 :     | R_Variance of ty
197 :     *)
198 : jhr 3886 | (Op.Transform info, [img]) => CL.mkDispatch(img, "world2image", [])
199 :     | (Op.Translate info, [img]) => CL.mkDispatch(img, "translate", [])
200 :     | (Op.BaseAddress info, [img]) => CL.mkDispatch(img, "base_addr", [])
201 :     | (Op.ControlIndex(info, ctl, d), [img, idx]) =>
202 :     CL.mkDispatch(img, IndexCtl.toString ctl, [intExp d, idx])
203 :     | (Op.Inside(info, s), [pos, img]) => CL.mkDispatch(img, "inside", [pos, intExp s])
204 :     | (Op.ImageDim(info, i), [img]) => CL.mkDispatch(img, "size", [intExp i])
205 : jhr 3870 | (Op.MathFn f, args) => mkStdApply(MathFns.toString f, args)
206 : jhr 3866 | _ => raise Fail(concat[
207 :     "unknown or incorrect operator ", Op.toString rator
208 :     ])
209 : jhr 3768 (* end case *))
210 :    
211 : jhr 3866 fun trExp (env, e) = (case e
212 :     of IR.E_Global x => rvalueGlobalVar (env, x)
213 : jhr 3872 | IR.E_State(NONE, x) => rvalueStateVar (env, x)
214 :     | IR.E_State(SOME e, x) => CL.mkIndirect(trExp(env, e), TreeStateVar.name x)
215 : jhr 3866 | IR.E_Var x => rvalueVar (env, x)
216 : jhr 3876 | IR.E_Lit(Literal.Int n) => CL.mkIntTy(n, Env.intTy env)
217 : jhr 3866 | IR.E_Lit(Literal.Bool b) => CL.mkBool b
218 : jhr 3876 | IR.E_Lit(Literal.Real f) => CL.mkFlt(f, Env.realTy env)
219 : jhr 3866 | IR.E_Lit(Literal.String s) => CL.mkStr s
220 : jhr 3886 | IR.E_Op(rator, args) => trOp (env, rator, trExps(env, args))
221 : jhr 3893 | IR.E_Vec(w, pw, args) => let
222 :     val args = trExps (env, args)
223 :     val args = if (w < pw) then args @ List.tabulate(pw-w, fn _ => zero) else args
224 :     in
225 :     CL.mkVec(CL.T_Named("vec" ^ Int.toString pw), args)
226 :     end
227 :     | IR.E_Cons(args, Ty.TensorTy shape) => raise Fail "unexpected E_Cons"
228 :     | IR.E_Seq(args, ty) => raise Fail "unexpected E_Seq"
229 : jhr 3894 | IR.E_Pack(layout, args) => raise Fail "unexpected E_Pack"
230 :     (* FIXME: check if e is aligned and use "vload_aligned" in that case *)
231 :     | IR.E_VLoad(layout, e, i) =>
232 :     CL.mkTemplateApply("vload",
233 :     [trType(env, Ty.nthVec(layout, i))],
234 :     [CL.mkBinOp(trExp(env, e), CL.#+, intExp(Ty.offsetOf(layout, i)))])
235 :     | _ => raise Fail "trExp"
236 : jhr 3866 (* end case *))
237 :    
238 :     and trExps (env, exps) = List.map (fn exp => trExp(env, exp)) exps
239 :    
240 : jhr 3873 (* QUESTION: not sure that we need this function? *)
241 : jhr 3872 fun trExpToVar (env, ty, name, exp) = (case trExp (env, exp)
242 :     of e as CL.E_Var _ => (e, [])
243 :     | e => let
244 : jhr 3893 val x = freshVar name
245 : jhr 3872 in
246 : jhr 3876 (CL.mkVar x, [CL.mkDeclInit(ty, x, e)])
247 : jhr 3872 end
248 : jhr 3873 (* end case *))
249 : jhr 3872
250 : jhr 3893 fun trAssign (env, lhs, rhs) = let
251 :     fun trArg (i, arg) = CL.mkAssign(CL.mkSubscript(lhs, intExp i), trExp (env, arg))
252 :     in
253 :     case rhs
254 : jhr 3894 of IR.E_Pack(_, args) => [CL.mkCall ("vpack", List.map (fn e => trExp(env, e)) args)]
255 :     | IR.E_Cons(args, _) => List.mapi trArg args
256 : jhr 3893 | IR.E_Seq(args, _) => List.mapi trArg args
257 :     | _ => [CL.mkAssign(lhs, trExp (env, rhs))]
258 :     (* end case *)
259 :     end
260 : jhr 3872
261 : jhr 3893 fun trDecl (env, ty, lhs, rhs) = let
262 :     fun trArgs args = CL.mkDecl(
263 :     ty, lhs, SOME(CL.I_Exps(List.map (fn arg => CL.I_Exp(trExp (env, arg))) args)))
264 :     in
265 :     case rhs
266 :     of IR.E_Cons(args, _) => trArgs args
267 :     | IR.E_Seq(args, _) => trArgs args
268 :     | _ => CL.mkDeclInit(ty, lhs, trExp (env, rhs))
269 :     (* end case *)
270 :     end
271 : jhr 3872
272 : jhr 3870 fun trMultiAssign (env, lhs, IR.E_Op(rator, args)) = (case (lhs, rator, args)
273 : jhr 3876 of ([vals, vecs], Op.EigenVecs2x2, [exp]) =>
274 : jhr 3872 mkDiderotCall("eigenvecs", [trExp (env, exp), vals, vecs])
275 : jhr 3876 | ([vals, vecs], Op.EigenVecs3x3, [exp]) =>
276 : jhr 3872 mkDiderotCall("eigenvecs", [trExp (env, exp), vals, vecs])
277 : jhr 3870 | _ => raise Fail "bogus multi-assignment"
278 :     (* end case *))
279 :     | trMultiAssign (env, lhs, rhs) = raise Fail "bogus multi-assignment"
280 : jhr 3866
281 : jhr 3872 fun trStms (env, stms : TreeIR.stm list) = let
282 : jhr 3870 fun trStm (stm, (env, stms : CL.stm list)) = (case stm
283 :     of IR.S_Comment text => (env, CL.mkComment text :: stms)
284 : jhr 3872 | IR.S_Assign(true, x, exp) => let
285 : jhr 3893 val ty = trType (env, V.ty x)
286 : jhr 3894 val x' = V.name x
287 : jhr 3893 val env = Env.insert (env, x, x')
288 : jhr 3872 in
289 : jhr 3893 (env, trDecl (env, ty, x', exp) :: stms)
290 : jhr 3872 end
291 :     | IR.S_Assign(false, x, exp) => let
292 : jhr 3893 val stms' = trAssign (env, lvalueVar (env, x), exp)
293 : jhr 3866 in
294 : jhr 3893 (env, stms' @ stms)
295 : jhr 3866 end
296 :     | IR.S_MAssign(xs, exp) =>
297 : jhr 3886 (env, trMultiAssign (env, List.map (fn x => lvalueVar (env, x)) xs, exp) :: stms)
298 : jhr 3866 | IR.S_GAssign(x, exp) =>
299 : jhr 3893 (env, trAssign (env, lvalueGlobalVar (env, x), exp) @ stms)
300 : jhr 3866 | IR.S_IfThen(cond, thenBlk) =>
301 : jhr 3870 (env, CL.mkIfThen(trExp(env, cond), trBlock(env, thenBlk)) :: stms)
302 : jhr 3866 | IR.S_IfThenElse(cond, thenBlk, elseBlk) => let
303 :     val stm = CL.mkIfThenElse(trExp(env, cond),
304 : jhr 3870 trBlock(env, thenBlk),
305 :     trBlock(env, elseBlk))
306 : jhr 3866 in
307 :     (env, stm :: stms)
308 :     end
309 : jhr 3876 | IR.S_Foreach(x, IR.E_Op(Op.Range, [lo, hi]), blk) => let
310 :     val x' = V.name x
311 :     val env' = Env.insert (env, x, x')
312 : jhr 3894 val (hi', hiInit) = if CodeGenUtil.isSimple hi
313 :     then (trExp(env, hi), [])
314 :     else let
315 :     val hi' = freshVar "hi"
316 :     in
317 :     (CL.mkVar hi', [CL.mkDeclInit(CL.int32, hi', trExp(env, hi))])
318 :     end
319 : jhr 3876 val loop = CL.mkFor(
320 : jhr 3894 [(CL.int32, x', trExp(env, lo))],
321 : jhr 3876 CL.mkBinOp(CL.mkVar x', CL.#<=, hi'),
322 : jhr 3886 [CL.mkUnOp(CL.%++, CL.mkVar x')],
323 : jhr 3876 trBlock (env', blk))
324 :     in
325 : jhr 3894 (env, hiInit @ loop :: stms)
326 : jhr 3876 end
327 : jhr 3894 | IR.S_Foreach(x, e, blk) => raise Fail "Foreach"
328 :     | IR.S_New(strand, args) => raise Fail "New"
329 : jhr 3893 | IR.S_Save(x, exp) => (env, trAssign (env, lvalueStateVar(env, x), exp))
330 : jhr 3894 | IR.S_LoadNrrd(lhs, ty, nrrd) => let
331 :     val stm = (case ty
332 :     of APITypes.SeqTy(ty, NONE) =>
333 : jhr 3886 GenLoadNrrd.loadSeqFromFile (lvalueVar (env, lhs), ty, CL.mkStr nrrd)
334 : jhr 3894 | APITypes.ImageTy(dim, shape) =>
335 :     GenLoadNrrd.loadImage (lvalueVar (env, lhs), dim, CL.mkStr nrrd)
336 :     | _ => raise Fail(concat[
337 :     "bogus type ", APITypes.toString ty, " for LoadNrrd"
338 :     ])
339 : jhr 3886 (* end case *))
340 :     in
341 :     (env, stm :: stms)
342 :     end
343 : jhr 3870 | IR.S_Input(_, _, _, NONE) => (env, stms)
344 :     | IR.S_Input(gv, name, _, SOME dflt) =>
345 :     (env, CL.mkAssign(lvalueGlobalVar (env, gv), trExp(env, dflt)) :: stms)
346 : jhr 3866 | IR.S_InputNrrd _ => (env, stms)
347 : jhr 3870 | IR.S_Exit => (env, stms)
348 :     | IR.S_Print(tys, args) => let
349 :     val args = List.map (fn e => trExp(env, e)) args
350 :     val stm = GenPrint.genPrintStm (
351 :     CL.mkIndirect(CL.mkVar "wrld", "_output"),
352 :     tys, args)
353 :     in
354 :     (env, stm::stms)
355 :     end
356 : jhr 3876 | IR.S_Active => (env, CL.mkReturn(SOME(CL.mkVar "diderot::kActive")) :: stms)
357 :     | IR.S_Stabilize => (env, CL.mkReturn(SOME(CL.mkVar "diderot::kStabilize")) :: stms)
358 :     | IR.S_Die => (env, CL.mkReturn(SOME(CL.mkVar "diderot::kDie")) :: stms)
359 : jhr 3866 (* end case *))
360 :     in
361 :     List.rev (#2 (List.foldl trStm (env, []) stms))
362 :     end
363 :    
364 :     and trBlock (env, IR.Block{locals, body}) = let
365 : jhr 3873 fun trLocal (x, (env, dcls)) = let
366 :     val x' = V.name x
367 : jhr 3886 val dcl = CL.mkDecl(trType(env, V.ty x), x', NONE)
368 : jhr 3873 in
369 : jhr 3886 (Env.insert(env, x, x'), dcl :: dcls)
370 : jhr 3873 end
371 :     val (env, dcls) = List.foldl trLocal (env, []) (!locals)
372 : jhr 3866 in
373 : jhr 3873 CL.mkBlock (dcls @ trStms (env, body))
374 : jhr 3866 end
375 :    
376 : jhr 3768 end

root@smlnj-gforge.cs.uchicago.edu
ViewVC Help
Powered by ViewVC 1.0.0