Home My Page Projects Code Snippets Project Openings diderot
Summary Activity Tracker Tasks SCM

SCM Repository

[diderot] Annotation of /trunk/src/compiler/c-target/c-target.sml
ViewVC logotype

Annotation of /trunk/src/compiler/c-target/c-target.sml

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1115 - (view) (download)

1 : jhr 1115 (* c-target.sml
2 :     *
3 :     * COPYRIGHT (c) 2011 The Diderot Project (http://diderot-language.cs.uchicago.edu)
4 :     * All rights reserved.
5 :     *)
6 :    
7 :     structure CTarget : TARGET =
8 :     struct
9 :    
10 :     structure IL = TreeIL
11 :     structure V = IL.Var
12 :     structure Ty = IL.Ty
13 :     structure CL = CLang
14 :     structure RN = RuntimeNames
15 :     structure ToC = TreeToC
16 :    
17 :     type var = ToC.var
18 :     type exp = CL.exp
19 :     type stm = CL.stm
20 :    
21 :     datatype strand = Strand of {
22 :     name : string,
23 :     tyName : string,
24 :     state : var list ref,
25 :     output : (Ty.ty * CL.var) option ref, (* the strand's output variable (only one for now) *)
26 :     code : CL.decl list ref
27 :     }
28 :    
29 :     datatype program = Prog of {
30 :     globals : CL.decl list ref,
31 :     topDecls : CL.decl list ref,
32 :     strands : strand AtomTable.hash_table,
33 :     initially : CL.decl ref
34 :     }
35 :    
36 :     datatype env = ENV of {
37 :     info : env_info,
38 :     vMap : var V.Map.map,
39 :     scope : scope
40 :     }
41 :    
42 :     and env_info = INFO of {
43 :     prog : program
44 :     }
45 :    
46 :     and scope
47 :     = NoScope
48 :     | GlobalScope
49 :     | InitiallyScope
50 :     | StrandScope of TreeIL.var list (* strand initialization *)
51 :     | MethodScope of TreeIL.var list (* method body; vars are state variables *)
52 :    
53 :     (* the supprted widths of vectors of reals on the target. For the GNU vector extensions,
54 :     * the supported sizes are powers of two, but float2 is broken.
55 :     * NOTE: we should also consider the AVX vector hardware, which has 256-bit registers.
56 :     *)
57 :     fun vectorWidths () = if !Controls.doublePrecision
58 :     then [2, 4, 8]
59 :     else [4, 8]
60 :    
61 :     (* tests for whether various expression forms can appear inline *)
62 :     fun inlineCons n = (n < 2) (* vectors are inline, but not matrices *)
63 :     val inlineMatrixExp = false (* can matrix-valued expressions appear inline? *)
64 :    
65 :     (* TreeIL to target translations *)
66 :     structure Tr =
67 :     struct
68 :     fun saveState cxt stateVars (env, args, stm) = (
69 :     ListPair.foldrEq
70 :     (fn (x, e, stms) => ToC.trAssign(env, x, e)@stms)
71 :     [stm]
72 :     (stateVars, args)
73 :     ) handle ListPair.UnequalLengths =>
74 :     raise Fail(concat["saveState ", cxt, ": length mismatch"])
75 :     fun block (ENV{vMap, scope, ...}, blk) = (case scope
76 :     of StrandScope stateVars => ToC.trBlock (vMap, saveState "StrandScope" stateVars, blk)
77 :     | MethodScope stateVars => ToC.trBlock (vMap, saveState "MethodScope" stateVars, blk)
78 :     | _ => ToC.trBlock (vMap, fn (_, _, stm) => [stm], blk)
79 :     (* end case *))
80 :     fun exp (ENV{vMap, ...}, e) = ToC.trExp(vMap, e)
81 :     end
82 :    
83 :     (* variables *)
84 :     structure Var =
85 :     struct
86 :     fun name (ToC.V(_, name)) = name
87 :     fun global (Prog{globals, ...}, name, ty) = let
88 :     val ty' = ToC.trType ty
89 :     in
90 :     globals := CL.D_Var([], ty', name, NONE) :: !globals;
91 :     ToC.V(ty', name)
92 :     end
93 :     fun param x = ToC.V(ToC.trType(V.ty x), V.name x)
94 :     fun state (Strand{state, ...}, x) = let
95 :     val ty' = ToC.trType(V.ty x)
96 :     val x' = ToC.V(ty', V.name x)
97 :     in
98 :     state := x' :: !state;
99 :     x'
100 :     end
101 :     end
102 :    
103 :     (* environments *)
104 :     structure Env =
105 :     struct
106 :     (* create a new environment *)
107 :     fun new prog = ENV{
108 :     info=INFO{prog = prog},
109 :     vMap = V.Map.empty,
110 :     scope = NoScope
111 :     }
112 :     (* define the current translation context *)
113 :     fun setScope scope (ENV{info, vMap, ...}) = ENV{info=info, vMap=vMap, scope=scope}
114 :     val scopeGlobal = setScope GlobalScope
115 :     val scopeInitially = setScope InitiallyScope
116 :     fun scopeStrand (env, svars) = setScope (StrandScope svars) env
117 :     fun scopeMethod (env, svars) = setScope (MethodScope svars) env
118 :     (* bind a TreeIL varaiable to a target variable *)
119 :     fun bind (ENV{info, vMap, scope}, x, x') = ENV{
120 :     info = info,
121 :     vMap = V.Map.insert(vMap, x, x'),
122 :     scope = scope
123 :     }
124 :     end
125 :    
126 :     (* programs *)
127 :     structure Program =
128 :     struct
129 :     fun new () = (
130 :     RN.initTargetSpec();
131 :     Prog{
132 :     globals = ref [
133 :     CL.D_Verbatim[
134 :     if !Controls.doublePrecision
135 :     then "#define DIDEROT_DOUBLE_PRECISION"
136 :     else "#define DIDEROT_SINGLE_PRECISION",
137 :     "#include \"Diderot/diderot.h\""
138 :     ]],
139 :     topDecls = ref [],
140 :     strands = AtomTable.mkTable (16, Fail "strand table"),
141 :     initially = ref(CL.D_Comment["missing initially"])
142 :     })
143 :     (* register the global initialization part of a program *)
144 :     fun init (Prog{topDecls, ...}, init) = let
145 :     val initFn = CL.D_Func([], CL.voidTy, RN.initGlobals, [], init)
146 :     in
147 :     topDecls := initFn :: !topDecls
148 :     end
149 :     (* create and register the initially function for a program *)
150 :     fun initially {
151 :     prog = Prog{strands, initially, ...},
152 :     isArray : bool,
153 :     iterPrefix : stm,
154 :     iters : (var * exp * exp) list,
155 :     createPrefix : stm,
156 :     strand : Atom.atom,
157 :     args : exp list
158 :     } = let
159 :     val iterPrefix = (case iterPrefix
160 :     of CL.S_Block stms => stms
161 :     | stm => [stm]
162 :     (* end case *))
163 :     val createPrefix = (case createPrefix
164 :     of CL.S_Block stms => stms
165 :     | stm => [stm]
166 :     (* end case *))
167 :     val name = Atom.toString strand
168 :     val nDims = List.length iters
169 :     val worldTy = CL.T_Ptr(CL.T_Named RN.worldTy)
170 :     fun mapi f xs = let
171 :     fun mapf (_, []) = []
172 :     | mapf (i, x::xs) = f(i, x) :: mapf(i+1, xs)
173 :     in
174 :     mapf (0, xs)
175 :     end
176 :     val baseInit = mapi (fn (i, (_, e, _)) => (i, CL.I_Exp e)) iters
177 :     val sizeInit = mapi
178 :     (fn (i, (ToC.V(ty, _), lo, hi)) =>
179 :     (i, CL.I_Exp(CL.mkBinOp(CL.mkBinOp(hi, CL.#-, lo), CL.#+, CL.E_Int(1, ty))))
180 :     ) iters
181 :     val allocCode = [
182 :     CL.mkComment["allocate initial block of strands"],
183 :     CL.mkDecl(CL.T_Array(CL.int32, SOME nDims), "base", SOME(CL.I_Array baseInit)),
184 :     CL.mkDecl(CL.T_Array(CL.uint32, SOME nDims), "size", SOME(CL.I_Array sizeInit)),
185 :     CL.mkDecl(worldTy, "wrld",
186 :     SOME(CL.I_Exp(CL.E_Apply(RN.allocInitially, [
187 :     CL.mkUnOp(CL.%&, CL.E_Var(RN.strandDesc name)),
188 :     CL.E_Bool isArray,
189 :     CL.E_Int(IntInf.fromInt nDims, CL.int32),
190 :     CL.E_Var "base",
191 :     CL.E_Var "size"
192 :     ]))))
193 :     ]
194 :     (* create the loop nest for the initially iterations *)
195 :     val indexVar = "ix"
196 :     val strandTy = CL.T_Ptr(CL.T_Named(RN.strandTy name))
197 :     fun mkLoopNest [] = CL.mkBlock(createPrefix @ [
198 :     CL.mkDecl(strandTy, "sp",
199 :     SOME(CL.I_Exp(
200 :     CL.E_Cast(strandTy,
201 :     CL.E_Apply(RN.inState, [CL.E_Var "wrld", CL.E_Var indexVar]))))),
202 :     CL.mkCall(RN.strandInit name, CL.E_Var "sp" :: args),
203 :     CL.mkAssign(CL.E_Var indexVar, CL.mkBinOp(CL.E_Var indexVar, CL.#+, CL.E_Int(1, CL.uint32)))
204 :     ])
205 :     | mkLoopNest ((ToC.V(ty, param), lo, hi)::iters) = let
206 :     val body = mkLoopNest iters
207 :     in
208 :     CL.mkFor(
209 :     [(ty, param, lo)],
210 :     CL.mkBinOp(CL.E_Var param, CL.#<=, hi),
211 :     [CL.mkPostOp(CL.E_Var param, CL.^++)],
212 :     body)
213 :     end
214 :     val iterCode = [
215 :     CL.mkComment["initially"],
216 :     CL.mkDecl(CL.uint32, indexVar, SOME(CL.I_Exp(CL.E_Int(0, CL.uint32)))),
217 :     mkLoopNest iters
218 :     ]
219 :     val body = CL.mkBlock(iterPrefix @ allocCode @ iterCode @ [CL.mkReturn(SOME(CL.E_Var "wrld"))])
220 :     val initFn = CL.D_Func([], worldTy, RN.initially, [], body)
221 :     in
222 :     initially := initFn
223 :     end
224 :    
225 :     (***** OUTPUT *****)
226 :     fun genStrand (Strand{name, tyName, state, output, code}) = let
227 :     (* the type declaration for the strand's state struct *)
228 :     val selfTyDef = CL.D_StructDef(
229 :     List.rev (List.map (fn ToC.V(ty, x) => (ty, x)) (!state)),
230 :     tyName)
231 :     (* the print function *)
232 :     val prFnName = concat[name, "_print"]
233 :     val prFn = let
234 :     val params = [
235 :     CL.PARAM([], CL.T_Ptr(CL.T_Named "FILE"), "outS"),
236 :     CL.PARAM([], CL.T_Ptr(CL.T_Named tyName), "self")
237 :     ]
238 :     val SOME(ty, x) = !output
239 :     val outState = CL.mkIndirect(CL.mkVar "self", x)
240 :     val prArgs = (case ty
241 :     of Ty.IVecTy 1 => [CL.E_Str(!RN.gIntFormat ^ "\n"), outState]
242 :     | Ty.IVecTy d => let
243 :     val fmt = CL.E_Str(
244 :     String.concatWith " " (List.tabulate(d, fn _ => !RN.gIntFormat))
245 :     ^ "\n")
246 :     val args = List.tabulate (d, fn i => ToC.ivecIndex(outState, d, i))
247 :     in
248 :     fmt :: args
249 :     end
250 :     | Ty.TensorTy[] => [CL.E_Str "%f\n", outState]
251 :     | Ty.TensorTy[d] => let
252 :     val fmt = CL.E_Str(
253 :     String.concatWith " " (List.tabulate(d, fn _ => "%f"))
254 :     ^ "\n")
255 :     val args = List.tabulate (d, fn i => ToC.vecIndex(outState, d, i))
256 :     in
257 :     fmt :: args
258 :     end
259 :     | _ => raise Fail("genStrand: unsupported output type " ^ Ty.toString ty)
260 :     (* end case *))
261 :     in
262 :     CL.D_Func(["static"], CL.voidTy, prFnName, params,
263 :     CL.mkCall("fprintf", CL.mkVar "outS" :: prArgs))
264 :     end
265 :     (* the strand's descriptor object *)
266 :     val descI = let
267 :     fun fnPtr (ty, f) = CL.I_Exp(CL.mkCast(CL.T_Named ty, CL.mkVar f))
268 :     in
269 :     CL.I_Struct[
270 :     ("name", CL.I_Exp(CL.E_Str name)),
271 :     ("stateSzb", CL.I_Exp(CL.mkSizeof(CL.T_Named(RN.strandTy name)))),
272 :     ("update", fnPtr("update_method_t", name ^ "_update")),
273 :     ("print", fnPtr("print_method_t", prFnName))
274 :     ]
275 :     end
276 :     val desc = CL.D_Var([], CL.T_Named RN.strandDescTy, RN.strandDesc name, SOME descI)
277 :     in
278 :     selfTyDef :: List.rev (desc :: prFn :: !code)
279 :     end
280 :    
281 :     (* generate the table of strand descriptors *)
282 :     fun genStrandTable (ppStrm, strands) = let
283 :     val nStrands = length strands
284 :     fun genInit (Strand{name, ...}) = CL.I_Exp(CL.mkUnOp(CL.%&, CL.E_Var(RN.strandDesc name)))
285 :     fun genInits (_, []) = []
286 :     | genInits (i, s::ss) = (i, genInit s) :: genInits(i+1, ss)
287 :     fun ppDecl dcl = PrintAsC.output(ppStrm, dcl)
288 :     in
289 :     ppDecl (CL.D_Var([], CL.int32, RN.numStrands,
290 :     SOME(CL.I_Exp(CL.E_Int(IntInf.fromInt nStrands, CL.int32)))));
291 :     ppDecl (CL.D_Var([],
292 :     CL.T_Array(CL.T_Ptr(CL.T_Named RN.strandDescTy), SOME nStrands),
293 :     RN.strands,
294 :     SOME(CL.I_Array(genInits (0, strands)))))
295 :     end
296 :    
297 :     fun genSrc (baseName, Prog{globals, topDecls, strands, initially}) = let
298 :     val fileName = OS.Path.joinBaseExt{base=baseName, ext=SOME "c"}
299 :     val outS = TextIO.openOut fileName
300 :     val ppStrm = PrintAsC.new outS
301 :     fun ppDecl dcl = PrintAsC.output(ppStrm, dcl)
302 :     val strands = AtomTable.listItems strands
303 :     in
304 :     List.app ppDecl (List.rev (!globals));
305 :     List.app ppDecl (List.rev (!topDecls));
306 :     List.app (fn strand => List.app ppDecl (genStrand strand)) strands;
307 :     genStrandTable (ppStrm, strands);
308 :     ppDecl (!initially);
309 :     PrintAsC.close ppStrm;
310 :     TextIO.closeOut outS
311 :     end
312 :    
313 :     (* output the code to a file. The string is the basename of the file, the extension
314 :     * is provided by the target.
315 :     *)
316 :     fun generate (baseName, prog) = (
317 :     genSrc (baseName, prog);
318 :     RunCC.compile baseName;
319 :     RunCC.link baseName)
320 :    
321 :     end
322 :    
323 :     (* strands *)
324 :     structure Strand =
325 :     struct
326 :     fun define (Prog{strands, ...}, strandId) = let
327 :     val name = Atom.toString strandId
328 :     val strand = Strand{
329 :     name = name,
330 :     tyName = RN.strandTy name,
331 :     state = ref [],
332 :     output = ref NONE,
333 :     code = ref []
334 :     }
335 :     in
336 :     AtomTable.insert strands (strandId, strand);
337 :     strand
338 :     end
339 :    
340 :     (* return the strand with the given name *)
341 :     fun lookup (Prog{strands, ...}, strandId) = AtomTable.lookup strands strandId
342 :    
343 :     (* register the strand-state initialization code. The variables are the strand
344 :     * parameters.
345 :     *)
346 :     fun init (Strand{name, tyName, code, ...}, params, init) = let
347 :     val fName = RN.strandInit name
348 :     val params =
349 :     CL.PARAM([], CL.T_Ptr(CL.T_Named tyName), "selfOut") ::
350 :     List.map (fn (ToC.V(ty, x)) => CL.PARAM([], ty, x)) params
351 :     val initFn = CL.D_Func([], CL.voidTy, fName, params, init)
352 :     in
353 :     code := initFn :: !code
354 :     end
355 :    
356 :     (* register a strand method *)
357 :     fun method (Strand{name, tyName, code, ...}, methName, body) = let
358 :     val fName = concat[name, "_", methName]
359 :     val params = [
360 :     CL.PARAM([], CL.T_Ptr(CL.T_Named tyName), "selfIn"),
361 :     CL.PARAM([], CL.T_Ptr(CL.T_Named tyName), "selfOut")
362 :     ]
363 :     val methFn = CL.D_Func(["static"], CL.int32, fName, params, body)
364 :     in
365 :     code := methFn :: !code
366 :     end
367 :    
368 :     fun output (Strand{output, ...}, ty, ToC.V(_, x)) = output := SOME(ty, x)
369 :    
370 :     end
371 :    
372 :     end
373 :    
374 :     structure CBackEnd = CodeGenFn(CTarget)

root@smlnj-gforge.cs.uchicago.edu
ViewVC Help
Powered by ViewVC 1.0.0