(* census-fn.sml
 *
 * COPYRIGHT (c) 2010 The Diderot Project (http://diderot-language.cs.uchicago.edu)
 * All rights reserved.
 *
 * Compute use counts for IL variables and initialize their bindings.
 *)

functor CensusFn (IL : SSA) : sig

    structure IL : SSA

    val init : IL.program -> unit

    val inc : IL.var -> unit

  end = struct

    structure IL = IL

    fun inc (IL.V{useCnt, ...}) = (useCnt := !useCnt + 1)
    fun setBinding (IL.V{bind, ...}, vb) = bind := vb

    fun init (IL.Program{globals, globalInit, strands}) = let
	  fun clearVar (IL.V{useCnt, ...}) = useCnt := 0
	(* clear the counts of the variables defined in a node *)
	  fun clearNode (IL.ND{kind, ...}) = (case kind
		 of IL.JOIN{phis, ...} => List.app (fn (x, _) => clearVar x) (!phis)
		  | IL.ASSIGN{stm=(x, _), ...} => clearVar x
		  | _ => ()
		(* end case *))
	(* clear the counts of the variables defined in an strand *)
	  fun clearStrand (IL.Strand{params, state, stateInit, methods, ...}) = let
		fun clearMethod (IL.Method{stateIn, body, ...}) = (
		      List.app clearVar stateIn;
		      IL.CFG.apply clearNode body)
		in
		  List.app clearVar params;
		  List.app clearVar state;
		  IL.CFG.apply clearNode stateInit;
		  List.app clearMethod methods
		end
	(* increment the use counts of a list of variables *)
	  val incList = List.app inc
	(* increment the counts of the variables used in a node *)
	  fun incNode (IL.ND{kind, ...}) = (case kind
		 of IL.JOIN{phis, ...} => let
		      fun f (y, xs) = (
			    setBinding (y, IL.VB_PHI xs);
			    incList xs)
		      in
			List.app f (!phis)
		      end
		  | IL.COND{cond, ...} => inc cond
		  | IL.ASSIGN{stm = (y, rhs), ...} => (
		      setBinding (y, IL.VB_RHS rhs);
		      case rhs
		       of (IL.VAR x) => inc x
			| (IL.LIT _) => ()
			| (IL.OP(_, args)) => incList args
			| (IL.CONS args) => incList args
		      (* end case *))
		  | IL.NEW{args, ...} => incList args
		  | _ => ()
		(* end case *))
	(* increment the counts of the variables used in a strand *)
	  fun incStrand (IL.Strand{params, state, stateInit, methods, ...}) = let
		fun incMethod (IL.Method{stateIn, stateOut, body, ...}) = (
		      List.app (fn x => setBinding(x, IL.VB_STATE_VAR)) stateIn;
		      incList stateOut;
		      IL.CFG.apply incNode body)
		in
		  List.app (fn x => setBinding(x, IL.VB_PARAM)) params;
		  IL.CFG.apply incNode stateInit;
		  List.app incMethod methods
		end
	  in
	  (* first clear the counts of all variables *)
	    List.app clearVar globals;
	    IL.CFG.apply clearNode globalInit;
	    List.app clearStrand strands;
	  (* then count uses *)
	    IL.CFG.apply incNode globalInit;
	    List.app incStrand strands
	  end

  end