Home My Page Projects Code Snippets Project Openings diderot
Summary Activity Tracker Tasks SCM

SCM Repository

[diderot] View of /branches/vis15/src/compiler/cxx-util/tree-to-cxx.sml
ViewVC logotype

View of /branches/vis15/src/compiler/cxx-util/tree-to-cxx.sml

Parent Directory Parent Directory | Revision Log Revision Log


Revision 4026 - (download) (annotate)
Wed Jun 22 15:55:07 2016 UTC (3 years, 2 months ago) by jhr
File size: 17908 byte(s)
  Working on merge: code generation
(* tree-to-cxx.sml
 *
 * This code is part of the Diderot Project (http://diderot-language.cs.uchicago.edu)
 *
 * COPYRIGHT (c) 2016 The University of Chicago
 * All rights reserved.
 *
 * Translate TreeIR to the C++ version of CLang.
 *)


structure TreeToCxx : sig

    val trType : CodeGenEnv.t * TreeTypes.t -> CLang.ty

    val trBlock : CodeGenEnv.t * TreeIR.block -> CLang.stm

    val trWithLocals : CodeGenEnv.t * TreeVar.t list * (CodeGenEnv.t -> CLang.stm list) -> CLang.stm

    val trStms : CodeGenEnv.t * TreeIR.stm list -> CodeGenEnv.t * CLang.stm list

    val trExp : CodeGenEnv.t * TreeIR.exp -> CLang.exp

  (* translate an expression to a variable form; return the variable (as an expression)
   * and the (optional) declaration.
   *)
    val trExpToVar : CodeGenEnv.t * CLang.ty * string * TreeIR.exp -> CLang.exp * CLang.stm list

  (* generate code to register an error message (require that a world pointer "wrld" is in scope) *)
    val errorMsgAdd : CodeGenEnv.t * CLang.exp -> CLang.stm

    val trParam : CodeGenEnv.t * TreeIR.var -> CodeGenEnv.t * CLang.param

  end = struct

    structure CL = CLang
    structure IR = TreeIR
    structure Op = TreeOps
    structure Ty = TreeTypes
    structure V = TreeVar
    structure Env = CodeGenEnv
    structure RN = CxxNames

    val trType = TypeToCxx.trType
    val dynseqTy = TypeToCxx.dynseqTy

  (* translate a local variable that occurs in an l-value context *)
    fun lvalueVar (env, x) = CL.mkVar(Env.lookup(env, x))
  (* translate a variable that occurs in an r-value context *)
    fun rvalueVar (env, x) = CL.mkVar(Env.lookup(env, x))

  (* translate a global variable that occurs in an l-value context *)
    fun lvalueGlobalVar (env, x) = CL.mkIndirect(CL.mkVar(Env.global env), TreeGlobalVar.qname x)
  (* translate a global variable that occurs in an r-value context *)
    val rvalueGlobalVar = lvalueGlobalVar

  (* translate a strand state variable that occurs in an l-value context *)
    fun lvalueStateVar (env, x) = CL.mkIndirect(CL.mkVar(Env.selfOut env), TreeStateVar.qname x)
  (* translate a strand state variable that occurs in an r-value context *)
    fun rvalueStateVar (env, x) = CL.mkIndirect(CL.mkVar(Env.selfIn env), TreeStateVar.qname x)

    fun worldVar env = CL.mkVar(Env.world env)

  (* generate new variables *)
    val freshVar = CodeGenUtil.freshVar

  (* integer literal expression *)
    fun mkInt (i : int) = CL.mkInt(IntInf.fromInt i)

    val zero = CL.mkInt 0

    fun addrOf e = CL.mkUnOp(CL.%&, e)

  (* make an application of a function from the "std" namespace *)
    fun mkStdApply (f, args) = CL.mkApply("std::" ^ f, args)

  (* make an application of a function from the "diderot" namespace *)
    fun mkDiderotApply (f, args) = CL.mkApply("diderot::" ^ f, args)
    fun mkDiderotCall (f, args) = CL.mkCall("diderot::" ^ f, args)
    fun mkDynseqApply (env, ty, f, args) = CL.mkTemplateApply(f, [dynseqTy(env, ty)], args)

  (* Translate a TreeIR operator application to a CLang expression *)
    fun trOp (env, rator, args) = (case (rator, args)
	   of (Op.IAdd, [a, b]) => CL.mkBinOp(a, CL.#+, b)
	    | (Op.ISub, [a, b]) => CL.mkBinOp(a, CL.#-, b)
	    | (Op.IMul, [a, b]) => CL.mkBinOp(a, CL.#*, b)
	    | (Op.IDiv, [a, b]) => CL.mkBinOp(a, CL.#/, b)
	    | (Op.IMod, [a, b]) => CL.mkBinOp(a, CL.#%, b)
	    | (Op.INeg, [a]) => CL.mkUnOp(CL.%-, a)
	    | (Op.RAdd, [a, b]) => CL.mkBinOp(a, CL.#+, b)
	    | (Op.RSub, [a, b]) => CL.mkBinOp(a, CL.#-, b)
	    | (Op.RMul, [a, b]) => CL.mkBinOp(a, CL.#*, b)
	    | (Op.RDiv, [a, b]) => CL.mkBinOp(a, CL.#/, b)
	    | (Op.RNeg, [a]) => CL.mkUnOp(CL.%-, a)
	    | (Op.RClamp, [a, b, c]) => CL.mkApply("clamp", [a, b, c])
	    | (Op.RLerp, [a, b, c]) => CL.mkApply("lerp", [a, b, c])
	    | (Op.RCeiling, [a]) => mkStdApply("ceil", [a])
	    | (Op.RFloor, [a]) => mkStdApply("floor", [a])
	    | (Op.RRound, [a]) => mkStdApply("round", [a])
	    | (Op.RTrunc, [a]) => mkStdApply("trunc", [a])
	    | (Op.RealToInt, [a]) => mkStdApply("lround", [a])
            | (Op.LT ty, [a, b]) => CL.mkBinOp(a, CL.#<, b)
            | (Op.LTE ty, [a, b]) => CL.mkBinOp(a, CL.#<=, b)
            | (Op.EQ ty, [a, b]) => CL.mkBinOp(a, CL.#==, b)
            | (Op.NEQ ty, [a, b]) => CL.mkBinOp(a, CL.#!=, b)
            | (Op.GTE ty, [a, b]) => CL.mkBinOp(a, CL.#>=, b)
            | (Op.GT ty, [a, b]) => CL.mkBinOp(a, CL.#>, b)
            | (Op.Not, [a]) => CL.mkUnOp(CL.%!, a)
	    | (Op.Abs ty, args) => mkStdApply("abs", args)
	    | (Op.Max ty, args) => mkStdApply("min", args)
	    | (Op.Min ty, args) => mkStdApply("max", args)
	    | (Op.VAdd d, [a, b]) => CL.mkBinOp(a, CL.#+, b)
	    | (Op.VSub d, [a, b]) => CL.mkBinOp(a, CL.#-, b)
	    | (Op.VScale d, [a, b]) => CL.mkApply("vscale", [a, b])
	    | (Op.VMul d, [a, b]) => CL.mkBinOp(a, CL.#*, b)
	    | (Op.VNeg d, [a]) => CL.mkUnOp(CL.%-, a)
	    | (Op.VSum(w, _), [a]) => CL.mkApply(RN.vsum w, [a])
	    | (Op.VIndex(w, p, i), [a]) => CL.mkSubscript(a, mkInt i)
	    | (Op.VClamp(w, _), [a, b, c]) => CL.mkApply("vclamp", [a, b, c])
	    | (Op.VMapClamp(w, _), [a, b, c]) => CL.mkApply("vclamp", [a, b, c])
	    | (Op.VLerp(w, _), [a, b, c]) => CL.mkApply("vlerp", [a, b, c])
	    | (Op.VCeiling d, [a]) => CL.mkApply("vceiling", [a])
	    | (Op.VFloor d, [a]) => CL.mkApply("vfloor", [a])
	    | (Op.VRound d, [a]) => CL.mkApply("vround", [a])
	    | (Op.VTrunc d, [a]) => CL.mkApply("vtrunc", [a])
	    | (Op.TensorIndex(Ty.TensorRefTy(_::dd), idxs), [a]) => let
	      (* dimensions/indices are slowest to fastest *)
		fun index ([], [i], acc) = acc + i
		  | index (d::dd, i::ii, acc) = index (dd, ii, d * (acc + i))
		in
		  CL.mkSubscript(a, mkInt(index (dd, idxs, 0)))
		end
	    | (Op.ProjectLast(Ty.TensorRefTy(_::dd), idxs), [a]) => let
	      (* dimensions/indices are slowest to fastest *)
		fun index ([], [], acc) = acc
		  | index (d::dd, i::ii, acc) = index (dd, ii, d * (acc + i))
		in
		  CL.mkAddrOf(CL.mkSubscript(a, mkInt(index (dd, idxs, 0))))
		end
	    | (Op.EigenVals2x2, [a]) => raise Fail "FIXME: EigenVals2x2"
	    | (Op.EigenVals3x3, [a]) => raise Fail "FIXME: EigenVals3x3"
	    | (Op.Select(ty, i), [a]) => raise Fail "FIXME: Select"
	    | (Op.Subscript ty, [a, b]) => CL.mkSubscript(a, b)
	    | (Op.MkDynamic(ty, n), [a]) => CL.mkCons(dynseqTy(env, ty), [mkInt n, a])
(* FIXME: eventually we should do some kind of liveness analysis to enable in situ operations *)
	    | (Op.Append ty, [a, b]) => mkDynseqApply (env, ty, "append", [a, b])
	    | (Op.Prepend ty, [a, b]) => mkDynseqApply (env, ty, "prepend", [a, b])
	    | (Op.Concat ty, [a, b]) => mkDynseqApply (env, ty, "concat", [a, b])
	    | (Op.Range, [a, b]) => CL.mkCons(dynseqTy(env, Ty.IntTy), [a, b])
	    | (Op.Length ty, [a]) => CL.mkDispatch(a, "length", [])
	    | (Op.SphereQuery(ty1, ty2), []) => raise Fail "FIXME: SphereQuery"
	    | (Op.Sqrt, [a]) => mkStdApply("sqrt", [a])
	    | (Op.Cos, [a]) => mkStdApply("cos", [a])
	    | (Op.ArcCos, [a]) => mkStdApply("acos", [a])
	    | (Op.Sin, [a]) => mkStdApply("sin", [a])
	    | (Op.ArcSin, [a]) => mkStdApply("asin", [a])
	    | (Op.Tan, [a]) => mkStdApply("tan", [a])
	    | (Op.ArcTan, [a]) => mkStdApply("atan", [a])
	    | (Op.Exp, [a]) => mkStdApply("exp", [a])
	    | (Op.IntToReal, [a]) => CL.mkStaticCast(Env.realTy env, a)
(*
	    | R_All of ty
	    | R_Exists of ty
	    | R_Max of ty
	    | R_Min of ty
	    | R_Sum of ty
	    | R_Product of ty
	    | R_Mean of ty
	    | R_Variance of ty
*)
	    | (Op.Transform info, [img]) => let
		val e = CL.mkDispatch(img, "world2image", [])
		in
		  case ImageInfo.dim info
		   of 1 => e
		    | d => CL.mkCons(RN.tensorRefTy[d,d], [e])
		  (* end case *)
		end
	    | (Op.Translate info, [img]) => let
		val e = CL.mkDispatch(img, "translate", [])
		in
		  case ImageInfo.dim info
		   of 1 => e
		    | d => CL.mkCons(RN.tensorRefTy[d], [e])
		  (* end case *)
		end
	    | (Op.BaseAddress info, [img]) => CL.mkDispatch(img, "base_addr", [])
	    | (Op.ControlIndex(info, ctl, d), [img, idx]) =>
		CL.mkDispatch(img, IndexCtl.toString ctl, [mkInt d, idx])
	    | (Op.LoadVoxel info, [addr, offp]) => let
		val voxel = CL.mkSubscript(addr, offp)
		in
		  case ImageInfo.sampleTy info
		   of NONE => voxel (* no proxy, so we are using the default real type *)
		    | SOME rty => if RawTypes.same(rty, Env.rawRealTy env)
			then voxel
			else CL.mkStaticCast(Env.realTy env, voxel)
		  (* end case *)
		end
	    | (Op.Inside(info, s), [pos, img]) => CL.mkDispatch(img, "inside", [pos, mkInt s])
	    | (Op.ImageDim(info, i), [img]) => CL.mkDispatch(img, "size", [mkInt i])
	    | (Op.MathFn f, args) => mkStdApply(MathFns.toString f, args)
	    | _ => raise Fail(concat[
		   "unknown or incorrect operator ", Op.toString rator
		 ])
	  (* end case *))

    fun trExp (env, e) = (case e
           of IR.E_Global x => rvalueGlobalVar (env, x)
            | IR.E_State(NONE, x) => rvalueStateVar (env, x)
            | IR.E_State(SOME e, x) => CL.mkIndirect(trExp(env, e), TreeStateVar.name x)
            | IR.E_Var x => rvalueVar (env, x)
            | IR.E_Lit(Literal.Int n) => CL.mkIntTy(n, Env.intTy env)
            | IR.E_Lit(Literal.Bool b) => CL.mkBool b
            | IR.E_Lit(Literal.Real f) => CL.mkFlt(f, Env.realTy env)
            | IR.E_Lit(Literal.String s) => CL.mkStr s
            | IR.E_Op(rator, args) => trOp (env, rator, trExps(env, args))
	    | IR.E_Vec(w, pw, args) => CL.mkApply(RN.vcons w, trExps (env, args))
            | IR.E_Cons(args, Ty.TensorTy shape) => raise Fail "unexpected E_Cons"
            | IR.E_Seq(args, ty) => raise Fail "unexpected E_Seq"
	    | IR.E_Pack(layout, args) => raise Fail "unexpected E_Pack"
(* FIXME: check if e is aligned and use "vload_aligned" in that case *)
	    | IR.E_VLoad(layout, e, i) =>
		CL.mkApply(RN.vload(Ty.nthWidth(layout, i)),
		  [CL.mkDispatch(trExp(env, e), "addr", [mkInt(Ty.offsetOf(layout, i))])])
	    | _ => raise Fail "trExp"
          (* end case *))

    and trExps (env, exps) = List.map (fn exp => trExp(env, exp)) exps

(* QUESTION: not sure that we need this function? *)
    fun trExpToVar (env, ty, name, exp) = (case trExp (env, exp)
	   of e as CL.E_Var _ => (e, [])
	    | e => let
		val x = freshVar name
		in
		  (CL.mkVar x, [CL.mkDeclInit(ty, x, e)])
		end
	  (* end case *))

(* FIXME: trAssign and trDecl do the same analysis of the rhs; we should factor that out *)
  (* translate the assignment `lhs = rhs` and add the code to the stms list.  Note that the
   * stms list is reverse order!
   *)
    fun trAssign (env, lhs, rhs, stms) = let
	  fun trArg (i, arg, stms) =
		CL.mkAssign(CL.mkSubscript(lhs, mkInt i), trExp (env, arg)) :: stms
	  in
	    case rhs
	     of IR.E_Op(Op.VToInt _, [a]) =>
		  CL.mkCall ("vtoi", [lhs, trExp(env, a)]) :: stms
(*
	      | IR.E_Op(Op.TensorCopy shp, [a]) =>
		  CL.mkCall (RN.tensorCopy shp, [lhs, trExp(env, a)]) :: stms
*)
	      | IR.E_Op(Op.TensorCopy shp, [a]) => CL.mkAssign(lhs, trExp (env, a)) :: stms
	      | IR.E_Pack({wid, ...}, args) =>
		  CL.mkCall (RN.vpack wid, lhs :: List.map (fn e => trExp(env, e)) args) :: stms
	      | IR.E_Cons(args, _) => List.foldli trArg stms args
	      | IR.E_Seq(args, _) => List.foldli trArg stms args
	      | _ => CL.mkAssign(lhs, trExp (env, rhs)) :: stms
	    (* end case *)
	  end

    fun trDecl (env, ty, lhs, rhs, stms) = let
	  fun trArgs args = CL.mkDecl(
		ty, lhs, SOME(CL.I_Exps(List.map (fn arg => CL.I_Exp(trExp (env, arg))) args)))
	  in
	    case rhs
	     of IR.E_Op(Op.VToInt _, [a]) => (* NOTE: reverse order! *)
		  CL.mkCall ("vtoi", [CL.mkVar lhs, trExp(env, a)]) ::
		  CL.mkDecl(ty, lhs, NONE) :: stms
(*
	      | IR.E_Op(Op.TensorCopy shp, [a]) => [ (* NOTE: reverse order! *)
		    CL.mkCall (RN.tensorCopy shp, [CL.mkVar lhs, trExp(env, a)]),
		    CL.mkDecl(ty, lhs, NONE)
		  ]
*)
	      | IR.E_Op(Op.TensorCopy shp, [a]) => CL.mkDeclInit(ty, lhs, trExp(env, a)) :: stms
	      | IR.E_Pack({wid, ...}, args) =>
		  CL.mkCall (RN.vpack wid, CL.mkVar lhs :: List.map (fn e => trExp(env, e)) args) ::
		  CL.mkDecl(ty, lhs, NONE) :: stms
	      | IR.E_Cons(args, _) => trArgs args :: stms
	      | IR.E_Seq(args, _) => trArgs args :: stms
	      | _ => CL.mkDeclInit(ty, lhs, trExp (env, rhs)) :: stms
	    (* end case *)
	  end

    fun trMultiAssign (env, lhs, IR.E_Op(rator, args)) = (case (lhs, rator, args)
           of ([vals, vecs], Op.EigenVecs2x2, [exp]) =>
		mkDiderotCall("eigenvecs", [trExp (env, exp), vals, vecs])
            | ([vals, vecs], Op.EigenVecs3x3, [exp]) =>
		mkDiderotCall("eigenvecs", [trExp (env, exp), vals, vecs])
            | _ => raise Fail "bogus multi-assignment"
          (* end case *))
      | trMultiAssign (env, lhs, rhs) = raise Fail "bogus multi-assignment"

    fun trPrintStm (outS, tys, args) = let
	  fun mkExp (lhs, [], []) = CL.mkBinOp(lhs, CL.#<<, CL.mkVar "std::flush")
	    | mkExp (lhs, ty::tys, e::es) = let
	      (* if necessary, wrap the argument so that the correct "<<" instance is used *)
		val e = (case ty
		       of Ty.TensorTy shape => CL.mkApply(RN.tensorStruct shape, [e])
			| _ => e
		      (* end case *))
		in
		  mkExp (CL.mkBinOp(lhs, CL.#<<, e), tys, es)
		end
	    | mkExp _ = raise Fail "trPrintStm: arity mismatch"
	  in
	    CL.mkExpStm (mkExp (outS, tys, args))
	  end

    fun trStms (env, stms : TreeIR.stm list) = let
          fun trStm (stm, (env, stms : CL.stm list)) = (case stm
                 of IR.S_Comment text => (env, CL.mkComment text :: stms)
                  | IR.S_Assign(true, x, exp) => let
		      val ty = trType (env, V.ty x)
		      val x' = V.name x
		      val env = Env.insert (env, x, x')
		      in
			(env, trDecl (env, ty, x', exp, stms))
		      end
                  | IR.S_Assign(false, x, exp) =>
		      (env, trAssign (env, lvalueVar (env, x), exp, stms))
		  | IR.S_MAssign(xs, exp) =>
                      (env, trMultiAssign (env, List.map (fn x => lvalueVar (env, x)) xs, exp) :: stms)
                  | IR.S_GAssign(x, exp) =>
		      (env, trAssign (env, lvalueGlobalVar (env, x), exp, stms))
                  | IR.S_IfThen(cond, thenBlk) =>
                      (env, CL.mkIfThen(trExp(env, cond), trBlock(env, thenBlk)) :: stms)
                  | IR.S_IfThenElse(cond, thenBlk, elseBlk) => let
		      val stm = CL.mkIfThenElse(trExp(env, cond),
			    trBlock(env, thenBlk),
			    trBlock(env, elseBlk))
		      in
			(env, stm :: stms)
		      end
		  | IR.S_For(x, lo, hi, blk) => let
		      val x' = V.name x
		      val env' = Env.insert (env, x, x')
		      val (hi', hiInit) = if CodeGenUtil.isSimple hi
			    then (trExp(env, hi), [])
			    else let
			      val hi' = freshVar "hi"
			      in
				(CL.mkVar hi', [CL.mkDeclInit(CL.int32, hi', trExp(env, hi))])
			      end
		      val loop = CL.mkFor(
			    CL.int32, [( x', trExp(env, lo))],
			    CL.mkBinOp(CL.mkVar x', CL.#<=, hi'),
			    [CL.mkUnOp(CL.%++, CL.mkVar x')],
			    trBlock (env', blk))
		      in
			(env, hiInit @ loop :: stms)
		      end
		  | IR.S_Foreach(x, e, blk) => raise Fail "Foreach"
                  | IR.S_New(strand, args) => let
		      val args = List.map (fn e => trExp(env, e)) args
		      val stm = CL.mkCall(
			    Atom.toString strand ^ "_new",
			    worldVar env :: args)
		      in
			(env, stm :: stms)
		      end
                  | IR.S_Save(x, exp) =>
		    (env, trAssign (env, lvalueStateVar(env, x), exp, stms))
                  | IR.S_LoadNrrd(lhs, ty, nrrd) => let
		      val stm = (case ty
			     of APITypes.SeqTy(ty, NONE) =>
				  GenLoadNrrd.loadSeqFromFile (
				    env, lvalueVar (env, lhs), ty, CL.mkStr nrrd)
			      | APITypes.ImageTy _ =>
				  GenLoadNrrd.loadImage (lvalueVar (env, lhs), CL.mkStr nrrd)
			      | _ => raise Fail(concat[
				    "bogus type ", APITypes.toString ty, " for LoadNrrd"
				  ])
			    (* end case *))
		      in
			(env, stm :: stms)
		      end
                  | IR.S_Input(_, _, _, NONE) => (env, stms)
                  | IR.S_Input(gv, name, _, SOME dflt) =>
                      (env, CL.mkAssign(lvalueGlobalVar (env, gv), trExp(env, dflt)) :: stms)
                  | IR.S_InputNrrd _ => (env, stms)
                  | IR.S_Exit => (env, List.revAppend(Env.handleExit env, stms))
		  | IR.S_Print(tys, args) => let
		      val args = List.map (fn e => trExp(env, e)) args
		      val stm = trPrintStm (
			    CL.mkIndirectDispatch(worldVar env, "output", []),
			    tys, args)
		      in
			(env, stm::stms)
		      end
                  | IR.S_Active => (env, CL.mkReturn(SOME(CL.mkVar "diderot::kActive")) :: stms)
                  | IR.S_Stabilize => (env, CL.mkReturn(SOME(CL.mkVar "diderot::kStabilize")) :: stms)
                  | IR.S_Die => (env, CL.mkReturn(SOME(CL.mkVar "diderot::kDie")) :: stms)
                (* end case *))
	  val (env, stms) = List.foldl trStm (env, []) stms
          in
	    (env, List.rev stms)
          end

    and trBlock (env, IR.Block{locals, body}) = let
	  fun trLocal (x, (env, dcls)) = let
		val x' = V.name x
		val dcl = CL.mkDecl(trType(env, V.ty x), x', NONE)
		in
		  (Env.insert(env, x, x'), dcl :: dcls)
		end
	  val (env, dcls) = List.foldl trLocal (env, []) (!locals)
	  val (_, stms) = trStms (env, body)
          in
            CL.mkBlock (dcls @ stms)
          end

    and trWithLocals (env, locals, trBody) = let
	  fun trLocal (x, (env, dcls)) = let
		val x' = V.name x
		val dcl = CL.mkDecl(trType(env, V.ty x), x', NONE)
		in
		  (Env.insert(env, x, x'), dcl :: dcls)
		end
	  val (env, dcls) = List.foldl trLocal (env, []) locals
          in
            CL.mkBlock (dcls @ trBody env)
          end

    fun errorMsgAdd (env, msg) =
          CL.mkCall("biffMsgAdd", [CL.mkIndirect(worldVar env, "_errors"), msg])

    fun trParam (env, x)= let
	  val x' = V.name x
	  in
	    (Env.insert (env, x, x'), CL.PARAM([], trType(env, V.ty x), x'))
	  end

  end

root@smlnj-gforge.cs.uchicago.edu
ViewVC Help
Powered by ViewVC 1.0.0