Home My Page Projects Code Snippets Project Openings diderot
Summary Activity Tracker Tasks SCM

SCM Repository

[diderot] Annotation of /branches/vis15/src/compiler/cxx-util/tree-to-cxx.sml
ViewVC logotype

Annotation of /branches/vis15/src/compiler/cxx-util/tree-to-cxx.sml

Parent Directory Parent Directory | Revision Log Revision Log


Revision 3900 - (view) (download)

1 : jhr 3866 (* tree-to-cxx.sml
2 : jhr 3768 *
3 :     * This code is part of the Diderot Project (http://diderot-language.cs.uchicago.edu)
4 :     *
5 :     * COPYRIGHT (c) 2016 The University of Chicago
6 :     * All rights reserved.
7 :     *
8 : jhr 3866 * Translate TreeIR to the C++ version of CLang.
9 : jhr 3768 *)
10 :    
11 :    
12 : jhr 3866 structure TreeToCxx : sig
13 : jhr 3768
14 : jhr 3886 val trType : CodeGenEnv.t * TreeTypes.t -> CLang.ty
15 : jhr 3768
16 : jhr 3873 val trBlock : CodeGenEnv.t * TreeIR.block -> CLang.stm
17 : jhr 3768
18 : jhr 3873 val trExp : CodeGenEnv.t * TreeIR.exp -> CLang.exp
19 : jhr 3768
20 : jhr 3866 (* translate an expression to a variable form; return the variable (as an expression)
21 : jhr 3768 * and the (optional) declaration.
22 :     *)
23 : jhr 3876 val trExpToVar : CodeGenEnv.t * CLang.ty * string * TreeIR.exp -> CLang.exp * CLang.stm list
24 : jhr 3768
25 : jhr 3873 val trAssign : CodeGenEnv.t * CLang.exp * TreeIR.exp -> CLang.stm list
26 : jhr 3768
27 : jhr 3900 (* generate code to register an error message (require that a world pointer "wrld" is in scope) *)
28 :     val errorMsgAdd : CLang.exp -> CLang.stm
29 :    
30 : jhr 3768 end = struct
31 :    
32 :     structure CL = CLang
33 :     structure IR = TreeIR
34 :     structure Op = TreeOps
35 :     structure Ty = TreeTypes
36 : jhr 3866 structure V = TreeVar
37 : jhr 3873 structure Env = CodeGenEnv
38 : jhr 3768
39 : jhr 3886 fun trType (env, ty) = (case ty
40 :     of Ty.BoolTy => CL.boolTy
41 :     | Ty.StringTy => CL.T_Named "std::string"
42 :     | Ty.IntTy => Env.intTy env
43 :     | (Ty.VecTy(1, 1)) => Env.realTy env
44 :     | (Ty.VecTy(d, _)) => CL.T_Named("vec" ^ Int.toString d)
45 : jhr 3894 | (Ty.TupleTy tys) => raise Fail "FIXME: TupleTy"
46 : jhr 3886 | (Ty.TensorTy dd) => CL.T_Array(Env.realTy env, SOME(List.foldl Int.* 1 dd))
47 :     | (Ty.SeqTy(t, NONE)) => CL.T_Template("diderot::dynseq", [trType(env, t)])
48 :     | (Ty.SeqTy(t, SOME n)) => CL.T_Array(trType(env, t), SOME n)
49 :     | (Ty.ImageTy info) =>
50 :     CL.T_Template(
51 :     concat["diderot::image", Int.toString(ImageInfo.dim info), "d"],
52 :     [Env.realTy env])
53 :     | (Ty.StrandTy name) => CL.T_Named("strand_" ^ Atom.toString name)
54 :     (* end case *))
55 : jhr 3768
56 : jhr 3866 (* translate a local variable that occurs in an l-value context *)
57 : jhr 3873 fun lvalueVar (env, x) = CL.mkVar(Env.lookup(env, x))
58 : jhr 3866 (* translate a variable that occurs in an r-value context *)
59 : jhr 3873 fun rvalueVar (env, x) = CL.mkVar(Env.lookup(env, x))
60 : jhr 3768
61 : jhr 3866 (* translate a global variable that occurs in an l-value context *)
62 : jhr 3876 fun lvalueGlobalVar (env, x) = CL.mkIndirect(CL.mkVar(Env.global env), TreeGlobalVar.name x)
63 : jhr 3866 (* translate a global variable that occurs in an r-value context *)
64 :     val rvalueGlobalVar = lvalueGlobalVar
65 :    
66 :     (* translate a strand state variable that occurs in an l-value context *)
67 : jhr 3876 fun lvalueStateVar (env, x) = CL.mkIndirect(CL.mkVar(Env.selfOut env), TreeStateVar.name x)
68 : jhr 3866 (* translate a strand state variable that occurs in an r-value context *)
69 : jhr 3876 fun rvalueStateVar (env, x) = CL.mkIndirect(CL.mkVar(Env.selfIn env), TreeStateVar.name x)
70 : jhr 3866
71 :     (* generate new variables *)
72 :     local
73 :     val count = ref 0
74 :     fun freshName prefix = let
75 :     val n = !count
76 :     in
77 :     count := n+1;
78 :     concat[prefix, "_", Int.toString n]
79 :     end
80 :     in
81 :     fun tmpVar () = freshName "tmp"
82 :     fun freshVar prefix = freshName prefix
83 :     end (* local *)
84 :    
85 :     (* integer literal expression *)
86 :     fun intExp (i : int) = CL.mkInt(IntInf.fromInt i)
87 :    
88 : jhr 3893 val zero = CL.mkInt 0
89 :    
90 : jhr 3866 fun addrOf e = CL.mkUnOp(CL.%&, e)
91 :    
92 :     (* make an application of a function from the "std" namespace *)
93 :     fun mkStdApply (f, args) = CL.mkApply("std::" ^ f, args)
94 :    
95 :     (* make an application of a function from the "diderot" namespace *)
96 :     fun mkDiderotApply (f, args) = CL.mkApply("diderot::" ^ f, args)
97 : jhr 3872 fun mkDiderotCall (f, args) = CL.mkCall("diderot::" ^ f, args)
98 : jhr 3866
99 : jhr 3810 (* Translate a TreeIR operator application to a CLang expression *)
100 : jhr 3886 fun trOp (env, rator, args) = (case (rator, args)
101 : jhr 3870 of (Op.IAdd, [a, b]) => CL.mkBinOp(a, CL.#+, b)
102 : jhr 3768 | (Op.ISub, [a, b]) => CL.mkBinOp(a, CL.#-, b)
103 :     | (Op.IMul, [a, b]) => CL.mkBinOp(a, CL.#*, b)
104 :     | (Op.IDiv, [a, b]) => CL.mkBinOp(a, CL.#/, b)
105 :     | (Op.IMod, [a, b]) => CL.mkBinOp(a, CL.#%, b)
106 :     | (Op.INeg, [a]) => CL.mkUnOp(CL.%-, a)
107 :     | (Op.RAdd, [a, b]) => CL.mkBinOp(a, CL.#+, b)
108 :     | (Op.RSub, [a, b]) => CL.mkBinOp(a, CL.#-, b)
109 :     | (Op.RMul, [a, b]) => CL.mkBinOp(a, CL.#*, b)
110 :     | (Op.RDiv, [a, b]) => CL.mkBinOp(a, CL.#/, b)
111 :     | (Op.RNeg, [a]) => CL.mkUnOp(CL.%-, a)
112 : jhr 3870 | (Op.RClamp, [a, b, c]) => CL.mkApply("clamp", [a, b, c])
113 :     | (Op.RLerp, [a, b, c]) => CL.mkApply("lerp", [a, b, c])
114 : jhr 3886 | (Op.RCeiling, [a]) => mkStdApply("ceil", [a])
115 :     | (Op.RFloor, [a]) => mkStdApply("floor", [a])
116 :     | (Op.RRound, [a]) => mkStdApply("round", [a])
117 :     | (Op.RTrunc, [a]) => mkStdApply("trunc", [a])
118 :     | (Op.RealToInt, [a]) => mkStdApply("lround", [a])
119 : jhr 3768 | (Op.LT ty, [a, b]) => CL.mkBinOp(a, CL.#<, b)
120 :     | (Op.LTE ty, [a, b]) => CL.mkBinOp(a, CL.#<=, b)
121 :     | (Op.EQ ty, [a, b]) => CL.mkBinOp(a, CL.#==, b)
122 :     | (Op.NEQ ty, [a, b]) => CL.mkBinOp(a, CL.#!=, b)
123 :     | (Op.GTE ty, [a, b]) => CL.mkBinOp(a, CL.#>=, b)
124 :     | (Op.GT ty, [a, b]) => CL.mkBinOp(a, CL.#>, b)
125 :     | (Op.Not, [a]) => CL.mkUnOp(CL.%!, a)
126 : jhr 3866 | (Op.Abs ty, args) => mkStdApply("abs", args)
127 :     | (Op.Max ty, args) => mkStdApply("min", args)
128 :     | (Op.Min ty, args) => mkStdApply("max", args)
129 :     | (Op.VAdd d, [a, b]) => CL.mkBinOp(a, CL.#+, b)
130 :     | (Op.VSub d, [a, b]) => CL.mkBinOp(a, CL.#-, b)
131 : jhr 3870 | (Op.VScale d, [a, b]) => CL.mkApply("vscale", [a, b])
132 : jhr 3866 | (Op.VMul d, [a, b]) => CL.mkBinOp(a, CL.#*, b)
133 :     | (Op.VNeg d, [a]) => CL.mkUnOp(CL.%-, a)
134 : jhr 3872 | (Op.VSum d, [a]) => CL.mkApply("vsum", [a])
135 : jhr 3886 | (Op.VIndex(w, p, i), [a]) => CL.mkSubscript(a, intExp i)
136 :     | (Op.VClamp d, [a, b, c]) => CL.mkApply("vclamp", [a, b, c])
137 :     | (Op.VMapClamp d, [a, b, c]) => CL.mkApply("vclamp", [a, b, c])
138 :     | (Op.VLerp d, [a, b, c]) => CL.mkApply("vlerp", [a, b, c])
139 :     | (Op.VCeiling d, [a]) => CL.mkApply("vceiling", [a])
140 :     | (Op.VFloor d, [a]) => CL.mkApply("vfloor", [a])
141 :     | (Op.VRound d, [a]) => CL.mkApply("vround", [a])
142 :     | (Op.VTrunc d, [a]) => CL.mkApply("vtrunc", [a])
143 :     | (Op.VToInt d, [a]) => CL.mkApply("vtoi", [a])
144 :     | (Op.TensorIndex(Ty.TensorTy(_::dd), idxs), [a]) => let
145 :     (* dimensions/indices are slowest to fastest *)
146 :     fun index ([], [i], acc) = acc + i
147 :     | index (d::dd, i::ii, acc) = index (dd, ii, d * (acc + i))
148 :     in
149 :     CL.mkSubscript(a, intExp(index (dd, idxs, 0)))
150 :     end
151 :     | (Op.ProjectLast(Ty.TensorTy(_::dd), idxs), [a]) => let
152 :     (* dimensions/indices are slowest to fastest *)
153 :     fun index ([], [], acc) = acc
154 :     | index (d::dd, i::ii, acc) = index (dd, ii, d * (acc + i))
155 :     in
156 :     CL.mkAddrOf(CL.mkSubscript(a, intExp(index (dd, idxs, 0))))
157 :     end
158 :     | (Op.EigenVals2x2, [a]) => raise Fail "FIXME: EigenVals2x2"
159 :     | (Op.EigenVals3x3, [a]) => raise Fail "FIXME: EigenVals3x3"
160 :     | (Op.Select(ty, i), [a]) => raise Fail "FIXME: Select"
161 :     | (Op.Subscript ty, [a, b]) => CL.mkSubscript(a, b)
162 :     | (Op.MkDynamic(ty, i), [a]) => raise Fail "FIXME: MkDynamic"
163 :     | (Op.Append ty, [a, b]) => raise Fail "FIXME: Append"
164 :     | (Op.Prepend ty, [a, b]) => raise Fail "FIXME: Prepend"
165 :     | (Op.Concat ty, [a, b]) => raise Fail "FIXME: Concat"
166 :     | (Op.Range, [a, b]) => raise Fail "FIXME: Range"
167 :     | (Op.Length ty, [a]) => raise Fail "FIXME: Length"
168 :     | (Op.SphereQuery(ty1, ty2), []) => raise Fail "FIXME: SphereQuery"
169 : jhr 3870 | (Op.Sqrt, [a]) => mkStdApply("sqrt", [a])
170 :     | (Op.Cos, [a]) => mkStdApply("cos", [a])
171 :     | (Op.ArcCos, [a]) => mkStdApply("acos", [a])
172 :     | (Op.Sin, [a]) => mkStdApply("sin", [a])
173 :     | (Op.ArcSin, [a]) => mkStdApply("asin", [a])
174 :     | (Op.Tan, [a]) => mkStdApply("tan", [a])
175 :     | (Op.ArcTan, [a]) => mkStdApply("atan", [a])
176 :     | (Op.Exp, [a]) => mkStdApply("exp", [a])
177 : jhr 3886 | (Op.IntToReal, [a]) => CL.mkStaticCast(Env.realTy env, a)
178 : jhr 3768 (*
179 :     | R_All of ty
180 :     | R_Exists of ty
181 :     | R_Max of ty
182 :     | R_Min of ty
183 :     | R_Sum of ty
184 :     | R_Product of ty
185 :     | R_Mean of ty
186 :     | R_Variance of ty
187 :     *)
188 : jhr 3886 | (Op.Transform info, [img]) => CL.mkDispatch(img, "world2image", [])
189 :     | (Op.Translate info, [img]) => CL.mkDispatch(img, "translate", [])
190 :     | (Op.BaseAddress info, [img]) => CL.mkDispatch(img, "base_addr", [])
191 :     | (Op.ControlIndex(info, ctl, d), [img, idx]) =>
192 :     CL.mkDispatch(img, IndexCtl.toString ctl, [intExp d, idx])
193 :     | (Op.Inside(info, s), [pos, img]) => CL.mkDispatch(img, "inside", [pos, intExp s])
194 :     | (Op.ImageDim(info, i), [img]) => CL.mkDispatch(img, "size", [intExp i])
195 : jhr 3870 | (Op.MathFn f, args) => mkStdApply(MathFns.toString f, args)
196 : jhr 3866 | _ => raise Fail(concat[
197 :     "unknown or incorrect operator ", Op.toString rator
198 :     ])
199 : jhr 3768 (* end case *))
200 :    
201 : jhr 3866 fun trExp (env, e) = (case e
202 :     of IR.E_Global x => rvalueGlobalVar (env, x)
203 : jhr 3872 | IR.E_State(NONE, x) => rvalueStateVar (env, x)
204 :     | IR.E_State(SOME e, x) => CL.mkIndirect(trExp(env, e), TreeStateVar.name x)
205 : jhr 3866 | IR.E_Var x => rvalueVar (env, x)
206 : jhr 3876 | IR.E_Lit(Literal.Int n) => CL.mkIntTy(n, Env.intTy env)
207 : jhr 3866 | IR.E_Lit(Literal.Bool b) => CL.mkBool b
208 : jhr 3876 | IR.E_Lit(Literal.Real f) => CL.mkFlt(f, Env.realTy env)
209 : jhr 3866 | IR.E_Lit(Literal.String s) => CL.mkStr s
210 : jhr 3886 | IR.E_Op(rator, args) => trOp (env, rator, trExps(env, args))
211 : jhr 3893 | IR.E_Vec(w, pw, args) => let
212 :     val args = trExps (env, args)
213 :     val args = if (w < pw) then args @ List.tabulate(pw-w, fn _ => zero) else args
214 :     in
215 :     CL.mkVec(CL.T_Named("vec" ^ Int.toString pw), args)
216 :     end
217 :     | IR.E_Cons(args, Ty.TensorTy shape) => raise Fail "unexpected E_Cons"
218 :     | IR.E_Seq(args, ty) => raise Fail "unexpected E_Seq"
219 : jhr 3894 | IR.E_Pack(layout, args) => raise Fail "unexpected E_Pack"
220 :     (* FIXME: check if e is aligned and use "vload_aligned" in that case *)
221 :     | IR.E_VLoad(layout, e, i) =>
222 :     CL.mkTemplateApply("vload",
223 :     [trType(env, Ty.nthVec(layout, i))],
224 :     [CL.mkBinOp(trExp(env, e), CL.#+, intExp(Ty.offsetOf(layout, i)))])
225 :     | _ => raise Fail "trExp"
226 : jhr 3866 (* end case *))
227 :    
228 :     and trExps (env, exps) = List.map (fn exp => trExp(env, exp)) exps
229 :    
230 : jhr 3873 (* QUESTION: not sure that we need this function? *)
231 : jhr 3872 fun trExpToVar (env, ty, name, exp) = (case trExp (env, exp)
232 :     of e as CL.E_Var _ => (e, [])
233 :     | e => let
234 : jhr 3893 val x = freshVar name
235 : jhr 3872 in
236 : jhr 3876 (CL.mkVar x, [CL.mkDeclInit(ty, x, e)])
237 : jhr 3872 end
238 : jhr 3873 (* end case *))
239 : jhr 3872
240 : jhr 3893 fun trAssign (env, lhs, rhs) = let
241 :     fun trArg (i, arg) = CL.mkAssign(CL.mkSubscript(lhs, intExp i), trExp (env, arg))
242 :     in
243 :     case rhs
244 : jhr 3894 of IR.E_Pack(_, args) => [CL.mkCall ("vpack", List.map (fn e => trExp(env, e)) args)]
245 :     | IR.E_Cons(args, _) => List.mapi trArg args
246 : jhr 3893 | IR.E_Seq(args, _) => List.mapi trArg args
247 :     | _ => [CL.mkAssign(lhs, trExp (env, rhs))]
248 :     (* end case *)
249 :     end
250 : jhr 3872
251 : jhr 3893 fun trDecl (env, ty, lhs, rhs) = let
252 :     fun trArgs args = CL.mkDecl(
253 :     ty, lhs, SOME(CL.I_Exps(List.map (fn arg => CL.I_Exp(trExp (env, arg))) args)))
254 :     in
255 :     case rhs
256 :     of IR.E_Cons(args, _) => trArgs args
257 :     | IR.E_Seq(args, _) => trArgs args
258 :     | _ => CL.mkDeclInit(ty, lhs, trExp (env, rhs))
259 :     (* end case *)
260 :     end
261 : jhr 3872
262 : jhr 3870 fun trMultiAssign (env, lhs, IR.E_Op(rator, args)) = (case (lhs, rator, args)
263 : jhr 3876 of ([vals, vecs], Op.EigenVecs2x2, [exp]) =>
264 : jhr 3872 mkDiderotCall("eigenvecs", [trExp (env, exp), vals, vecs])
265 : jhr 3876 | ([vals, vecs], Op.EigenVecs3x3, [exp]) =>
266 : jhr 3872 mkDiderotCall("eigenvecs", [trExp (env, exp), vals, vecs])
267 : jhr 3870 | _ => raise Fail "bogus multi-assignment"
268 :     (* end case *))
269 :     | trMultiAssign (env, lhs, rhs) = raise Fail "bogus multi-assignment"
270 : jhr 3866
271 : jhr 3872 fun trStms (env, stms : TreeIR.stm list) = let
272 : jhr 3870 fun trStm (stm, (env, stms : CL.stm list)) = (case stm
273 :     of IR.S_Comment text => (env, CL.mkComment text :: stms)
274 : jhr 3872 | IR.S_Assign(true, x, exp) => let
275 : jhr 3893 val ty = trType (env, V.ty x)
276 : jhr 3894 val x' = V.name x
277 : jhr 3893 val env = Env.insert (env, x, x')
278 : jhr 3872 in
279 : jhr 3893 (env, trDecl (env, ty, x', exp) :: stms)
280 : jhr 3872 end
281 :     | IR.S_Assign(false, x, exp) => let
282 : jhr 3893 val stms' = trAssign (env, lvalueVar (env, x), exp)
283 : jhr 3866 in
284 : jhr 3893 (env, stms' @ stms)
285 : jhr 3866 end
286 :     | IR.S_MAssign(xs, exp) =>
287 : jhr 3886 (env, trMultiAssign (env, List.map (fn x => lvalueVar (env, x)) xs, exp) :: stms)
288 : jhr 3866 | IR.S_GAssign(x, exp) =>
289 : jhr 3893 (env, trAssign (env, lvalueGlobalVar (env, x), exp) @ stms)
290 : jhr 3866 | IR.S_IfThen(cond, thenBlk) =>
291 : jhr 3870 (env, CL.mkIfThen(trExp(env, cond), trBlock(env, thenBlk)) :: stms)
292 : jhr 3866 | IR.S_IfThenElse(cond, thenBlk, elseBlk) => let
293 :     val stm = CL.mkIfThenElse(trExp(env, cond),
294 : jhr 3870 trBlock(env, thenBlk),
295 :     trBlock(env, elseBlk))
296 : jhr 3866 in
297 :     (env, stm :: stms)
298 :     end
299 : jhr 3876 | IR.S_Foreach(x, IR.E_Op(Op.Range, [lo, hi]), blk) => let
300 :     val x' = V.name x
301 :     val env' = Env.insert (env, x, x')
302 : jhr 3894 val (hi', hiInit) = if CodeGenUtil.isSimple hi
303 :     then (trExp(env, hi), [])
304 :     else let
305 :     val hi' = freshVar "hi"
306 :     in
307 :     (CL.mkVar hi', [CL.mkDeclInit(CL.int32, hi', trExp(env, hi))])
308 :     end
309 : jhr 3876 val loop = CL.mkFor(
310 : jhr 3894 [(CL.int32, x', trExp(env, lo))],
311 : jhr 3876 CL.mkBinOp(CL.mkVar x', CL.#<=, hi'),
312 : jhr 3886 [CL.mkUnOp(CL.%++, CL.mkVar x')],
313 : jhr 3876 trBlock (env', blk))
314 :     in
315 : jhr 3894 (env, hiInit @ loop :: stms)
316 : jhr 3876 end
317 : jhr 3894 | IR.S_Foreach(x, e, blk) => raise Fail "Foreach"
318 :     | IR.S_New(strand, args) => raise Fail "New"
319 : jhr 3893 | IR.S_Save(x, exp) => (env, trAssign (env, lvalueStateVar(env, x), exp))
320 : jhr 3894 | IR.S_LoadNrrd(lhs, ty, nrrd) => let
321 :     val stm = (case ty
322 :     of APITypes.SeqTy(ty, NONE) =>
323 : jhr 3886 GenLoadNrrd.loadSeqFromFile (lvalueVar (env, lhs), ty, CL.mkStr nrrd)
324 : jhr 3900 | APITypes.ImageTy _ =>
325 :     GenLoadNrrd.loadImage (lvalueVar (env, lhs), CL.mkStr nrrd)
326 : jhr 3894 | _ => raise Fail(concat[
327 :     "bogus type ", APITypes.toString ty, " for LoadNrrd"
328 :     ])
329 : jhr 3886 (* end case *))
330 :     in
331 :     (env, stm :: stms)
332 :     end
333 : jhr 3870 | IR.S_Input(_, _, _, NONE) => (env, stms)
334 :     | IR.S_Input(gv, name, _, SOME dflt) =>
335 :     (env, CL.mkAssign(lvalueGlobalVar (env, gv), trExp(env, dflt)) :: stms)
336 : jhr 3866 | IR.S_InputNrrd _ => (env, stms)
337 : jhr 3870 | IR.S_Exit => (env, stms)
338 :     | IR.S_Print(tys, args) => let
339 :     val args = List.map (fn e => trExp(env, e)) args
340 :     val stm = GenPrint.genPrintStm (
341 :     CL.mkIndirect(CL.mkVar "wrld", "_output"),
342 :     tys, args)
343 :     in
344 :     (env, stm::stms)
345 :     end
346 : jhr 3876 | IR.S_Active => (env, CL.mkReturn(SOME(CL.mkVar "diderot::kActive")) :: stms)
347 :     | IR.S_Stabilize => (env, CL.mkReturn(SOME(CL.mkVar "diderot::kStabilize")) :: stms)
348 :     | IR.S_Die => (env, CL.mkReturn(SOME(CL.mkVar "diderot::kDie")) :: stms)
349 : jhr 3866 (* end case *))
350 :     in
351 :     List.rev (#2 (List.foldl trStm (env, []) stms))
352 :     end
353 :    
354 :     and trBlock (env, IR.Block{locals, body}) = let
355 : jhr 3873 fun trLocal (x, (env, dcls)) = let
356 :     val x' = V.name x
357 : jhr 3886 val dcl = CL.mkDecl(trType(env, V.ty x), x', NONE)
358 : jhr 3873 in
359 : jhr 3886 (Env.insert(env, x, x'), dcl :: dcls)
360 : jhr 3873 end
361 :     val (env, dcls) = List.foldl trLocal (env, []) (!locals)
362 : jhr 3866 in
363 : jhr 3873 CL.mkBlock (dcls @ trStms (env, body))
364 : jhr 3866 end
365 :    
366 : jhr 3900 fun errorMsgAdd msg =
367 :     CL.mkCall("biffMsgAdd", [CL.mkIndirect(CL.mkVar "wrld", "_errors"), msg])
368 :    
369 : jhr 3768 end

root@smlnj-gforge.cs.uchicago.edu
ViewVC Help
Powered by ViewVC 1.0.0