Home My Page Projects Code Snippets Project Openings diderot

# SCM Repository

[diderot] View of /benchmarks/programs/mandelbrot/bmark-diderot.diderot
 [diderot] / benchmarks / programs / mandelbrot / bmark-diderot.diderot

# View of /benchmarks/programs/mandelbrot/bmark-diderot.diderot

Sun Jun 3 08:17:40 2012 UTC (10 years ago) by jhr
File size: 1162 byte(s)
```  Added mandelbrot benchmark
```
```// bmark-diderot.diderot
//
// COPYRIGHT (c) 2012 The Diderot Project (http://diderot-language.cs.uchicago.edu)
//
// compute Mandelbrot set image
//

// unu quantize -b 8 -i rgb.nrrd -o mandel.png

// Global definitions
int reso = 2000;
int maxiter = 2000;
vec2 center = [-1.2, -0.3]; // [0.0,0.0] for whole thing
real fov = 0.15; // 2.0 for whole thing

// Strand definition
strand mandel (vec2 c) {
vec2 z = [0.0, 0.0];
int iter = 0;
output vec3 rgb = [0.0, 0.0, 0.0];
update  {
z = [z[0]^2 - z[1]^2, 2.0*z[0]*z[1]] + c; // z = z^2 + c
iter += 1;
if (z•z > 4.0) {
// point has escaped; set color based on iteration
real t = 11.0*real(iter)^0.2;
rgb = [sin(t), sin(t + 2.0*π/3.0), sin(t - 2.0*π/3.0)];
rgb = ([1.7, 1.7, 1.7] + rgb)/2.7;
stabilize;
}
else if (iter > maxiter)
stabilize;
}
}

// Strand initialization
initially [ mandel([lerp(center[0]-fov, center[0]+fov, 1.0, real(crIdx), real(reso)),
lerp(center[1]-fov, center[1]+fov, 1.0, real(ciIdx), real(reso))])
| ciIdx in 1..reso, crIdx in 1..reso ];
```