Home My Page Projects Code Snippets Project Openings diderot
Summary Activity Tracker Tasks SCM

SCM Repository

[diderot] Annotation of /examples/vr-demo/vr.diderot
ViewVC logotype

Annotation of /examples/vr-demo/vr.diderot

Parent Directory Parent Directory | Revision Log Revision Log


Revision 2061 - (view) (download)

1 : jhr 2061 /*! \file vr.diderot
2 :     *
3 :     * \author John Reppy
4 :     *
5 :     * simple volume renderer, with a single directional light,
6 :     * Phong shading, and the new camera.
7 :     */
8 : jhr 2058
9 : jhr 2061 /*
10 :     * COPYRIGHT (c) 2012 The Diderot Project (http://diderot-language.cs.uchicago.edu)
11 :     * All rights reserved.
12 :     */
13 :    
14 : jhr 2058 // image parameters
15 :     input int imgResU = 480;
16 :     input int imgResV = 345;
17 :     input real rayStep = 0.1;
18 :    
19 :     // camera controls
20 :     input vec3 camEye = [127.331, -1322.05, 272.53];
21 :     input vec3 camAt = [63.0, 82.6536, 98.0];
22 :     input vec3 camUp = [0.9987, 0.0459166, -0.0221267];
23 :     input real camNear = -78.0;
24 :     input real camFar = 78.0;
25 :     input real camFOV = 5.0;
26 :    
27 :     /* we control the opacity by its center value and the +/- keys */
28 :     input real valOpacMid = 550.0; // 550 for skin, 1300.0 for bone
29 :     real valOpacMin = valOpacMid - 150.0;
30 :     real valOpacMax = valOpacMid + 150.0;
31 :    
32 :     real camDist = |camAt - camEye|;
33 :     real camVspNear = camDist + camNear;
34 :     real camVspFar = camDist + camFar;
35 :     vec3 camN = normalize(camAt - camEye);
36 :     vec3 camU = normalize(camN × camUp);
37 :     vec3 camV = camN × camU;
38 :     real camVmax = tan(camFOV*π/360.0)*camDist;
39 :     real camUmax = camVmax*real(imgResU)/real(imgResV);
40 :    
41 :     vec3 lightVspDir = [0.9, -1.0, -2.5];
42 :     vec3 lightDir = normalize(lightVspDir[0]*camU + lightVspDir[1]*camV + lightVspDir[2]*camN);
43 :     //vec3 lightRGB = [1.0, 1.0, 1.0];
44 :    
45 :     real phongKa = 0.05;
46 :     real phongKd = 0.65;
47 :     real phongKs = 0.45;
48 :     real phongSp = 50.0;
49 :    
50 :     field#2(3)[] F = bspln3 ⊛ image("data/vfrhand-nohip.nhdr");
51 :    
52 :     strand RayCast (int ui, int vi)
53 :     {
54 :     real rayU = lerp(-camUmax, camUmax, -0.5, real(ui), real(imgResU)-0.5);
55 :     real rayV = lerp(-camVmax, camVmax, -0.5, real(vi), real(imgResV)-0.5);
56 :     vec3 rayVec = (camDist*camN + rayU*camU + rayV*camV)/camDist;
57 :     vec3 toEye = normalize(-rayVec);
58 :    
59 :     real rayN = camVspNear;
60 :     // ########## BEGIN per-ray initialization
61 :     real rayTransp = 1.0;
62 :     // vec3 rayRGB = [0.0, 0.0, 0.0];
63 :     real rayGrey = 0.0;
64 :     output vec4 outRGBA = [0.0, 0.0, 0.0, 0.0];
65 :     // ########## END per-ray initialization
66 :    
67 :     update
68 :     {
69 :     vec3 rayPos = camEye + rayN*rayVec;
70 :     if (inside (rayPos,F)) {
71 :     // ########## BEGIN per-sample code
72 :     real val = F(rayPos);
73 :     if (val > valOpacMin) { // we have some opacity
74 :     vec3 grad = ∇F(rayPos);
75 :     vec3 norm = normalize(-∇F(rayPos));
76 :     real alpha = min(1.0, lerp(0.0, 1.0, valOpacMin, val, valOpacMax));
77 :     real ld = max(0.0, norm • lightDir);
78 :     real hd = max(0.0, norm • normalize(lightDir + toEye));
79 :     real pnt = phongKa
80 :     + phongKd * ld
81 :     + phongKs * hd^phongSp;
82 :     rayGrey += rayTransp*alpha*pnt;
83 :     rayTransp = rayTransp*(1.0 - alpha);
84 :     }
85 :     // ########## END per-sample code
86 :     }
87 :     if (rayTransp < 0.01) { // early ray termination
88 :     rayTransp = 0.0;
89 :     stabilize;
90 :     }
91 :     if (rayN > camVspFar) {
92 :     stabilize;
93 :     }
94 :     rayN += rayStep;
95 :     }
96 :    
97 :     stabilize {
98 :     outRGBA = [rayGrey, rayGrey, rayGrey, 1.0-rayTransp];
99 :     }
100 :    
101 :     }
102 :    
103 :     initially [ RayCast(ui, vi) | vi in 0..(imgResV-1), ui in 0..(imgResU-1) ];

root@smlnj-gforge.cs.uchicago.edu
ViewVC Help
Powered by ViewVC 1.0.0