Home My Page Projects Code Snippets Project Openings diderot
Summary Activity Tracker Tasks SCM

SCM Repository

[diderot] Annotation of /examples/vr-demo/vr.diderot
ViewVC logotype

Annotation of /examples/vr-demo/vr.diderot

Parent Directory Parent Directory | Revision Log Revision Log


Revision 2070 - (view) (download)

1 : jhr 2061 /*! \file vr.diderot
2 :     *
3 :     * \author John Reppy
4 :     *
5 :     * simple volume renderer, with a single directional light,
6 :     * Phong shading, and the new camera.
7 :     */
8 : jhr 2058
9 : jhr 2061 /*
10 :     * COPYRIGHT (c) 2012 The Diderot Project (http://diderot-language.cs.uchicago.edu)
11 :     * All rights reserved.
12 :     */
13 :    
14 : jhr 2067 // input image
15 :     input image(3)[] hand = image("data/vfrhand-nohip.nhdr");
16 :    
17 : jhr 2058 // image parameters
18 :     input int imgResU = 480;
19 :     input int imgResV = 345;
20 : jhr 2067 input real rayStep = 0.5;
21 : jhr 2058
22 :     // camera controls
23 :     input vec3 camEye = [127.331, -1322.05, 272.53];
24 :     input vec3 camAt = [63.0, 82.6536, 98.0];
25 :     input vec3 camUp = [0.9987, 0.0459166, -0.0221267];
26 :     input real camNear = -78.0;
27 :     input real camFar = 78.0;
28 :     input real camFOV = 5.0;
29 :    
30 :     /* we control the opacity by its center value and the +/- keys */
31 :     input real valOpacMid = 550.0; // 550 for skin, 1300.0 for bone
32 :     real valOpacMin = valOpacMid - 150.0;
33 :     real valOpacMax = valOpacMid + 150.0;
34 :    
35 :     real camDist = |camAt - camEye|;
36 :     real camVspNear = camDist + camNear;
37 :     real camVspFar = camDist + camFar;
38 :     vec3 camN = normalize(camAt - camEye);
39 :     vec3 camU = normalize(camN × camUp);
40 :     vec3 camV = camN × camU;
41 :     real camVmax = tan(camFOV*π/360.0)*camDist;
42 :     real camUmax = camVmax*real(imgResU)/real(imgResV);
43 :    
44 :     vec3 lightVspDir = [0.9, -1.0, -2.5];
45 :     vec3 lightDir = normalize(lightVspDir[0]*camU + lightVspDir[1]*camV + lightVspDir[2]*camN);
46 :     //vec3 lightRGB = [1.0, 1.0, 1.0];
47 :    
48 :     real phongKa = 0.05;
49 :     real phongKd = 0.65;
50 :     real phongKs = 0.45;
51 :     real phongSp = 50.0;
52 :    
53 : jhr 2067 field#2(3)[] F = bspln3 ⊛ hand;
54 : jhr 2058
55 :     strand RayCast (int ui, int vi)
56 :     {
57 :     real rayU = lerp(-camUmax, camUmax, -0.5, real(ui), real(imgResU)-0.5);
58 : jhr 2070 // we flip the v coordinate, since we are using DrawPixels to render the image
59 :     real rayV = lerp(-camVmax, camVmax, -0.5, real(imgResV - vi - 1), real(imgResV)-0.5);
60 : jhr 2058 vec3 rayVec = (camDist*camN + rayU*camU + rayV*camV)/camDist;
61 :     vec3 toEye = normalize(-rayVec);
62 :    
63 :     real rayN = camVspNear;
64 :     // ########## BEGIN per-ray initialization
65 :     real rayTransp = 1.0;
66 :     // vec3 rayRGB = [0.0, 0.0, 0.0];
67 :     real rayGrey = 0.0;
68 :     output vec4 outRGBA = [0.0, 0.0, 0.0, 0.0];
69 :     // ########## END per-ray initialization
70 :    
71 :     update
72 :     {
73 :     vec3 rayPos = camEye + rayN*rayVec;
74 :     if (inside (rayPos,F)) {
75 :     // ########## BEGIN per-sample code
76 :     real val = F(rayPos);
77 :     if (val > valOpacMin) { // we have some opacity
78 :     vec3 grad = ∇F(rayPos);
79 :     vec3 norm = normalize(-∇F(rayPos));
80 :     real alpha = min(1.0, lerp(0.0, 1.0, valOpacMin, val, valOpacMax));
81 :     real ld = max(0.0, norm • lightDir);
82 :     real hd = max(0.0, norm • normalize(lightDir + toEye));
83 :     real pnt = phongKa
84 :     + phongKd * ld
85 :     + phongKs * hd^phongSp;
86 :     rayGrey += rayTransp*alpha*pnt;
87 :     rayTransp = rayTransp*(1.0 - alpha);
88 :     }
89 :     // ########## END per-sample code
90 :     }
91 :     if (rayTransp < 0.01) { // early ray termination
92 :     rayTransp = 0.0;
93 :     stabilize;
94 :     }
95 :     if (rayN > camVspFar) {
96 :     stabilize;
97 :     }
98 :     rayN += rayStep;
99 :     }
100 :    
101 :     stabilize {
102 :     outRGBA = [rayGrey, rayGrey, rayGrey, 1.0-rayTransp];
103 :     }
104 :    
105 :     }
106 :    
107 :     initially [ RayCast(ui, vi) | vi in 0..(imgResV-1), ui in 0..(imgResU-1) ];

root@smlnj-gforge.cs.uchicago.edu
ViewVC Help
Powered by ViewVC 1.0.0