Home My Page Projects Code Snippets Project Openings diderot
Summary Activity Tracker Tasks SCM

SCM Repository

[diderot] Annotation of /branches/cuda/src/compiler/cuda-target/print-as-cuda.sml
ViewVC logotype

Annotation of /branches/cuda/src/compiler/cuda-target/print-as-cuda.sml

Parent Directory Parent Directory | Revision Log Revision Log


Revision 3349 - (view) (download)

1 : jhr 1677 (* print-as-cuda.sml
2 :     *
3 : jhr 3349 * This code is part of the Diderot Project (http://diderot-language.cs.uchicago.edu)
4 :     *
5 :     * COPYRIGHT (c) 2015 The University of Chicago
6 : jhr 1677 * All rights reserved.
7 :     *
8 :     * Print the CLang representation using CUDA syntax.
9 :     *)
10 :    
11 :     structure PrintAsCUDA : sig
12 :    
13 :     type strm
14 :    
15 :     val new : TextIO.outstream -> strm
16 :    
17 :     val close : strm -> unit
18 :    
19 :     val output : strm * CLang.decl -> unit
20 :    
21 :     end = struct
22 :    
23 :     structure CL = CLang
24 :     structure PP = TextIOPP
25 :    
26 :     type strm = PP.stream
27 :    
28 :     val indent = (PP.Abs 4) (* standard indentation amount *)
29 :    
30 :     fun new outs = PP.openOut {dst = outs, wid = 90}
31 :    
32 :     val close = PP.closeStream
33 :    
34 :     fun output (strm, decl) = let
35 :     val str = PP.string strm
36 :     fun sp () = PP.space strm 1
37 :     fun inHBox f = (PP.openHBox strm; f(); PP.closeBox strm)
38 :     fun ppComLn s = (
39 :     inHBox (fn () => (str "// "; str s));
40 :     PP.newline strm)
41 :     fun ppList {pp, sep, l} = let
42 :     fun ppList' [] = ()
43 :     | ppList' [x] = pp x
44 :     | ppList' (x::xs) = (pp x; sep(); ppList' xs)
45 :     in
46 :     ppList' l
47 :     end
48 :     fun ppTy (ty, optVar) = let
49 :     fun getBaseTy (CL.T_Ptr ty) = getBaseTy ty
50 :     | getBaseTy (CL.T_Array(ty, _)) = getBaseTy ty
51 :     | getBaseTy (CL.T_Num rty) = (case rty
52 :     of RawTypes.RT_Int8 => "char"
53 :     | RawTypes.RT_UInt8 => "uchar"
54 :     | RawTypes.RT_Int16 => "short"
55 :     | RawTypes.RT_UInt16 => "ushort"
56 :     | RawTypes.RT_Int32 => "int"
57 :     | RawTypes.RT_UInt32 => "uint"
58 :     | RawTypes.RT_Int64 => "long"
59 :     | RawTypes.RT_UInt64 => "ulong"
60 :     | RawTypes.RT_Float => "float"
61 :     | RawTypes.RT_Double => "double" (* only if 64-bitFP extension is supported *)
62 :     (* end case *))
63 :     | getBaseTy (CL.T_Named ty) = ty
64 :     | getBaseTy (CL.T_Qual(attr, ty)) =
65 :     concat[attr, " ", getBaseTy ty]
66 :     fun pp (isFirst, CL.T_Ptr ty, optVar) = (
67 :     if isFirst then sp() else ();
68 :     case ty
69 :     of CL.T_Array _ => (
70 :     str "(*"; pp(false, ty, optVar); str ")")
71 :     | _ => (str "*"; pp(false, ty, optVar))
72 :     (* end case *))
73 :     | pp (isFirst, CL.T_Array(ty, optN), optVar) = (
74 :     pp (isFirst, ty, optVar);
75 :     case optN
76 :     of NONE => str "[]"
77 :     | SOME n => (str "["; str(Int.toString n); str "]")
78 :     (* end case *))
79 :     | pp (isFirst, CL.T_Qual(_, ty), optVar) =
80 :     pp (isFirst, ty, optVar)
81 :     | pp (isFirst, _, SOME x) = (
82 :     if isFirst then sp() else ();
83 :     str x)
84 :     | pp (_, _, NONE) = ()
85 :     in
86 :     str (getBaseTy ty);
87 :     pp (true, ty, optVar)
88 :     end
89 :     fun ppAttrs [] = ()
90 :     | ppAttrs attrs = (
91 :     ppList {pp=str, sep=sp, l = attrs};
92 :     sp())
93 :     fun ppDecl dcl = (case dcl
94 :     of CL.D_Comment l => List.app ppComLn l
95 :     | CL.D_Verbatim l => List.app str l
96 :     | CL.D_Var(attrs, ty, x, optInit) => (
97 :     inHBox (fn () => (
98 :     ppAttrs attrs;
99 :     ppTy (ty, SOME x);
100 :     case optInit
101 :     of SOME init => (sp(); str "="; sp(); ppInit init)
102 :     | NONE => ()
103 :     (* end case *);
104 :     str ";"));
105 :     PP.newline strm)
106 :     | CL.D_Func(attrs, ty, f, params, body) => (
107 :     inHBox (fn () => (
108 :     ppAttrs attrs;
109 :     ppTy(ty, SOME f);
110 :     sp(); str "(";
111 :     ppList {pp=ppParam, sep=fn () => (str ","; sp()), l=params};
112 :     str ")"));
113 :     PP.newline strm;
114 :     ppBlock (case body of CL.S_Block stms => stms | stm => [stm]))
115 :     | CL.D_StructDef(fields, tyName) => (
116 :     str "typedef struct {";
117 :     PP.openVBox strm indent;
118 :     List.app (fn (ty, x) => (
119 :     PP.newline strm;
120 :     inHBox (fn () => (ppTy(ty, SOME x); str ";"))))
121 :     fields;
122 :     PP.closeBox strm;
123 :     PP.newline strm;
124 :     inHBox (fn () => (str "}"; sp(); str tyName; str ";"));
125 :     PP.newline strm)
126 :     (* end case *))
127 :     and ppParam (CL.PARAM(attrs, ty, x)) = (
128 :     ppAttrs attrs;
129 :     ppTy(ty, SOME(CL.varToString x)))
130 :     and ppInit init = (case init
131 :     of CL.I_Exp e => ppExp e
132 :     | CL.I_Struct fields => (
133 :     str "{";
134 :     PP.openHVBox strm indent;
135 :     List.app (fn (lab, init) => (
136 :     PP.break strm;
137 :     inHBox (fn () => (
138 :     str("." ^ lab); sp(); str "="; sp(); ppInit init; str ","))))
139 :     fields;
140 :     PP.closeBox strm;
141 :     str "}")
142 :     | CL.I_Array elems => (
143 :     str "{";
144 :     PP.openHVBox strm indent;
145 :     List.app (fn (i, init) => (
146 :     PP.break strm;
147 :     inHBox (fn () => (
148 :     str(concat["[", Int.toString i, "]"]); sp(); str "="; sp();
149 :     ppInit init; str ","))))
150 :     elems;
151 :     PP.closeBox strm;
152 :     str "}")
153 :     (* end case *))
154 :     and ppBlock stms = (
155 :     str "{";
156 :     PP.openVBox strm indent;
157 :     PP.newline strm;
158 :     List.app ppStm stms;
159 :     PP.closeBox strm;
160 :     str "}"; PP.newline strm)
161 :     and ppStm stm = (case stm
162 :     of CL.S_Block stms => ppBlock stms
163 :     | CL.S_Comment l => List.app ppComLn l
164 :     | CL.S_Decl(attrs, ty, x, NONE) => (
165 :     inHBox (fn () => (
166 :     ppAttrs attrs;
167 :     ppTy(ty, SOME x); str ";"));
168 :     PP.newline strm)
169 :     | CL.S_Decl(attrs,ty, x, SOME e) => (
170 :     inHBox (fn () => (
171 :     ppAttrs attrs;
172 :     ppTy(ty, SOME x); sp(); str "="; sp(); ppInit e; str ";"));
173 :     PP.newline strm)
174 :     | CL.S_Exp e => (
175 :     inHBox (fn () => (ppExp e; str ";"));
176 :     PP.newline strm)
177 :     | CL.S_If(e, blk, CL.S_Block[]) =>
178 :     inHBox (fn () => (str "if"; sp(); ppExp e; ppStms blk))
179 :     | CL.S_If(e, blk1, blk2) => (
180 :     inHBox (fn () => (str "if"; sp(); ppExp e)); ppStms blk1;
181 :     str "else"; ppStms blk2)
182 :     | CL.S_While(e, blk) => (
183 :     inHBox (fn () => (str "while"; sp(); ppExp e)); ppStms blk)
184 :     | CL.S_DoWhile(blk, e) => (
185 :     str "do"; sp(); ppStms blk;
186 :     inHBox (fn () => (str "while"; sp(); ppExp e; str ";")))
187 :     | CL.S_For(inits, cond, incrs, blk) => let
188 :     fun ppInit (ty, x, e) = inHBox (fn () => (
189 :     ppTy(ty, SOME x);
190 :     sp(); str "="; sp();
191 :     ppExp e))
192 :     in
193 :     inHBox (fn () => (
194 :     str "for"; sp(); str "(";
195 :     ppList {pp = ppInit, sep = fn () => str ",", l = inits};
196 :     str ";"; sp();
197 :     ppExp cond; str ";"; sp();
198 :     ppList {pp = ppExp, sep = fn () => str ",", l = incrs}));
199 :     str ")";
200 :     ppStms blk
201 :     end
202 :     | CL.S_Call(f, args) => (
203 :     inHBox (fn () => (str f; ppArgs args; str ";"));
204 :     PP.newline strm)
205 :     | CL.S_Return(SOME e) => (
206 :     inHBox (fn () => (str "return"; sp(); ppExp e; str ";"));
207 :     PP.newline strm)
208 :     | CL.S_Return _ => (str "return;"; PP.newline strm)
209 :     | CL.S_Break => (str "break;"; PP.newline strm)
210 :     | CL.S_Continue => (str "continue;"; PP.newline strm)
211 :     (* end case *))
212 :     and ppStms (CL.S_Block stms) = (sp(); ppBlock stms)
213 :     | ppStms stm = (
214 :     PP.openVBox strm indent;
215 :     PP.newline strm;
216 :     ppStm stm;
217 :     PP.closeBox strm)
218 :     and ppExp e = (case e
219 :     of CL.E_Grp e => (str "("; ppExp e; str ")")
220 :     | CL.E_AssignOp(lhs, rator, rhs) => (
221 :     ppExp lhs; sp(); str(CL.assignopToString rator); sp(); ppExp rhs)
222 :     | CL.E_Cond(e1, e2, e3) => (
223 :     ppExp e1; sp(); str "?"; sp(); ppExp e2; sp(); str ":"; sp(); ppExp e3)
224 :     | CL.E_BinOp(e1, rator, e2) => (ppExp e1; str(CL.binopToString rator); ppExp e2)
225 :     | CL.E_UnOp(rator, e) => (str(CL.unopToString rator); ppExp e)
226 :     | CL.E_PostOp(e, rator) => (ppExp e; str(CL.postopToString rator))
227 :     | CL.E_Apply(f, args) => (str f; ppArgs args)
228 :     | CL.E_Subscript(e1, e2) => (ppExp e1; str "["; ppExp e2; str "]")
229 :     | CL.E_Select(e, f) => (ppExp e; str "."; str f)
230 :     | CL.E_Indirect(e, f) => (ppExp e; str "->"; str f)
231 :     | CL.E_Cast(ty, e) => (
232 :     str "("; ppTy(ty, NONE); str ")"; ppExp e)
233 :     | CL.E_Var x => str(CL.varToString x)
234 :     | CL.E_Int(n, CL.T_Num(RawTypes.RT_Int64)) =>
235 :     str(IntegerLit.toString n ^ "l")
236 :     | CL.E_Int(n, _) => str(IntegerLit.toString n)
237 :     | CL.E_Flt(f, ty) => let
238 :     val isDouble = (case ty
239 :     of CL.T_Num(RawTypes.RT_Float) => false
240 :     | _ => true
241 :     (* end case *))
242 :     (* NOTE: the CLang.mkFlt function guarantees that f is non-negative *)
243 :     val f = if FloatLit.same(FloatLit.posInf, f)
244 :     then if isDouble
245 :     then "HUGE_VAL"
246 :     else "HUGE_VALF"
247 :     else if FloatLit.same(FloatLit.nan, f)
248 :     then "nan((uint)0)"
249 :     else if isDouble
250 :     then FloatLit.toString f
251 :     else FloatLit.toString f ^ "f"
252 :     in
253 :     str f
254 :     end
255 :     | CL.E_Bool b => str(Bool.toString b)
256 :     | CL.E_Str s => str(concat["\"", String.toCString s, "\""])
257 :     | CL.E_Sizeof ty => (str "sizeof("; ppTy(ty, NONE); str ")")
258 :     (* end case *))
259 :     and ppArgs args = (
260 :     str "(";
261 :     PP.openHOVBox strm indent;
262 :     PP.cut strm;
263 :     ppList {
264 :     pp = fn e => (PP.openHBox strm; ppExp e; PP.closeBox strm),
265 :     sep = fn () => (str ","; sp()),
266 :     l = args
267 :     };
268 :     str ")";
269 :     PP.closeBox strm)
270 :     in
271 :     ppDecl decl
272 :     end
273 :    
274 :     end

root@smlnj-gforge.cs.uchicago.edu
ViewVC Help
Powered by ViewVC 1.0.0