Home My Page Projects Code Snippets Project Openings diderot
Summary Activity Tracker Tasks SCM

SCM Repository

[diderot] View of /branches/pure-cfg/src/compiler/c-target/runtime-names.sml
ViewVC logotype

View of /branches/pure-cfg/src/compiler/c-target/runtime-names.sml

Parent Directory Parent Directory | Revision Log Revision Log


Revision 810 - (download) (annotate)
Tue Apr 12 16:30:36 2011 UTC (10 years, 5 months ago) by jhr
File size: 4199 byte(s)
  Working on codegen support for vector-matrix, matrix-vector, and matrix-matrix
  multiplication.
(* runtime-names.sml
 *
 * COPYRIGHT (c) 2011 The Diderot Project (http://diderot-language.cs.uchicago.edu)
 * All rights reserved.
 *)

structure RuntimeNames =
  struct

    local
      structure F = Format
    in

  (* globals that specify the target characteristics.  These should be initialized
   * when the program object is created.
   *)
    val gVectorWid = ref 4
    val gIntTy = ref CLang.int32
    val gRealTy = ref CLang.float
    val gRealSuffix = ref "?"
    val gIntSuffix = ref "?"
    val gIntFormat = ref "?"

  (* initialize globals based on target precision *)
    fun initTargetSpec () = if !Controls.doublePrecision
	  then (
	    gVectorWid := 2;
	    gIntTy := CLang.int64;
	    gRealTy := CLang.double;
	    gRealSuffix := "d";
	    gIntSuffix := "l";
	    gIntFormat := "%ld")
	  else (
	    gVectorWid := 4;
	    gIntTy := CLang.int32;
	    gRealTy := CLang.float;
	    gRealSuffix := "f";
	    gIntSuffix := "i";
	    gIntFormat := "%d")

    fun addVecSuffix stem n = concat[stem, Int.toString n, !gRealSuffix]
    fun addIVecSuffix stem n = concat[stem, Int.toString n, !gIntSuffix]

    fun addTySuffix (stem, TargetTy.T_Real) = stem ^ !gRealSuffix
      | addTySuffix (stem, TargetTy.T_Vec n) = addVecSuffix stem n
      | addTySuffix (stem, ty) = raise Fail(concat["invalid type ", TargetTy.toString ty, " for ", stem])

    fun vecTy n = concat["vec", Int.toString n, !gRealSuffix, "_t"]
    fun ivecTy n = concat["vec", Int.toString n, !gIntSuffix, "_t"]
    fun imageTy n = concat["Diderot_image", Int.toString n, "D_t"]
    fun matTy (n, m) = concat["Diderot_Mat", Int.toString n, "x", Int.toString m, "_t"]

  (* names of generated tyes, functions, and globals *)
    val initGlobals = "Diderot_InitGlobals"	(* function for initializing program globals *)
    val initially = "Diderot_Initially"		(* function for creating initial strands *)
    fun strandInit strand = strand ^ "_InitState"
    fun strandTy strand = concat["Strand_", strand, "_t"]
    fun strandDesc strand = concat["Strand_", strand]
    val numStrands = "Diderot_NumStrands"
    val strands = "Diderot_Strands"

  (* scalar math functions *)
    fun max ty = addTySuffix ("max", ty)
    fun min ty = addTySuffix ("min", ty)

  (* lerp *)
    fun lerp 0 = "lerp" ^ !gRealSuffix
      | lerp n = concat["lerp", Int.toString n, !gRealSuffix]

  (* vector math functions *)
    val mkVec = addVecSuffix "vec"
    val scale = addVecSuffix "scale"
    val truncToInt = addVecSuffix "truncToInt"
    val dot = addVecSuffix "dot"
    fun mulVecMat (m, n) = F.format "mulVec%dMat%dx%d%s"
	  [F.INT m, F.INT m, F.INT n, F.STR(!gRealSuffix)]
    fun mulMatVec (m, n) = F.format "mulMat%dx%dVec%d%s"
	  [F.INT n, F.INT m, F.INT n, F.STR(!gRealSuffix)]
    fun mulMatMat (m, n, p) = F.format "mulMat%dx%dMat%dx%d%s"
	  [F.INT m, F.INT n, F.INT n, F.INT p, F.STR(!gRealSuffix)]
    fun cross () = addVecSuffix "cross" 3
    val length = addVecSuffix "length"
    val normalize = addVecSuffix "normalize"
    fun vecitof n = concat["vec", Int.toString n, "ito", !gRealSuffix]
    fun vecftoi n = concat["vec", Int.toString n, !gRealSuffix, "toi"]

  (* matrix operations *)
    fun trace n = concat["trace", Int.toString n, "x", Int.toString n, !gRealSuffix]
    fun copyMat (n, m) = concat["copy", Int.toString n, "x", Int.toString m, !gRealSuffix]

  (* Status_t symbols *)
    val kActive = "DIDEROT_ACTIVE"
    val kDie = "DIDEROT_DIE"
    val kStabilize = "DIDEROT_STABILIZE"

  (* Diderot runtime system hooks *)
    val statusTy = "Status_t"
    val toImageSpace = addVecSuffix "Diderot_ToImageSpace"
    val inside = addVecSuffix "Diderot_Inside"
    fun loadImage dim = concat["Diderot_LoadImage", Int.toString dim, "D"]
    val strandDescTy = "Strand_t"
    val worldTy = "Diderot_World_t"
    val allocInitially = "Diderot_AllocInitially"
    val inState = "Diderot_InState"

    fun input ty = (case ty
	   of TargetTy.T_String => "Diderot_InputString"
	    | TargetTy.T_Real => "Diderot_Input" ^ !gRealSuffix
	    | TargetTy.T_Vec 3 => "Diderot_InputVec3" ^ !gRealSuffix
	    | ty => raise Fail("unsupported input type " ^ TargetTy.toString ty)
	  (* end case *))

    end (* local *)
  end

root@smlnj-gforge.cs.uchicago.edu
ViewVC Help
Powered by ViewVC 1.0.0