Home My Page Projects Code Snippets Project Openings diderot
Summary Activity Tracker Tasks SCM

SCM Repository

[diderot] Annotation of /trunk/src/compiler/IL/ssa-fn.sml
ViewVC logotype

Annotation of /trunk/src/compiler/IL/ssa-fn.sml

Parent Directory Parent Directory | Revision Log Revision Log


Revision 364 - (view) (download)

1 : jhr 137 (* ssa-fn.sml
2 : jhr 124 *
3 :     * COPYRIGHT (c) 2010 The Diderot Project (http://diderot.cs.uchicago.edu)
4 :     * All rights reserved.
5 : jhr 137 *
6 :     * The IL is a combination of a block-structured tree and an SSA control-flow
7 :     * graph of blocks.
8 : jhr 124 *)
9 :    
10 : jhr 198 signature SSA =
11 :     sig
12 :    
13 :     structure Op : OPERATORS
14 :    
15 : jhr 256 (***** CFG *****)
16 : jhr 198
17 : jhr 256 datatype node = ND of {
18 :     id : Stamp.stamp,
19 :     props : PropList.holder,
20 :     kind : node_kind
21 : jhr 198 }
22 :    
23 : jhr 256 and node_kind
24 :     = NULL
25 :     | ENTRY of {
26 :     succ : node ref
27 :     }
28 :     | JOIN of {
29 :     preds : node list ref,
30 :     phis : (var * var list) list ref, (* phi statements *)
31 :     succ : node ref
32 :     }
33 :     | COND of {
34 :     pred : node ref,
35 :     cond : var,
36 :     trueBranch : node ref,
37 :     falseBranch : node ref
38 :     }
39 :     | BLOCK of {
40 :     pred : node ref,
41 :     body : assign list ref,
42 :     succ : node ref
43 :     }
44 :     | NEW of {
45 :     pred : node ref,
46 :     actor : Atom.atom,
47 :     args : var list,
48 :     succ : node ref
49 :     }
50 :     | DIE of {
51 :     pred : node ref
52 :     }
53 :     | STABILIZE of {
54 :     pred : node ref
55 :     }
56 :     | EXIT of {
57 :     pred : node ref
58 :     }
59 : jhr 198
60 : jhr 256 (***** Statements *****)
61 :    
62 : jhr 198 and stmt = STM of {
63 :     id : Stamp.stamp,
64 :     props : PropList.holder,
65 : jhr 256 kind : stmt_kind,
66 :     next : stmt option (* next statement at this structural level *)
67 : jhr 198 }
68 :    
69 :     and stmt_kind
70 : jhr 256 = S_SIMPLE of node (* ENTRY, JOIN, BLOCK, NEW, DIE, STABILIZE, or EXIT node *)
71 :     | S_IF of {
72 :     cond : node, (* COND node *)
73 : jhr 198 thenBranch : stmt,
74 :     elseBranch : stmt
75 :     }
76 : jhr 256 | S_LOOP of {
77 : jhr 198 hdr : stmt,
78 : jhr 256 cond : node, (* COND node *)
79 :     body : stmt
80 : jhr 198 }
81 :    
82 :     and rhs
83 :     = VAR of var
84 :     | LIT of Literal.literal
85 :     | OP of Op.rator * var list
86 :     | CONS of var list (* tensor-value construction *)
87 :    
88 :     and var = V of {
89 :     name : string, (* name *)
90 :     id : Stamp.stamp, (* unique ID *)
91 :     useCnt : int ref, (* count of uses *)
92 :     props : PropList.holder
93 :     }
94 :    
95 :     withtype assign = (var * rhs)
96 :    
97 : jhr 256 datatype program = Program of {
98 :     globals : var list,
99 :     globalInit : stmt,
100 :     actors : actor list
101 :     (* initialization *)
102 :     }
103 : jhr 198
104 : jhr 256 and actor = Actor of {
105 :     name : Atom.atom,
106 :     params : var list,
107 :     state : var list,
108 :     stateInit : stmt,
109 :     methods : method list
110 :     }
111 : jhr 198
112 : jhr 256 and method = Method of {
113 :     name : Atom.atom,
114 :     stateIn : var list, (* names of state variables on method entry *)
115 :     stateOut : var list, (* names of state variables on method exit *)
116 :     body : stmt (* method body *)
117 :     }
118 : jhr 198
119 : jhr 256 structure Node : sig
120 :     val same : node * node -> bool
121 :     val compare : node * node -> order
122 :     val hash : node -> word
123 :     val toString : node -> string
124 : jhr 360 (* dummy node *)
125 :     val dummy : node
126 : jhr 359 (* CFG edges *)
127 : jhr 256 val preds : node -> node list
128 :     val setPred : node * node -> unit
129 :     val hasSucc : node -> bool
130 :     val succs : node -> node list
131 :     val setSucc : node * node -> unit
132 :     val setTrueBranch : node * node -> unit (* set trueBranch successor for COND node *)
133 :     val setFalseBranch : node * node -> unit (* set falseBranch successor for COND node *)
134 :     val addEdge : node * node -> unit
135 : jhr 359 (* constructors *)
136 :     val mkENTRY : unit -> node
137 :     val mkJOIN : (var * var list) list -> node
138 :     val mkCOND : {cond : var, trueBranch : node, falseBranch : node} -> node
139 :     val mkBLOCK : assign list -> node
140 : jhr 360 val mkNEW : {actor : Atom.atom, args : var list} -> node
141 : jhr 359 val mkDIE : unit -> node
142 :     val mkSTABILIZE : unit -> node
143 :     val mkEXIT : unit -> node
144 : jhr 283 (* properties *)
145 :     val newProp : (node -> 'a) -> {
146 :     getFn : node -> 'a,
147 :     peekFn : node -> 'a option,
148 :     setFn : node * 'a -> unit,
149 :     clrFn : node -> unit
150 :     }
151 :     val newFlag : unit -> {
152 :     getFn : node -> bool,
153 :     setFn : node * bool -> unit
154 :     }
155 : jhr 256 end
156 : jhr 198
157 : jhr 256 structure Stmt : sig
158 :     val same : stmt * stmt -> bool
159 :     val compare : stmt * stmt -> order
160 :     val hash : stmt -> word
161 :     val toString : stmt -> string
162 :     (* return the entry node of the statement *)
163 :     val entry : stmt -> node
164 :     (* return the tail-end node of a statement (not applicable to S_IF or S_LOOP) *)
165 :     val tail : stmt -> node
166 :     (* statement constructor functions *)
167 : jhr 361 val new : (stmt_kind * stmt option) -> stmt
168 : jhr 256 val mkENTRY : stmt option -> stmt
169 :     val mkJOIN : (var * var list) list * stmt option -> stmt
170 :     val mkIF : var * stmt * stmt * stmt option -> stmt
171 :     val mkBLOCK : assign list * stmt option -> stmt
172 :     val mkNEW : Atom.atom * var list * stmt option -> stmt
173 :     val mkDIE : unit -> stmt
174 :     val mkSTABILIZE : unit -> stmt
175 :     val mkEXIT : unit -> stmt
176 : jhr 283 (* properties *)
177 :     val newProp : (stmt -> 'a) -> {
178 :     getFn : stmt -> 'a,
179 :     peekFn : stmt -> 'a option,
180 :     setFn : stmt * 'a -> unit,
181 :     clrFn : stmt -> unit
182 :     }
183 :     val newFlag : unit -> {
184 :     getFn : stmt -> bool,
185 :     setFn : stmt * bool -> unit
186 :     }
187 : jhr 256 end
188 : jhr 198
189 : jhr 199 structure Var : sig
190 :     val new : string -> var
191 : jhr 364 val name : var -> string
192 : jhr 199 val same : var * var -> bool
193 :     val compare : var * var -> order
194 :     val hash : var -> word
195 :     val toString : var -> string
196 : jhr 283 (* properties *)
197 :     val newProp : (var -> 'a) -> {
198 :     getFn : var -> 'a,
199 :     peekFn : var -> 'a option,
200 :     setFn : var * 'a -> unit,
201 :     clrFn : var -> unit
202 :     }
203 :     val newFlag : unit -> {
204 :     getFn : var -> bool,
205 :     setFn : var * bool -> unit
206 :     }
207 :     (* collections *)
208 : jhr 199 structure Map : ORD_MAP where type Key.ord_key = var
209 :     structure Set : ORD_SET where type Key.ord_key = var
210 :     structure Tbl : MONO_HASH_TABLE where type Key.hash_key = var
211 :     end
212 : jhr 198
213 : jhr 319 (* DFS sorting of the graph rooted at the entry to a statement; the resulting list will
214 :     * be in preorder with parents before children.
215 :     *)
216 : jhr 257 val sortNodes : stmt -> node list
217 :    
218 : jhr 341 (* apply a function to all of the nodes in the graph rooted at the entry to the statement *)
219 :     val applyToNodes : (node -> unit) -> stmt -> unit
220 :    
221 : jhr 198 end
222 :    
223 :     functor SSAFn (Op : OPERATORS) : SSA =
224 : jhr 192 struct
225 : jhr 137
226 : jhr 192 structure Op = Op
227 : jhr 137
228 : jhr 256 datatype node = ND of {
229 :     id : Stamp.stamp,
230 :     props : PropList.holder,
231 :     kind : node_kind
232 : jhr 197 }
233 :    
234 : jhr 256 and node_kind
235 :     = NULL
236 :     | ENTRY of {
237 :     succ : node ref
238 :     }
239 :     | JOIN of {
240 :     preds : node list ref,
241 :     phis : (var * var list) list ref, (* phi statements *)
242 :     succ : node ref
243 :     }
244 :     | COND of {
245 :     pred : node ref,
246 :     cond : var,
247 :     trueBranch : node ref,
248 :     falseBranch : node ref
249 :     }
250 :     | BLOCK of {
251 :     pred : node ref,
252 :     body : assign list ref,
253 :     succ : node ref
254 :     }
255 :     | NEW of {
256 :     pred : node ref,
257 :     actor : Atom.atom,
258 :     args : var list,
259 :     succ : node ref
260 :     }
261 :     | DIE of {
262 :     pred : node ref
263 :     }
264 :     | STABILIZE of {
265 :     pred : node ref
266 :     }
267 :     | EXIT of {
268 :     pred : node ref
269 :     }
270 : jhr 197
271 : jhr 256 (***** Statements *****)
272 : jhr 197
273 :     and stmt = STM of {
274 : jhr 188 id : Stamp.stamp,
275 :     props : PropList.holder,
276 : jhr 256 kind : stmt_kind,
277 :     next : stmt option (* next statement at this structural level *)
278 : jhr 188 }
279 :    
280 : jhr 192 and stmt_kind
281 : jhr 256 = S_SIMPLE of node (* ENTRY, JOIN, BLOCK, NEW, DIE, STABILIZE, or EXIT node *)
282 :     | S_IF of {
283 :     cond : node, (* COND node *)
284 : jhr 192 thenBranch : stmt,
285 :     elseBranch : stmt
286 :     }
287 : jhr 256 | S_LOOP of {
288 : jhr 192 hdr : stmt,
289 : jhr 256 cond : node, (* COND node *)
290 :     body : stmt
291 : jhr 192 }
292 :    
293 : jhr 188 and rhs
294 :     = VAR of var
295 :     | LIT of Literal.literal
296 :     | OP of Op.rator * var list
297 :     | CONS of var list (* tensor-value construction *)
298 :    
299 : jhr 192 and var = V of {
300 : jhr 137 name : string, (* name *)
301 :     id : Stamp.stamp, (* unique ID *)
302 :     useCnt : int ref, (* count of uses *)
303 :     props : PropList.holder
304 : jhr 124 }
305 :    
306 : jhr 192 withtype assign = (var * rhs)
307 : jhr 188
308 : jhr 256 datatype program = Program of {
309 :     globals : var list,
310 :     globalInit : stmt,
311 :     actors : actor list
312 :     (* initialization *)
313 :     }
314 : jhr 188
315 : jhr 256 and actor = Actor of {
316 :     name : Atom.atom,
317 :     params : var list,
318 :     state : var list,
319 :     stateInit : stmt,
320 :     methods : method list
321 :     }
322 : jhr 188
323 : jhr 256 and method = Method of {
324 :     name : Atom.atom,
325 :     stateIn : var list, (* names of state variables on method entry *)
326 :     stateOut : var list, (* names of state variables on method exit *)
327 :     body : stmt (* method body *)
328 :     }
329 : jhr 188
330 : jhr 256 structure Node =
331 :     struct
332 :     fun same (ND{id=a, ...}, ND{id=b, ...}) = Stamp.same(a, b)
333 :     fun compare (ND{id=a, ...}, ND{id=b, ...}) = Stamp.compare(a, b)
334 :     fun hash (ND{id, ...}) = Stamp.hash id
335 :     fun toString (ND{id, kind, ...}) = let
336 :     val tag = (case kind
337 :     of NULL => "NULL"
338 :     | ENTRY _ => "ENTRY"
339 :     | JOIN _ => "JOIN"
340 :     | COND _ => "COND"
341 :     | BLOCK _ => "BLOCK"
342 :     | NEW _ => "NEW"
343 :     | DIE _ => "DIE"
344 :     | STABILIZE _ => "STABILIZE"
345 :     | EXIT _ => "EXIT"
346 :     (* end case *))
347 :     in
348 :     tag ^ Stamp.toString id
349 :     end
350 :     fun new kind = ND{id = Stamp.new(), props = PropList.newHolder(), kind = kind}
351 :     val dummy = new NULL
352 :     fun mkENTRY () = new (ENTRY{succ = ref dummy})
353 :     fun mkJOIN phis = new (JOIN{preds = ref [], phis = ref phis, succ = ref dummy})
354 :     fun mkCOND {cond, trueBranch, falseBranch} = new (COND{
355 :     pred = ref dummy, cond = cond,
356 :     trueBranch = ref trueBranch, falseBranch = ref falseBranch
357 :     })
358 :     fun mkBLOCK body = new (BLOCK{pred = ref dummy, body = ref body, succ = ref dummy})
359 :     fun mkNEW {actor, args} = new (NEW{
360 :     pred = ref dummy, actor = actor, args = args, succ = ref dummy
361 :     })
362 :     fun mkDIE () = new (DIE{pred = ref dummy})
363 :     fun mkSTABILIZE () = new (STABILIZE{pred = ref dummy})
364 :     fun mkEXIT () = new (EXIT{pred = ref dummy})
365 :     (* editing node edges *)
366 :     fun setPred (ND{kind, ...}, nd) = (case kind
367 :     of NULL => raise Fail "setPred on NULL node"
368 :     | ENTRY _ => raise Fail "setPred on ENTRY node"
369 :     | JOIN{preds, ...} => if List.exists (fn nd' => same(nd, nd')) (!preds)
370 :     then ()
371 :     else preds := nd :: !preds
372 :     | COND{pred, ...} => pred := nd
373 :     | BLOCK{pred, ...} => pred := nd
374 :     | NEW{pred, ...} => pred := nd
375 :     | DIE{pred} => pred := nd
376 :     | STABILIZE{pred} => pred := nd
377 :     | EXIT{pred} => pred := nd
378 :     (* end case *))
379 :     fun preds (ND{kind, ...}) = (case kind
380 :     of NULL => raise Fail "preds on NULL node"
381 :     | ENTRY _ => []
382 :     | JOIN{preds, ...} => !preds
383 :     | COND{pred, ...} => [!pred]
384 :     | BLOCK{pred, ...} => [!pred]
385 :     | NEW{pred, ...} => [!pred]
386 :     | DIE{pred} => [!pred]
387 :     | STABILIZE{pred} => [!pred]
388 :     | EXIT{pred} => [!pred]
389 :     (* end case *))
390 :     fun hasSucc (ND{kind, ...}) = (case kind
391 :     of NULL => false
392 :     | ENTRY{succ} => true
393 :     | JOIN{succ, ...} => true
394 :     | COND{trueBranch, falseBranch, ...} => true
395 :     | BLOCK{succ, ...} => true
396 :     | NEW{succ, ...} => true
397 :     | DIE _ => false
398 :     | STABILIZE _ => false
399 :     | EXIT _ => false
400 :     (* end case *))
401 :     fun setSucc (ND{kind, ...}, nd) = (case kind
402 :     of NULL => raise Fail "setSucc on NULL node"
403 :     | ENTRY{succ} => succ := nd
404 :     | JOIN{succ, ...} => succ := nd
405 :     | COND _ => raise Fail "setSucc on COND node"
406 :     | BLOCK{succ, ...} => succ := nd
407 :     | NEW{succ, ...} => succ := nd
408 :     | DIE _ => raise Fail "setSucc on DIE node"
409 :     | STABILIZE _ => raise Fail "setSucc on STABILIZE node"
410 :     | EXIT _ => raise Fail "setSucc on EXIT node"
411 :     (* end case *))
412 :     fun succs (ND{kind, ...}) = (case kind
413 :     of NULL => raise Fail "succs on NULL node"
414 :     | ENTRY{succ} => [!succ]
415 :     | JOIN{succ, ...} => [!succ]
416 :     | COND{trueBranch, falseBranch, ...} => [!trueBranch, !falseBranch]
417 :     | BLOCK{succ, ...} => [!succ]
418 :     | NEW{succ, ...} => [!succ]
419 :     | DIE _ => []
420 :     | STABILIZE _ => []
421 :     | EXIT _ => []
422 :     (* end case *))
423 :     fun setTrueBranch (ND{kind=COND{trueBranch, ...}, ...}, nd) = trueBranch := nd
424 :     | setTrueBranch (nd, _) = raise Fail("setTrueBranch on " ^ toString nd)
425 :     fun setFalseBranch (ND{kind=COND{falseBranch, ...}, ...}, nd) = falseBranch := nd
426 :     | setFalseBranch (nd, _) = raise Fail("setFalseBranch on " ^ toString nd)
427 :     fun addEdge (nd1, nd2) = (
428 :     if hasSucc nd1
429 :     then (
430 :     setSucc (nd1, nd2);
431 :     setPred (nd2, nd1))
432 :     else ())
433 :     (*DEBUG*)handle ex => (
434 :     print(concat["error in addEdge(", toString nd1, ",", toString nd2, ")\n"]);
435 :     raise ex)
436 : jhr 283 (* properties *)
437 :     fun newProp initFn =
438 :     PropList.newProp (fn (ND{props, ...}) => props, initFn)
439 :     fun newFlag () =
440 :     PropList.newFlag (fn (ND{props, ...}) => props)
441 : jhr 256 end
442 : jhr 124
443 : jhr 256 structure Stmt =
444 :     struct
445 :     fun same (STM{id=a, ...}, STM{id=b, ...}) = Stamp.same(a, b)
446 :     fun compare (STM{id=a, ...}, STM{id=b, ...}) = Stamp.compare(a, b)
447 :     fun hash (STM{id, ...}) = Stamp.hash id
448 :     fun toString (STM{id, kind, ...}) = let
449 :     val tag = (case kind
450 :     of S_SIMPLE(ND{kind, ...}) => (case kind
451 :     of NULL => "NULL"
452 :     | ENTRY _ => "ENTRY"
453 :     | JOIN _ => "JOIN"
454 :     | COND _ => raise Fail "unexpected S_SIMPLE with COND node"
455 :     | BLOCK _ => "BLOCK"
456 :     | NEW _ => "NEW"
457 :     | DIE _ => "DIE"
458 :     | STABILIZE _ => "STABILIZE"
459 :     | EXIT _ => "EXIT"
460 :     (* end case *))
461 :     | S_IF _ => "IF"
462 :     | S_LOOP _ => "LOOP"
463 :     (* end case *))
464 :     in
465 :     tag ^ Stamp.toString id
466 :     end
467 :     (* return the entry node of the statement *)
468 :     fun entry (STM{kind, ...}) = (case kind
469 :     of S_SIMPLE nd => nd
470 :     | S_IF{cond, ...} => cond
471 :     | S_LOOP{hdr, ...} => entry hdr
472 :     (* end case *))
473 :     (* return the tail-end node of a statement (not applicable to S_IF or S_LOOP) *)
474 :     fun tail (STM{kind, ...}) = (case kind
475 :     of S_SIMPLE nd => nd
476 :     | S_IF{cond, ...} => raise Fail "tail of IF"
477 :     | S_LOOP{hdr, ...} => raise Fail "tail of LOOP"
478 :     (* end case *))
479 :     (* statement constructor functions *)
480 :     fun new (kind, next) = STM{
481 : jhr 137 id = Stamp.new(),
482 : jhr 188 props = PropList.newHolder(),
483 : jhr 256 kind = kind,
484 :     next = next
485 : jhr 137 }
486 : jhr 256 val dummy = new (S_SIMPLE(Node.dummy), NONE)
487 :     fun mkENTRY next = new (S_SIMPLE(Node.mkENTRY ()), next)
488 :     fun mkJOIN (phis, next) = new (S_SIMPLE(Node.mkJOIN phis), next)
489 :     fun mkIF (cond, thenBranch, elseBranch, next) = let
490 :     val cond = Node.mkCOND {
491 :     cond = cond,
492 :     trueBranch = entry thenBranch,
493 :     falseBranch = entry elseBranch
494 :     }
495 :     in
496 :     Node.setPred (entry thenBranch, cond);
497 :     Node.setPred (entry elseBranch, cond);
498 :     new (S_IF{cond = cond, thenBranch = thenBranch, elseBranch = elseBranch}, next)
499 :     end
500 :     fun mkBLOCK (body, next) = new (S_SIMPLE(Node.mkBLOCK body), next)
501 :     fun mkNEW (actor, args, next) = new (S_SIMPLE(Node.mkNEW{actor=actor, args=args}), next)
502 :     fun mkDIE () = new (S_SIMPLE(Node.mkDIE ()), NONE)
503 :     fun mkSTABILIZE () = new (S_SIMPLE(Node.mkSTABILIZE ()), NONE)
504 :     fun mkEXIT () = new (S_SIMPLE(Node.mkEXIT ()), NONE)
505 : jhr 283 (* properties *)
506 :     fun newProp initFn =
507 :     PropList.newProp (fn (STM{props, ...}) => props, initFn)
508 :     fun newFlag () =
509 :     PropList.newFlag (fn (STM{props, ...}) => props)
510 : jhr 256 end
511 : jhr 137
512 : jhr 199 structure Var =
513 :     struct
514 :     fun new name = V{
515 :     name = name,
516 :     id = Stamp.new(),
517 :     useCnt = ref 0,
518 :     props = PropList.newHolder()
519 :     }
520 : jhr 364 fun name (V{name, ...}) = name
521 : jhr 199 fun same (V{id=a, ...}, V{id=b, ...}) = Stamp.same(a, b)
522 :     fun compare (V{id=a, ...}, V{id=b, ...}) = Stamp.compare(a, b)
523 :     fun hash (V{id, ...}) = Stamp.hash id
524 :     fun toString (V{name, id, ...}) = name ^ Stamp.toString id
525 : jhr 283 (* properties *)
526 :     fun newProp initFn =
527 :     PropList.newProp (fn (V{props, ...}) => props, initFn)
528 :     fun newFlag () =
529 :     PropList.newFlag (fn (V{props, ...}) => props)
530 : jhr 199 local
531 :     structure V =
532 :     struct
533 :     type ord_key = var
534 :     val compare = compare
535 :     end
536 :     in
537 :     structure Map = RedBlackMapFn (V)
538 :     structure Set = RedBlackSetFn (V)
539 :     end
540 :     structure Tbl = HashTableFn (
541 :     struct
542 :     type hash_key = var
543 :     val hashVal = hash
544 :     val sameKey = same
545 :     end)
546 :     end
547 : jhr 197
548 : jhr 319 (* DFS sorting of the graph rooted at the entry to a statement; the resulting list will
549 :     * be in preorder with parents before children.
550 :     *)
551 : jhr 257 fun sortNodes stmt = let
552 :     val {getFn, setFn} = PropList.newFlag (fn (ND{props, ...}) => props)
553 :     fun dfs (nd, l) =
554 :     if getFn nd
555 :     then l
556 :     else (
557 :     setFn (nd, true);
558 :     nd :: List.foldl dfs l (Node.succs nd))
559 : jhr 319 val nodes = dfs (Stmt.entry stmt, [])
560 : jhr 257 in
561 : jhr 319 List.app (fn nd => setFn(nd, false)) nodes;
562 :     nodes
563 : jhr 257 end
564 :    
565 : jhr 341 (* apply a function to all of the nodes in the graph rooted at the entry to the statement *)
566 :     fun applyToNodes (f : node -> unit) stmt = let
567 :     val {getFn, setFn} = PropList.newFlag (fn (ND{props, ...}) => props)
568 :     fun dfs (nd, l) =
569 :     if getFn nd
570 :     then l
571 :     else (
572 :     f nd; (* visit *)
573 :     setFn (nd, true);
574 :     nd :: List.foldl dfs l (Node.succs nd))
575 :     val nodes = dfs (Stmt.entry stmt, [])
576 :     in
577 :     List.app (fn nd => setFn(nd, false)) nodes
578 :     end
579 :    
580 : jhr 124 end

root@smlnj-gforge.cs.uchicago.edu
ViewVC Help
Powered by ViewVC 1.0.0