Home My Page Projects Code Snippets Project Openings SML/NJ
Summary Activity Forums Tracker Lists Tasks Docs Surveys News SCM Files

SCM Repository

[smlnj] Annotation of /sml/trunk/src/compiler/DebugProf/profile/btrace.sml
ViewVC logotype

Annotation of /sml/trunk/src/compiler/DebugProf/profile/btrace.sml

Parent Directory Parent Directory | Revision Log Revision Log


Revision 904 - (view) (download)

1 : blume 903 (*
2 :     * Perform Absyn annotations for back-tracing support.
3 :     * This adds a bt_add at the entry point of each FNexp,
4 :     * a push-restore sequence (bt_push) at each non-tail call site of
5 :     * a non-primitive function, and a save-restore sequence to each HANDLEexp.
6 :     *
7 :     * Copyright (c) 2000 by Lucent Bell Laboratories
8 :     *
9 :     * author: Matthias Blume (blume@kurims.kyoto-u.ac.jp)
10 :     *)
11 :     local
12 :     structure A = Absyn
13 :     structure SE = StaticEnv
14 :     structure SP = SymPath
15 :     structure EM = ErrorMsg
16 :     structure VC = VarCon
17 :     structure BT = CoreBasicTypes
18 :     structure AU = AbsynUtil
19 :    
20 :     structure Dummy = BTImp (* mention it, so it gets made! *)
21 :     in
22 :    
23 :     signature BTRACE = sig
24 :     val instrument :
25 :     (Symbol.symbol -> bool) -> (* isSpecial *)
26 :     SE.staticEnv * A.dec CompInfo.compInfo -> A.dec -> A.dec
27 :     end
28 :    
29 :     structure BTrace :> BTRACE = struct
30 :    
31 :     fun impossible s = EM.impossible ("BTrace: " ^ s)
32 :    
33 :     infix -->
34 :     val op --> = BT.-->
35 :    
36 :     val i_i_Ty = BT.intTy --> BT.intTy
37 :     val ii_u_Ty = BT.tupleTy [BT.intTy, BT.intTy] --> BT.unitTy
38 :     val ii_u_u_Ty = ii_u_Ty --> BT.unitTy
39 :     val u_u_Ty = BT.unitTy --> BT.unitTy
40 :     val u_u_u_Ty = BT.unitTy --> u_u_Ty
41 :     val iis_u_Ty = BT.tupleTy [BT.intTy, BT.intTy, BT.unitTy] --> BT.unitTy
42 :    
43 :     fun instrument0 isSpecial (senv, cinfo: A.dec CompInfo.compInfo) d = let
44 :    
45 :     val matchstring = #errorMatch cinfo
46 :    
47 :     val mkv = #mkLvar cinfo
48 :    
49 :     fun tmpvar (n, t) = let
50 :     val sy = Symbol.varSymbol n
51 :     in
52 :     VC.VALvar { access = Access.namedAcc (sy, mkv), info = II.Null,
53 :     path = SP.SPATH [sy], typ = ref t }
54 :     end
55 :    
56 :     (*
57 :     val isSpecial = let
58 :     val l = [SpecialSymbols.paramId,
59 :     SpecialSymbols.functorId,
60 :     SpecialSymbols.hiddenId,
61 :     SpecialSymbols.tempStrId,
62 :     SpecialSymbols.tempFctId,
63 :     SpecialSymbols.fctbodyId,
64 :     SpecialSymbols.anonfsigId,
65 :     SpecialSymbols.resultId,
66 :     SpecialSymbols.returnId,
67 :     SpecialSymbols.internalVarId]
68 :     in
69 :     fn s => List.exists (fn s' => Symbol.eq (s, s')) l
70 :     end
71 :     *)
72 :    
73 :     fun cons (s, []) = if isSpecial s then [] else [(s, 0)]
74 :     | cons (s, l as ((s', m) :: t)) =
75 :     if isSpecial s then l
76 :     else if Symbol.eq (s, s') then (s, m+1) :: t
77 :     else (s, 0) :: l
78 :    
79 : blume 904 fun getCoreVal s = CoreAccess.getVar (senv, s)
80 :     fun getCoreCon s = CoreAccess.getCon (senv, s)
81 : blume 903
82 :     val bt_reserve = getCoreVal "bt_reserve"
83 :     val bt_register = getCoreVal "bt_register"
84 :     val bt_save = getCoreVal "bt_save"
85 :     val bt_push = getCoreVal "bt_push"
86 :     val bt_nopush = getCoreVal "bt_nopush"
87 :     val bt_add = getCoreVal "bt_add"
88 :     val matchcon = getCoreCon "Match"
89 :    
90 :     val bt_register_var = tmpvar ("<bt_register>", iis_u_Ty)
91 :     val bt_save_var = tmpvar ("<bt_save>", u_u_u_Ty)
92 :     val bt_push_var = tmpvar ("<bt_push>", ii_u_u_Ty)
93 :     val bt_nopush_var = tmpvar ("<bt_nopush>", ii_u_Ty)
94 :     val bt_add_var = tmpvar ("<bt_add>", ii_u_Ty)
95 :     val bt_reserve_var = tmpvar ("<bt_reserve>", i_i_Ty)
96 :     val bt_module_var = tmpvar ("<bt_module>", BT.intTy)
97 :    
98 :     fun VARexp v = A.VARexp (ref v, [])
99 :     fun INTexp i = A.INTexp (IntInf.fromInt i, BT.intTy)
100 :    
101 :     val uExp = AU.unitExp
102 :     val pushexp = A.APPexp (VARexp bt_push_var, uExp)
103 :     val saveexp = A.APPexp (VARexp bt_save_var, uExp)
104 :    
105 :     fun mkmodidexp fctvar id =
106 :     A.APPexp (VARexp fctvar,
107 :     AU.TUPLEexp [VARexp bt_module_var, INTexp id])
108 :    
109 :     val mkaddexp = mkmodidexp bt_add_var
110 :     val mkpushexp = mkmodidexp bt_push_var
111 :     val mknopushexp = mkmodidexp bt_nopush_var
112 :    
113 :     fun mkregexp (id, s) =
114 :     A.APPexp (VARexp bt_register_var,
115 :     AU.TUPLEexp [VARexp bt_module_var,
116 :     INTexp id, A.STRINGexp s])
117 :    
118 :     val regexps = ref []
119 :     val next = ref 0
120 :    
121 :     fun newid s = let
122 :     val id = !next
123 :     in
124 :     next := id + 1;
125 :     regexps := mkregexp (id, s) :: !regexps;
126 :     id
127 :     end
128 :    
129 :     val mkadd = mkaddexp o newid
130 :     val mkpush = mkpushexp o newid
131 :     val mknopush = mknopushexp o newid
132 :    
133 :     fun VALdec (v, e) =
134 :     A.VALdec [A.VB { pat = A.VARpat v, exp = e,
135 :     tyvars = ref [], boundtvs = [] }]
136 :     fun LETexp (v, e, b) = A.LETexp (VALdec (v, e), b)
137 :     fun AUexp v = A.APPexp (VARexp v, uExp) (* apply to unit *)
138 :    
139 :     fun is_prim_exp (A.VARexp (ref (VC.VALvar v), _)) =
140 :     II.isSimple (#info v)
141 :     | is_prim_exp (A.CONexp _) = true
142 :     | is_prim_exp (A.CONSTRAINTexp (e, _)) = is_prim_exp e
143 :     | is_prim_exp (A.MARKexp (e, _)) = is_prim_exp e
144 :     | is_prim_exp _ = false
145 :    
146 :     fun is_raise_exp (A.RAISEexp (e, _)) =
147 :     let fun is_simple_exn (A.VARexp _) = true
148 :     | is_simple_exn (A.CONexp _) = true
149 :     | is_simple_exn (A.CONSTRAINTexp (e, _)) = is_simple_exn e
150 :     | is_simple_exn (A.MARKexp (e, _)) = is_simple_exn e
151 :     | is_simple_exn (A.RAISEexp (e, _)) =
152 :     is_simple_exn e (* !! *)
153 :     | is_simple_exn _ = false
154 :     in
155 :     is_simple_exn e
156 :     end
157 :     | is_raise_exp (A.MARKexp (e, _) |
158 :     A.CONSTRAINTexp (e, _) |
159 :     A.SEQexp [e]) = is_raise_exp e
160 :     | is_raise_exp _ = false
161 :    
162 :     fun mkDescr ((n, r), what) = let
163 :     fun name ((s, 0), a) = Symbol.name s :: a
164 :     | name ((s, m), a) = Symbol.name s :: "[" ::
165 :     Int.toString (m + 1) :: "]" :: a
166 :     fun dot ([z], a) = name (z, a)
167 :     | dot (h :: t, a) = dot (t, "." :: name (h, a))
168 :     | dot ([], a) = impossible (what ^ ": no path")
169 :     val ms = matchstring r
170 :     in
171 :     concat (ms :: ": " :: dot (n, []))
172 :     end
173 :    
174 :     fun i_exp _ loc (A.RECORDexp l) =
175 :     A.RECORDexp (map (fn (l, e) => (l, i_exp false loc e)) l)
176 :     | i_exp _ loc (A.SELECTexp (l, e)) =
177 :     A.SELECTexp (l, i_exp false loc e)
178 :     | i_exp _ loc (A.VECTORexp (l, t)) =
179 :     A.VECTORexp (map (i_exp false loc) l, t)
180 :     | i_exp tail loc (A.PACKexp (e, t, tcl)) =
181 :     A.PACKexp (i_exp tail loc e, t, tcl)
182 :     | i_exp tail loc (e as A.APPexp (f, a)) = let
183 :     val mainexp = A.APPexp (i_exp false loc f, i_exp false loc a)
184 :     in
185 :     if is_prim_exp f then mainexp
186 :     else if tail then A.SEQexp [mknopush (mkDescr (loc, "GOTO")),
187 :     mainexp]
188 :     else let
189 :     val ty = Reconstruct.expType e
190 :     val result = tmpvar ("tmpresult", ty)
191 :     val restore = tmpvar ("tmprestore", u_u_Ty)
192 :     val pushexp = mkpush (mkDescr (loc, "CALL"))
193 :     in
194 :     LETexp (restore, pushexp,
195 :     LETexp (result, mainexp,
196 :     A.SEQexp [AUexp restore,
197 :     VARexp result]))
198 :     end
199 :     end
200 :     | i_exp tail loc (A.HANDLEexp (e, A.HANDLER (A.FNexp (rl, t)))) = let
201 :     val restore = tmpvar ("tmprestore", u_u_Ty)
202 :     fun rule (r as A.RULE (p, e)) =
203 :     if is_raise_exp e then r
204 :     else A.RULE (p, A.SEQexp [AUexp restore, i_exp tail loc e])
205 :     in
206 :     LETexp (restore, saveexp,
207 :     A.HANDLEexp (i_exp false loc e,
208 :     A.HANDLER (A.FNexp (map rule rl, t))))
209 :     end
210 :     | i_exp _ _ (A.HANDLEexp _) = impossible "bad HANDLEexp"
211 :     | i_exp _ loc (A.RAISEexp (e, t)) =
212 :     A.RAISEexp (i_exp false loc e, t)
213 :     | i_exp tail loc (A.CASEexp (e, rl, b)) =
214 :     A.CASEexp (i_exp false loc e, map (i_rule tail loc) rl, b)
215 :     | i_exp tail loc (A.FNexp (rl, t)) = let
216 :     val addexp = mkadd (mkDescr (loc, "FN"))
217 :     val arg = tmpvar ("fnvar", t)
218 :     val rl' = map (i_rule true loc) rl
219 :     val re = let
220 :     val A.RULE (_, lst) = List.last rl
221 :     val t = Reconstruct.expType lst
222 :     in
223 :     A.RAISEexp (A.CONexp (matchcon, []), t)
224 :     end
225 :     in
226 :     A.FNexp ([A.RULE (A.VARpat arg,
227 :     A.SEQexp [addexp,
228 :     A.CASEexp (A.VARexp (ref arg, []),
229 :     rl', true)]),
230 :     A.RULE (A.WILDpat, re)],
231 :     t)
232 :     end
233 :     | i_exp tail loc (A.LETexp (d, e)) =
234 :     A.LETexp (i_dec loc d, i_exp tail loc e)
235 :     | i_exp tail loc (A.SEQexp l) =
236 :     A.SEQexp (#1 (foldr (fn (e, (l, t)) => (i_exp t loc e :: l, false))
237 :     ([], tail) l))
238 :     | i_exp tail loc (A.CONSTRAINTexp (e, t)) =
239 :     A.CONSTRAINTexp (i_exp tail loc e, t)
240 :     | i_exp tail (n, _) (A.MARKexp (e, r)) =
241 :     A.MARKexp (i_exp tail (n, r) e, r)
242 :     | i_exp _ _ e = e
243 :    
244 :     and i_dec loc (A.VALdec l) = A.VALdec (map (i_vb loc) l)
245 :     | i_dec loc (A.VALRECdec l) = A.VALRECdec (map (i_rvb loc) l)
246 :     | i_dec loc (A.ABSTYPEdec { abstycs, withtycs, body }) =
247 :     A.ABSTYPEdec { abstycs = abstycs, withtycs = withtycs,
248 :     body = i_dec loc body }
249 :     | i_dec loc (A.EXCEPTIONdec l) = A.EXCEPTIONdec (map (i_eb loc) l)
250 :     | i_dec loc (A.STRdec l) = A.STRdec (map (i_strb loc) l)
251 :     | i_dec loc (A.ABSdec l) = A.ABSdec (map (i_strb loc) l)
252 :     | i_dec loc (A.FCTdec l) = A.FCTdec (map (i_fctb loc) l)
253 :     | i_dec loc (A.LOCALdec (d, d')) =
254 :     A.LOCALdec (i_dec loc d, i_dec loc d')
255 :     | i_dec loc (A.SEQdec l) = A.SEQdec (map (i_dec loc) l)
256 :     | i_dec (n, _) (A.MARKdec (d, r)) = A.MARKdec (i_dec (n, r) d, r)
257 :     | i_dec _ d = d
258 :    
259 :     and i_rule tail loc (A.RULE (p, e)) = A.RULE (p, i_exp tail loc e)
260 :    
261 :     and i_vb (n, r) (vb as A.VB { pat, exp, boundtvs, tyvars }) = let
262 :     fun gv (A.VARpat v) = SOME v
263 :     | gv (A.CONSTRAINTpat (p, _)) = gv p
264 :     | gv (A.LAYEREDpat (p, p')) =
265 :     (case gv p of
266 :     SOME v => SOME v
267 :     | NONE => gv p')
268 :     | gv _ = NONE
269 :     fun recur n = A.VB { pat = pat, exp = i_exp false (n, r) exp,
270 :     boundtvs = boundtvs, tyvars = tyvars }
271 :     in
272 :     case gv pat of
273 :     SOME (VC.VALvar { path = SP.SPATH [x], info, ... }) =>
274 :     if II.isSimple info then vb
275 :     else recur (cons (x, n))
276 :     | SOME (VC.VALvar { info, ... }) =>
277 :     if II.isSimple info then vb else recur n
278 :     | _ => recur n
279 :     end
280 :    
281 :     and i_rvb (n, r) (A.RVB { var, exp, boundtvs, resultty, tyvars }) = let
282 :     val x =
283 :     case var of
284 :     VC.VALvar { path = SymPath.SPATH [x], ... } => x
285 :     | _ => impossible "VALRECdec"
286 :     in
287 :     A.RVB { var = var, exp = i_exp false (cons (x, n), r) exp,
288 :     boundtvs = boundtvs, resultty = resultty, tyvars = tyvars }
289 :     end
290 :    
291 :     and i_eb loc (A.EBgen { exn, etype, ident }) =
292 :     A.EBgen { exn = exn, etype = etype, ident = i_exp false loc ident }
293 :     | i_eb _ eb = eb
294 :    
295 :     and i_strb (n, r) (A.STRB { name, str, def }) =
296 :     A.STRB { name = name, str = str,
297 :     def = i_strexp (cons (name, n), r) def }
298 :    
299 :     and i_fctb (n, r) (A.FCTB { name, fct, def }) =
300 :     A.FCTB { name = name, fct = fct,
301 :     def = i_fctexp (cons (name, n), r) def }
302 :    
303 :     and i_strexp loc (A.LETstr (d, s)) =
304 :     A.LETstr (i_dec loc d, i_strexp loc s)
305 :     | i_strexp (n, _) (A.MARKstr (s, r)) =
306 :     A.MARKstr (i_strexp (n, r) s, r)
307 :     | i_strexp _ s = s
308 :    
309 :     and i_fctexp loc (A.FCTfct { param, argtycs, def }) =
310 :     A.FCTfct { param = param, argtycs = argtycs,
311 :     def = i_strexp loc def }
312 :     | i_fctexp loc (A.LETfct (d, f)) =
313 :     A.LETfct (i_dec loc d, i_fctexp loc f)
314 :     | i_fctexp (n, _) (A.MARKfct (f, r)) =
315 :     A.MARKfct (i_fctexp (n, r) f, r)
316 :     | i_fctexp _ f = f
317 :    
318 :     val d' = i_dec ([], (0, 0)) d
319 :     in
320 :     A.LOCALdec (A.SEQdec [VALdec (bt_reserve_var, AUexp bt_reserve),
321 :     VALdec (bt_module_var,
322 :     A.APPexp (VARexp bt_reserve_var,
323 :     INTexp (!next))),
324 :     VALdec (bt_save_var, AUexp bt_save),
325 :     VALdec (bt_push_var, AUexp bt_push),
326 :     VALdec (bt_nopush_var, AUexp bt_nopush),
327 :     VALdec (bt_register_var, AUexp bt_register),
328 :     VALdec (bt_add_var,
329 :     A.SEQexp (!regexps @ [AUexp bt_add]))],
330 :     d')
331 :     end
332 :    
333 :     fun instrument isSpecial params d =
334 :     if SMLofNJ.Internals.BTrace.mode NONE then
335 :     instrument0 isSpecial params d
336 :     handle NoCore => d (* this takes care of core.sml *)
337 :     else d
338 :     end
339 :    
340 :     end (* local *)

root@smlnj-gforge.cs.uchicago.edu
ViewVC Help
Powered by ViewVC 1.0.0