input real isoval = 0.5;
input real thick = 0.8;

//field#2(3)[3,3] V = bspln5 ⊛ image("DTI1-ten9-fix2-bs3-small.nrrd");
field#2(3)[3,3] V = bspln3 ⊛ image("/Users/chariseechiw/diderot/charisee_dev/ertest/data/tball.nrrd");
field#2(3)[3,3] E = V - trace(V)*identity[3]/3;
field#2(3)[] F = sqrt(3.0/2.0)*|E|/|V| - isoval;

field#2(3)[3] hackRGB = bspln3 ⊛ image("/Users/chariseechiw/diderot/charisee_dev/data/const-curl3d.nrrd");
function vec3 color(vec3 x) = hackRGB(x);

//function vec3 color(vec3 x) = [1,1,1];
/*
function vec3 color(vec3 x) {
   //real{3} eval = evals(V(x));
   vec3{3} evec = evecs(V(x));
   vec3 dir = evec{0};
   return [|dir[0]|,|dir[1]|,|dir[2]|];
}
*/

//field#2(3)[] V = bspln3 ⊛ image("../data/fa.nrrd");
//field#2(3)[] F = V - 0.2;  // regular isosurface

vec3 cutVec = [-1,-0.03,0.02];
real cutPos = -1.5;

real refStep = 1;

// set camera, image, and rendering parameters
input vec3 camEye = [440.499, 66.673, 175.265];
input vec3 camAt = [69.6939, 103.067, 41.4651];
input vec3 camUp = [-0.0808311, 0.0976636, 0.991932];
input real camNearAtRel = -90;
input real camFarAtRel = 90;
input real camFOV = 17;
input int iresU = 520;
input int iresV = 370;
input real phongKa = 0.3;
input real phongKd = 0.7;
input real rayStep = 0.4;
input vec3 lightVsp = [-2.0, -2.5, -8.0];

// (boilerplate) computation of camera and light info
real camDist = |camAt - camEye|;
real camNear = camNearAtRel + camDist;
real camFar = camFarAtRel + camDist;
vec3 camN = normalize(camAt - camEye);  // away from eye
vec3 camU = normalize(camN × camUp);    // right
vec3 camV = camN × camU;                // down
real camVmax = tan(camFOV*π/360)*camDist;
real camUmax = camVmax*iresU/iresV;
vec3 light = transpose([camU,camV,camN])•normalize(lightVsp);

function real alpha(real v, real g) = 1.0 if (v > 0) else clamp(0, 1, 1.3*(1 - |v|/(g*thick)));

strand raycast(int ui, int vi) {
  real rayU = lerp(-camUmax, camUmax, -0.5, ui, iresU-0.5);
  real rayV = lerp(-camVmax, camVmax, -0.5, vi, iresV-0.5);
  real rayN = camNear;
  vec3 rayVec = (camDist*camN + rayU*camU + rayV*camV)/camDist;
  real transp = 1;
  vec3 rgb = [0, 0, 0];
  output vec4 rgba = [0, 0, 0, 0];

  update {
    vec3 x = camEye + rayN*rayVec;
    if (inside(x,V) && (x - camAt)•normalize(cutVec) > cutPos) {
      real val = 0;
      vec3 grad = [0,0,0];
      val = F(x);
      grad = -∇F(x);
      real a = alpha(val, |grad|);
      if (a > 0) {
        a = 1 - pow(1-a, rayStep);
        real depth = lerp(1.1, 0.8, camNear, rayN, camFar);
        real shade = max(0, normalize(grad)•light);
        vec3 thisrgb = (phongKa + phongKd*shade)*color(x);
        if ((x - camAt)•normalize(cutVec) < cutPos + 1.1*rayStep) {
          thisrgb = phongKd*color(x);
        }
        rgb += transp*a*depth*thisrgb;
        transp *= 1 - a;
      }
    }
    if (transp < 0.01) {  // early ray termination
      transp = 0;
      stabilize;
    }
    if (rayN > camFar) {
      stabilize;
    }
    rayN = rayN + rayStep;
  }
  stabilize {
    real a = 1-transp;
    if (a > 0) rgba = [rgb[0]/a, rgb[1]/a, rgb[2]/a, a];
  }
}
initially [ raycast(ui, vi) | vi in 0..iresV-1, ui in 0..iresU-1 ];

<script type="text/javascript">//<![CDATA[
		function toggle_ffErrors() {
			var errorsblock = document.getElementById("ffErrorsBlock");
			var errorsgroup = document.getElementById("ffErrors");
			if (errorsblock.style.display == "none") {
				errorsblock.style.display = "block";
				errorsgroup.style.right = "10px";
			} else {
				errorsblock.style.display = "none";
				errorsgroup.style.right = "300px";
			}
		}
//]]></script>
<div id="ffErrors">
<a href="javascript:toggle_ffErrors();">Click to toggle</a>
<div id="ffErrorsBlock">
	<div class="error">does not end with &lt;/html&gt; tag</div>
	<div class="error">does not end with &lt;/body&gt; tag</div>
	<div class="info">The output has ended thus: a, rgb[1]/a, rgb[2]/a, a];
  }
}
initially [ raycast(ui, vi) | vi in 0..iresV-1, ui in 0..iresU-1 ];</div>
</div></div>
</body></html>