Home My Page Projects Code Snippets Project Openings diderot
Summary Activity Tracker Tasks SCM

SCM Repository

[diderot] Annotation of /branches/vis15/src/compiler/high-to-mid/high-to-mid.sml
ViewVC logotype

Annotation of /branches/vis15/src/compiler/high-to-mid/high-to-mid.sml

Parent Directory Parent Directory | Revision Log Revision Log


Revision 3615 - (view) (download)

1 : jhr 3529 (* high-to-mid.sml
2 :     *
3 :     * Translation from HighIR to MidIR representations.
4 :     *
5 :     * This code is part of the Diderot Project (http://diderot-language.cs.uchicago.edu)
6 :     *
7 :     * COPYRIGHT (c) 2015 The University of Chicago
8 :     * All rights reserved.
9 :     *)
10 :    
11 :     structure HighToMid : sig
12 :    
13 :     val translate : HighIR.program -> MidIR.program
14 :    
15 :     end = struct
16 :    
17 :     structure SrcIR = HighIR
18 : jhr 3534 structure SrcTy = HighTypes
19 : jhr 3529 structure SrcOp = HighOps
20 :     structure SrcSV = SrcIR.StateVar
21 :     structure VTbl = SrcIR.Var.Tbl
22 :     structure DstIR = MidIR
23 : jhr 3534 structure DstTy = MidTypes
24 : jhr 3529 structure DstOp = MidOps
25 :     structure InP = Inputs
26 :     structure BCtl = BorderCtl
27 :    
28 :     fun useCount (SrcIR.V{useCnt, ...}) = !useCnt
29 :    
30 : jhr 3586 fun getRHS x = (case SrcIR.Var.getDef x
31 :     of SrcIR.GLOBAL gv => raise Fail(concat[
32 :     "expected rhs binding for ", SrcIR.Var.toString x,
33 :     " but found mutable global ", SrcIR.GlobalVar.toString gv
34 :     ])
35 :     | rhs => rhs
36 :     (* end case *))
37 : jhr 3529
38 : jhr 3586 fun getRHSOp x = (case SrcIR.Var.getDef x
39 : jhr 3534 of SrcIR.OP(rator, args) => (rator, args)
40 :     | rhs => raise Fail(concat[
41 :     "expected rhs operator for ", SrcIR.Var.toString x,
42 :     " but found ", SrcIR.RHS.toString rhs
43 :     ])
44 :     (* end case *))
45 :    
46 : jhr 3529 (* get the image referenced on a RHS and its border control (if any) *)
47 : jhr 3582 fun getRHSImage x = (case getRHSOp x
48 :     of (SrcOp.BorderCtlDefault info, [img, v]) => (info, BCtl.Default v)
49 :     | (SrcOp.BorderCtlClamp info, [img]) => (info, BCtl.clamp)
50 :     | (SrcOp.BorderCtlMirror info, [img]) => (info, BCtl.mirror)
51 :     | (SrcOp.BorderCtlWrap info, [img]) => (info, BCtl.wrap)
52 :     | (SrcOp.LoadImage(SrcTy.ImageTy info, _), _) => (info, BCtl.None)
53 :     | _ => raise Fail "bogus image variable"
54 :     (* end case *))
55 : jhr 3529
56 :     fun cvtTy SrcTy.BoolTy = DstTy.BoolTy
57 :     | cvtTy SrcTy.StringTy = DstTy.StringTy
58 :     | cvtTy SrcTy.IntTy = DstTy.intTy
59 :     | cvtTy (SrcTy.TensorTy dd) = DstTy.tensorTy dd
60 :     | cvtTy (SrcTy.SeqTy(ty, n)) = DstTy.SeqTy(cvtTy ty, n)
61 :     (* we replace Kernel and Field operations by 0, so the types are mapped to int *)
62 :     | cvtTy SrcTy.KernelTy = DstTy.KernelTy
63 :     | cvtTy SrcTy.FieldTy = DstTy.intTy
64 :     | cvtTy (SrcTy.ImageTy info) = DstTy.ImageTy info
65 :     | cvtTy ty = raise Fail("unexpected type " ^ SrcTy.toString ty)
66 :    
67 :     (* instantiate the translation environment *)
68 :     structure Env = TranslateEnvFn (
69 :     struct
70 :     structure SrcIR = SrcIR
71 :     structure DstIR = DstIR
72 :     val cvtTy = cvtTy
73 :     end)
74 :    
75 :     (* expand raising a real to an integer power. When we know the exponent, we can inline
76 :     * multiplications.
77 :     *)
78 :     fun expandPower (env, y, [x, n]) = let
79 :     fun getConst x = (case SrcIR.Var.binding x
80 :     of SrcIR.VB_RHS(SrcIR.VAR x') => getConst x'
81 :     | SrcIR.VB_RHS(SrcIR.LIT(Literal.Int n)) => SOME n
82 :     | vb => NONE
83 :     (* end case *))
84 :     val x = Env.rename(env, x)
85 :     fun pow () = let
86 :     val t = DstIR.Var.new("n", DstTy.realTy)
87 :     in [
88 :     (t, DstIR.OP(DstOp.IntToReal, [Env.rename(env, n)])),
89 : jhr 3582 (y, DstIR.OP(DstOp.MathFn MathFns.POW, [x, t]))
90 : jhr 3529 ] end
91 :     in
92 :     case getConst n
93 : jhr 3534 of SOME 0 => [(y, DstIR.LIT(Literal.Real(RealLit.one)))]
94 : jhr 3529 | SOME 1 => [(y, DstIR.VAR x)]
95 :     | SOME ~1 => let
96 :     val t = DstIR.Var.new("one", DstTy.realTy)
97 :     in [
98 : jhr 3534 (t, DstIR.LIT(Literal.Real(RealLit.one))),
99 : jhr 3529 (* FIXME: shouldn't be IDiv; should be real division! *)
100 : jhr 3548 (y, DstIR.OP(DstOp.IDiv, [t, x]))
101 : jhr 3529 ] end
102 :     (* FIXME: shouldn't be IMul; should be real multiplication! *)
103 : jhr 3548 | SOME 2 => [(y, DstIR.OP(DstOp.IMul, [x, x]))]
104 : jhr 3529 (* FIXME: expand into multiplications
105 :     | SOME n =>
106 :     *) | SOME _ => pow()
107 :     | NONE => pow()
108 :     (* end case *)
109 :     end
110 :    
111 :     (* expand the field Inside operator into a image-space test *)
112 :     fun expandInside (env, result, pos, fld) = (case getRHS fld
113 : jhr 3534 of SrcIR.EINAPP(_, [img, h]) => (case (getRHSImage img, getRHSOp h)
114 :     of ((v, _), (SrcOp.Kernel(h, _), _)) => let
115 : jhr 3529 val pos = Env.rename (env, pos)
116 :     val img = Env.rename (env, img)
117 :     val s = Kernel.support h
118 : jhr 3582 val (_, x, code) = CoordSpaceTransform.worldToImage{info = v, img = img, pos = pos}
119 : jhr 3529 in
120 :     code @ [(result, DstIR.OP(DstOp.Inside(v, s), [x, img]))]
121 :     end
122 :     | _ => raise Fail "bogus kernel binding"
123 :     (* end case *))
124 :     | _ => raise Fail "bogus field binding"
125 :     (* end case *))
126 :    
127 :     fun arity (SrcTy.TensorTy[]) = 1
128 :     | arity (SrcTy.TensorTy[d]) = d
129 :     | arity _ = raise Fail "arity"
130 :    
131 :     fun expandOp (env, y, rator, args) = let
132 :     fun assign rator' =
133 :     [(y, DstIR.OP(rator', Env.renameList(env, args)))]
134 :     fun cvtToInt rator' = let
135 :     val t = DstIR.Var.new ("t", DstTy.realTy)
136 :     in [
137 :     (t, DstIR.OP(rator', Env.renameList(env, args))),
138 :     (y, DstIR.OP(DstOp.RealToInt 1, [t]))
139 :     ] end
140 :     fun dummy () = [(y, DstIR.LIT(Literal.Int 0))]
141 : jhr 3582 fun copy () = let val [x] = args
142 :     in
143 :     [(y, DstIR.VAR(Env.rename(env, x)))]
144 :     end
145 : jhr 3529 in
146 :     case rator
147 : jhr 3582 of SrcOp.IAdd => assign DstOp.IAdd
148 :     | SrcOp.ISub => assign DstOp.ISub
149 :     | SrcOp.IMul => assign DstOp.IMul
150 :     | SrcOp.IDiv => assign DstOp.IDiv
151 :     | SrcOp.IMod => assign DstOp.IMod
152 :     | SrcOp.INeg => assign DstOp.INeg
153 : jhr 3529 | SrcOp.LT ty => assign (DstOp.LT(cvtTy ty))
154 :     | SrcOp.LTE ty => assign (DstOp.LTE(cvtTy ty))
155 :     | SrcOp.EQ ty => assign (DstOp.EQ(cvtTy ty))
156 :     | SrcOp.NEQ ty => assign (DstOp.NEQ(cvtTy ty))
157 :     | SrcOp.GT ty => assign (DstOp.GT(cvtTy ty))
158 :     | SrcOp.GTE ty => assign (DstOp.GTE(cvtTy ty))
159 :     | SrcOp.Power => expandPower(env, y, args)
160 :     | SrcOp.Not => assign DstOp.Not
161 : jhr 3534 | SrcOp.Abs ty => assign (DstOp.Abs(cvtTy ty))
162 :     | SrcOp.Max ty => assign (DstOp.Max(cvtTy ty))
163 :     | SrcOp.Min ty => assign (DstOp.Min(cvtTy ty))
164 : jhr 3529 | SrcOp.Clamp ty => assign (DstOp.Clamp(cvtTy ty))
165 :     | SrcOp.Lerp ty => assign (DstOp.Lerp(cvtTy ty))
166 :     | SrcOp.PrincipleEvec ty => assign (DstOp.PrincipleEvec(cvtTy ty))
167 :     | SrcOp.Zero ty => assign (DstOp.Zero(cvtTy ty))
168 : jhr 3534 | SrcOp.TensorSlice(SrcTy.TensorTy argTy, mask) => let
169 : jhr 3529 val args' = let
170 : jhr 3534 fun f x = let
171 :     val SrcIR.LIT(Literal.Int i) = getRHS x
172 : jhr 3529 in
173 :     IntInf.toInt i
174 :     end
175 :     in
176 :     List.map f (List.drop(args, 1))
177 :     end
178 :     val DstTy.TensorTy rstTy = DstIR.Var.ty y
179 :     val rator = MkOperators.slice (argTy, mask, args', rstTy)
180 :     val a = Env.renameList(env, args)
181 :     in
182 :     [(y, DstIR.EINAPP(rator, a))]
183 :     end
184 : jhr 3534 | SrcOp.TensorIndex(ty as SrcTy.TensorTy _) => assign (DstOp.Subscript(cvtTy ty))
185 : jhr 3529 | SrcOp.Select(ty as SrcTy.SeqTy _, i) => assign (DstOp.Index(cvtTy ty, i))
186 : jhr 3534 | SrcOp.Subscript(ty as SrcTy.SeqTy _) => assign (DstOp.Subscript(cvtTy ty))
187 : jhr 3582 | SrcOp.MkDynamic(ty, n) => assign (DstOp.MkDynamic(cvtTy ty, n))
188 :     | SrcOp.Append ty => assign (DstOp.Append(cvtTy ty))
189 :     | SrcOp.Prepend ty => assign (DstOp.Prepend(cvtTy ty))
190 :     | SrcOp.Concat ty => assign (DstOp.Concat(cvtTy ty))
191 :     | SrcOp.Range => assign DstOp.Range
192 :     | SrcOp.Length ty => assign (DstOp.Length(cvtTy ty))
193 :     | SrcOp.SphereQuery(ty1, ty2) => assign (DstOp.SphereQuery(cvtTy ty1, cvtTy ty2))
194 : jhr 3529 | SrcOp.IntToReal => assign DstOp.IntToReal
195 :     | SrcOp.TruncToInt => cvtToInt (DstOp.Trunc 1)
196 :     | SrcOp.RoundToInt => cvtToInt (DstOp.Round 1)
197 :     | SrcOp.CeilToInt => cvtToInt (DstOp.Ceiling 1)
198 :     | SrcOp.FloorToInt => cvtToInt (DstOp.Floor 1)
199 : jhr 3582 (* FIXME: are we going to use these? *)
200 :     | SrcOp.R_All ty => assign (DstOp.R_All(cvtTy ty))
201 :     | SrcOp.R_Exists ty => assign (DstOp.R_Exists(cvtTy ty))
202 :     | SrcOp.R_Max ty => assign (DstOp.R_Max(cvtTy ty))
203 :     | SrcOp.R_Min ty => assign (DstOp.R_Min(cvtTy ty))
204 :     | SrcOp.R_Sum ty => assign (DstOp.R_Sum(cvtTy ty))
205 :     | SrcOp.R_Product ty => assign (DstOp.R_Product(cvtTy ty))
206 :     | SrcOp.R_Mean ty => assign (DstOp.R_Mean(cvtTy ty))
207 :     | SrcOp.R_Variance ty => assign (DstOp.R_Variance(cvtTy ty))
208 : jhr 3529 | SrcOp.Kernel h => assign (DstOp.Kernel h)
209 :     | SrcOp.Inside _ => (case args
210 :     of [pos, fld] => expandInside(env, y, pos, fld)
211 :     (* end case *))
212 : jhr 3582 | SrcOp.ImageDim(info, i) => assign (DstOp.ImageDim(info, i))
213 :     | SrcOp.BorderCtlDefault info => (case args
214 :     of [x, _] => [(y, DstIR.VAR(Env.rename(env, x)))]
215 :     (* end case *))
216 :     | SrcOp.BorderCtlClamp info => copy()
217 :     | SrcOp.BorderCtlMirror info => copy()
218 :     | SrcOp.BorderCtlWrap info => copy()
219 :     | SrcOp.LoadSeq(ty, file) => assign (DstOp.LoadSeq(cvtTy ty, file))
220 :     | SrcOp.LoadImage(ty, file) => assign (DstOp.LoadImage(cvtTy ty, file))
221 : jhr 3529 | rator => raise Fail("bogus operator " ^ SrcOp.toString rator)
222 :     (* end case *)
223 :     end
224 :     handle ex => (print(concat["error converting ", SrcOp.toString rator, "\n"]); raise ex)
225 :    
226 :     (* expandEINAPP: env* midil.var*EIN*mid-ilvar->DstIR.ASSGN list
227 :     * Field operators are changed to zero
228 :     *)
229 :     fun expandEINAPP (env, srcy, y, rator, args) = (case SrcIR.Var.ty srcy
230 :     of SrcTy.FieldTy => [DstIR.ASSGN(y, DstIR.LIT(Literal.Int 0))]
231 :     | _ => if (useCount srcy > 0)
232 : jhr 3550 then HandleEin.expand (y, rator, Env.renameList(env, args))
233 : jhr 3529 else []
234 :     (* end case *))
235 :     handle ex => (print(concat["error converting: ", MidIR.Var.toString y, " = ",
236 :     EinPP.toString rator, " ", "(", String.concatWithMap ", " HighIR.Var.toString args, ")\n"]);
237 :     raise ex)
238 :    
239 :     (* expand a SrcIR assignment to a list of DstIR assignments *)
240 :     fun expand (env, (y, rhs)) = let
241 :     fun assign rhs = [DstIR.ASSGN(Env.rename (env, y), rhs)]
242 :     in
243 :     case rhs
244 :     of SrcIR.GLOBAL x => assign (DstIR.GLOBAL(Env.renameGV(env, x)))
245 :     | SrcIR.STATE x => assign (DstIR.STATE(Env.renameSV(env, x)))
246 :     | SrcIR.VAR x => assign (DstIR.VAR(Env.rename(env, x)))
247 :     | SrcIR.LIT lit => assign (DstIR.LIT lit)
248 :     | SrcIR.OP(rator, args) =>
249 :     List.map DstIR.ASSGN (expandOp (env, Env.rename (env, y), rator, args))
250 : jhr 3534 | SrcIR.CONS(args, ty) => assign (DstIR.CONS(Env.renameList(env, args), cvtTy ty))
251 :     | SrcIR.SEQ(args, ty) => assign (DstIR.SEQ(Env.renameList(env, args), cvtTy ty))
252 : jhr 3529 | SrcIR.EINAPP(rator, args) =>
253 :     expandEINAPP (env, y, Env.rename (env, y), rator, args)
254 :     (* end case *)
255 :     end
256 :    
257 :     (* expand a SrcIR multi-assignment to a DstIR CFG *)
258 :     fun mexpand (env, (ys, rator, xs)) = let
259 :     val ys' = Env.renameList(env, ys)
260 :     val rator' = (case rator
261 :     of SrcOp.Eigen2x2 => DstOp.EigenVecs2x2
262 :     | SrcOp.Eigen3x3 => DstOp.EigenVecs3x3
263 :     | SrcOp.Print tys => DstOp.Print(List.map cvtTy tys)
264 :     | _ => raise Fail("bogus operator " ^ SrcOp.toString rator)
265 :     (* end case *))
266 :     val xs' = Env.renameList(env, xs)
267 :     val nd = DstIR.Node.mkMASSIGN(ys', rator', xs')
268 :     in
269 :     DstIR.CFG{entry=nd, exit=nd}
270 :     end
271 :    
272 :     structure Trans = TranslateFn (
273 :     struct
274 :     open Env
275 :     val expand = DstIR.CFG.mkBlock o expand
276 :     val mexpand = mexpand
277 :     end)
278 :    
279 : jhr 3615 structure Promote = PromoteFn (DstIR)
280 :    
281 : jhr 3529 fun translate prog = let
282 :     (* need a prepass to add Inside tests for border control *)
283 :     val prog = Trans.translate prog
284 :     in
285 : jhr 3534 MidCensus.init prog;
286 : jhr 3615 Promote.transform prog
287 : jhr 3529 end
288 :    
289 :     end

root@smlnj-gforge.cs.uchicago.edu
ViewVC Help
Powered by ViewVC 1.0.0